Findメソッド,Like演算子を使った検索:Excel VBA入門

スポンサードリンク

Findメソッド

Like演算子

Replaceメソッド

Findメソッドでのデータ検索　　　 Topへ

データを検索し発見されたセル（Rangeオブジェクトを返します）。無い時はNothingを返します。

expression.Find(What, After, LookIn, LookAt, SearchOrder, SearchDirection, MatchCase, MatchByte, SearchFormat)

引数 LookIn、LookAt、SearchOrder、および MatchByte の設定は、このメソッドが使われるたびに保存されます。
次にこのメソッドを使うときに、これらの引数の指定を省略すると、保存された設定が使われます。
これらの引数の設定を変更すると、[検索と置換] ダイアログボックスに表示される設定が変わります。
また、[検索と置換] ダイアログボックスで設定を変更すると、保存されている設定が変わります。
このような設定の変更によって生じる問題を避けるためには、Find メソッドを使うたびに、これらの引数を明示的に指定します。

引数	定数	内容
What		検索するデータを指定
After		省略可：検索を開始するセルを指定。指定したセル自体は、検索が範囲全体を一度検索して戻ってくるまで検索されません。省略すると左上端から開始します。
LookIn		省略可：情報の種類を指定。
	xlFormulas	数式
	xlValues	値
	xlComents	コメント文
LookAt		省略可
	xlPart	一部が一致するセルを検索
	xlWhole	全てが一致するセルを検索
SearchOrder		省略可：検索の方向を指定
	xlByRows	検索方向を行にします
	xlByColumns	検索方向を列にします
SearchDirection		省略可：検索の順序を指定
	xlNext	順方向
	xlPrevious	逆方向
MatchCase		省略可：大文字と小文字を区別する。
	True	区別する
	False	区別しない
MatchByte		省略可：半角と全角を区別する
	True	区別する
	False	区別しない
SearchFormat		省略可：検索に書式を含める。
	True	含める
	False	含めない

※　SearchFormatはExcel2002以降で使用可能です。

[XL2002] 特定の書式設定を検索するために FindNext を使用すると間違ったセルが検索される
http://support.microsoft.com/kb/282151/ja
[XL2000]Findメソッドで日付と時刻形式のデータを検索できない
http://support.microsoft.com/kb/416317/ja

FindNext メソッド　expression.FindNext(After)

Find メソッドによって開始された検索を継続します

【例1】完全一致

下記の表で「鹿児島県」を検索し、その文字列に一致するセルを明るい緑色に塗りつぶしてみます。

Sub Find_01()
　Dim c As Object
　Dim myKey As String, fAddress As String
　　　myKey = "鹿児島県"
　　　With Worksheets(1).Range("a1:a30")
　　　　　 Set c = .Find(What:=myKey, LookIn:=xlValues, lookat:=xlWhole, _
　　　　　　　　　　　　　　SearchOrder:=xlByColumns, MatchByte:=False)
　　　　　If Not c Is Nothing Then
　　　　　　　fAddress = c.Address
　　　　　　　Do
　　　　　　　　　c.Interior.ColorIndex = 4 '明るい緑
　　　　　　　　　Set c = .FindNexｔ(c)
　　　　　　　　　　　If c.Address = fAddress Then Exit Do
　　　　　　　Loop
　　　　　End If
　　　End With
End Sub

【実行結果】

【例2】部分一致

下記の表で「崎」を検索し、その文字列を含むセルを明るい緑色に塗りつぶしてみます。

Sub Find_02()
　Dim c As Object
　Dim myKey As String, fAddress As String
　　　myKey = "崎"
　　　With Worksheets(1).Range("a1:a30")
　　　　　 Set c = .Find(What:=myKey, LookIn:=xlValues, lookat:=xlPart, _
　　　　　　　　　　　　　　SearchOrder:=xlByColumns, MatchByte:=False)
　　　　　If Not c Is Nothing Then
　　　　　　　fAddress = c.Address
　　　　　　　Do
　　　　　　　　　c.Interior.ColorIndex = 4 '明るい緑
　　　　　　　　　Set c = .FindNexｔ(c)
　　　　　　　　　　　If c.Address = fAddress Then Exit Do
　　　　　　　Loop
　　　　　End If
　　　End With
End Sub

【実行結果】

[例3]VLOOKUP関数のような表引きを行う

なお、Findメソッド以外の方法にも興味がある方は　列の検索・行の検索（VBA)　もご覧ください。
下図のように右の表から一致するセルの隣の値を取り出します。

Sub Find_03()
　Dim c As Object
　Dim r As Range
　Dim myKey As String

　　For Each r In Range("A2:A4")
　　　　myKey = Left(r.Value, 5)
　　　　Set c = Range("E2:E9").Find(myKey, LookAt:=xlWhole)
　　　　If c Is Nothing Then
　　　　　　MsgBox myKey & "は見つかりませんでした。"
　　　　Else
　　　　　　r.Offset(0, 1).Value = c.Offset(0, 1).Value
　　　　End If
　　Next r
End Sub

【実行結果】

Like演算子を使った検索　　　 Topへ

Like演算子は文字列の比較を行います。
演算結果は一致するとTrue、一致しないとFalseを返します。Null値の場合はNullとなります。

文字パターン	引数stringの中の一致する文字
?	任意の1文字
*	任意の数の文字
#	任意の1文字の数字 (0-9)
[charlist]	文字リスト(charlist)に指定した文字の中の任意の1文字
[!charlist]	文字リスト(charlist)に指定した文字以外の任意の1文字

【例1】完全一致

下記の表で「鹿児島県」を検索し、その文字列に一致するセルを赤色に塗りつぶしてみます。

Sub Find_01()
Dim c As Object
　　For Each c In Worksheets(1).Range("a1:a30")
　　　　If c.Value Like "鹿児島県" Then
　　　　　　c.Interior.ColorIndex = 3 '赤
　　　　End If
　　Next c
End Sub

実行結果

【例2】部分一致

下記の表で「崎」を検索し、その文字列を含むセルを赤色に塗りつぶしてみます。

Sub Like_02()
Dim c As Object
　　For Each c In Worksheets(1).Range("a1:a30")
　　　　If c.Value Like "*崎*" Then
　　　　　　c.Interior.ColorIndex = 3 '赤
　　　　End If
　　Next c
End Sub

実行結果

【例3】ある範囲の一致

下記の表でふりがなが「か～こ」で始まるものを検索し、該当するセルを赤色に塗りつぶしてみます。
ふりがながひらがなで設定されている例です。

Sub Like_03()
Dim c As Object
　　For Each c In Worksheets(1).Range("a1:a30")
　　　　If c.Phonetic.Text Like "[か-こ]*" Then
　　　　　　c.Interior.ColorIndex = 3 '赤
　　　　End If
　　Next c
End Sub

実行結果

Replaceメソッドを使った置換　　　 Topへ

データを置き換えます。
expression.Replace(What, Replacement, LookAt, SearchOrder, MatchCase, MatchByte, SearchFormat, ReplaceFormat)

【例】下記の表でC列の「福岡県」を「鹿児島県」に置換します。

Sub Find_02()
　Dim c As Object
　　　With Worksheets("Sheet1").Range("C1:C30")
　　　　　.Replace What:="福岡県", Replacement:="鹿児島県", _
　　　　　　　SearchOrder:=xlByColumns, MatchByte:=False
　　　　　End With
End Sub

実行結果

スポンサードリンク

よねさんのWordとExcelの小部屋｜Excel(エクセル)講座の総目次｜Excel(エクセル) VBA入門：目次｜Findメソッド,Like演算子を使った検索

PageViewCounter
　 Counter
　Since2006/2/27

Findメソッド,Like演算子を使った検索:Excel VBA入門

Findメソッドでのデータ検索 Topへ

FindNext メソッド expression.FindNext(After)

【例1】完全一致

【例2】部分一致

[例3]VLOOKUP関数のような表引きを行う

Like演算子を使った検索 Topへ

【例1】完全一致

【例2】部分一致

【例3】ある範囲の一致

Replaceメソッドを使った置換 Topへ

Findメソッドでのデータ検索　　　 Topへ

FindNext メソッド　expression.FindNext(After)

Like演算子を使った検索　　　 Topへ

Replaceメソッドを使った置換　　　 Topへ