1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. Expand関数を使って、ボックス型カレンダーに空白行を挿入する

Expand関数を使って、ボックス型カレンダーに空白行を挿入する:Excel関数

更新:2026/8/21;作成:2026/8/18

Expand関数を使って、ボックス型カレンダーに空白行を挿入する

• ボックス型のカレンダーはSequence関数を使うと簡単に作成できます。
  カレンダーに書き込みができるように空白行を入れたい・・・ということです。
• 使用する関数の説明は以下のページをご覧ください。
  • 配列を指定された行数・列数だけ拡大するEXPAND関数の使い方 Excel for Microsoft365
  • 配列を1行・1列にするTOROW関数・TOCOL関数の使い方 Excel2024
  • 行または列で折り返す配列を作成するWRAPROWS関数・WRAPCOLS関数の使い方 Excel2024
  • SEQUENCE関数の使い方(連続した数値の配列を作成する) Excel2021以降

カレンダーを作成する

• ボックス型カレンダーの作成方法は　ボックス型カレンダーを作成する　で解説しています。
• 表示したい月の前後の 日〜土 をすべて表示して作成します。
• B4セルに　=SEQUENCE(6,7,DATE(B2,D2,1)-WEEKDAY(DATE(B2,D2,1))+1)　と入力します。
  下図のようなカレンダーが作成できました。
  

EXPAND関数で空白行を作成する

1. 空白行を作成したいので、カレンダの列を倍の14列に拡張します。
   B4セルに　=EXPAND(SEQUENCE(6,7,DATE(B2,D2,1)-WEEKDAY(DATE(B2,D2,1))+1),,14,"")　と入力しています。
   
2. この配列を TOCOL関数で1列のデータにします。
   更に、WRAPROWS関数で7列で折り返します。
   B4セルに　
   =WRAPROWS(TOCOL(
   　　EXPAND(SEQUENCE(6,7,DATE(B2,D2,1)-WEEKDAY(DATE(B2,D2,1))+1),,14,"")
   　　　),7)
   と入力しています。
   
3. 2行の空白行を入れたいときは、14 → 21 とするだけです。
   B4セルに　
   =WRAPROWS(TOCOL(
   　　EXPAND(SEQUENCE(6,7,DATE(B2,D2,1)-WEEKDAY(DATE(B2,D2,1))+1),,21,"")
   　　　),7)
   と入力しています。
   

条件付き書式で当月の日にちを太くする

1. 表示する月と同じ場合は太文字にします。
   異なる場合は斜体にします。
   条件付き書式の数式は下図のようになります。
   
2. 祝日や日曜日、土曜日に色を付けたい場合は下図のように数式を作成します。
   
3. 罫線を入れたり、セルの色を白にしてみました。
   下図のようになりました。
   

PageViewCounter

Since2006/2/27