1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. 指定した区切り文字で分割するTEXTSPLIT関数の使い方

指定した区切り文字で分割するTEXTSPLIT関数の使い方:Excel関数

更新:2025/2/23;作成:2022/9/2

指定した区切り文字で文字列を分割します。
　テキスト　スプリット
=TEXTSPLIT(text,col_delimiter,[row_delimiter],[ignore_empty],[match_mode],[pad_with])

• TEXTSPLIT関数がExcel for Microsoft 365 で使用することができるようになりました。(2022/9/2に確認しました)
  Excel2024（2024/10/2から市販されました)でも使用できるようになりました。
• この関数とは逆に文字列を結合する関数はTEXTJOIN関数が使用できます。
  TEXTJOIN関数はExcel for Microsoft 365,Excel2019以降で使用することができます。

TEXTSPLIT関数の引数

• 関数の引数は現時点では英語表記になっています。
  ちなみに、TEXTJOIN関数は下図のように日本語表記です。
  
• TEXTSPLIT関数の引数
  

  引数		意味
  text 文字列	必須	分割したいテキスト(文字列)
  col_delimiter 列の区切り文字	必須	列方向に分割するときに使う文字または文字列
  row_delimiter 行の区切り文字	省略可	行方向に分割するときに使う文字または文字列
  ignore_empty 空欄を無視する	省略可	空欄を無視するかどうか TRUE: 空欄を無視する FALSE(省略): 空欄を無視しない
  match_mode 一致モード	省略可	区切り文字を検索する時、大文字・小文字を区別するか 0(省略): 大文字と文字を区別する 1: 大文字と小文字を区別しない
  pad_with 代替文字	省略可	各行の横方向のデータ不足時に表示する値

サンプルデータ

• 区切り文字で分割するには「区切り位置」を使う方法がありました。
  これを関数で実行できるようになったと考えればよさそうです。
  なので、ここではCSVデータを分割する例で説明しています。
• ここで使用しているサンプルデータ（架空のものです）です。
  このデータをシートのA1セルに貼り付けます。
  

  No,氏名,性別,郵便番号,住所,生年月日

  1,上原嘉男,男,027-0096,岩手県宮古市崎鍬ケ崎3-5-9,1977/7/12

  2,森永彩芽,女,760-0027,香川県高松市紺屋町4-18-1,1963/3/25

  3,古田恵,女,254-0912,神奈川県平塚市高根1-4,1980/5/4

  4,太田千恵子,女,972-8315,福島県いわき市常磐長孫町1-1-8,1987/8/17

col_delimiter(列の区切り文字)

• col_delimiter(列の区切り文字)を使用した例
  B1セルに　=TEXTSPLIT(A1,",")　と列の区切り文字に ,(カンマ) を指定しました。
  カンマで文字列が分割されて列方向へ入力されます。
  B1の数式を下方向へフィルハンドルをドラッグしてコピーします。
  

row_delimiter(行の区切り文字)

• row_delimiter(行の区切り文字) に ,(カンマ) を指定した例
  B2セルに　=TEXTSPLIT(A2,,",")　と行の区切り文字に ,(カンマ) を指定しました。列の区切り文字は省略しています。
  カンマで文字列が分割されて行方向へ入力されます。
  
• 右方向へデータを列記するには参照位置を下方向へずらす必要があります。
  =TEXTSPLIT(OFFSET($A$1,COLUMN(A1)-1,),,",")
  と、OFFSET関数を利用しました。
  

col_delimiter(列の区切り文字) とrow_delimiter(行の区切り文字) を指定する

• col_delimiter(列の区切り文字)に ,
  row_delimiter(列の区切り文字)に ;　を指定した
• サンプルデータ
  

  No,氏名,性別;郵便番号,住所,生年月日

  1,上原嘉男,男;027-0096,岩手県宮古市崎鍬ケ崎3-5-9,1977/7/12

• B1セルに　=TEXTSPLIT(A1,",",";")
  B3セルに　=TEXTSPLIT(A3,",",";")
  と入力すると、２行に分けて表示されます。
  

ignore_empty(空欄を無視する)

• サンプルデータ
  

  1,上原嘉男,男,027-0096,岩手県宮古市崎鍬ケ崎3-5-9,1977/7/12

  1,上原嘉男,,027-0096,,1977/7/12

• B3セルには　=TEXTSPLIT(A3,",",,TRUE)
  B4セルには　=TEXTSPLIT(A3,",",,FALSE)
  元の文字列に区切り文字,(カンマ)の文字列で空欄があった時(,,と区切り文字が連続しているとき)、この空欄を表示するか無視するかが設定できます。
  TRUEと指定すると、空欄は無視され、セルは詰めて入力されます。
  FALSEを指定すると、空欄もセルに設定され、空欄の位置のセルは空欄となります。
  

match_mode(一致モード)

• サンプルデータ
  

  1,上原嘉男,男，027-0096,岩手県宮古市崎鍬ケ崎3-5-9，1977/7/12

  1x上原嘉男x男X027-0096x岩手県宮古市崎鍬ケ崎3-5-9X1977/7/12

• match_mode(一致モード)で大文字と小文字の区別の方法を切り替えられるということで、
  最初に、「,」　と　「，」で区別しようと、=TEXTSPLIT(A1,",",,,0)　と　=TEXTSPLIT(A1,",",,,1)　で試したのですが・・・
  ご覧の通り、同じ結果になり、「，」で区切ることができませんでした。
  
• そうです、「,」　と　「，」は大文字と小文字ではなく、半角文字と全角文字です。
  初心者レベルの勘違いをしてしまいました。
• では、大文字と小文字があるのはアルファベットですので、ここでは「x]と「X」で再挑戦しました。
  元の文字列には ｘ　と　X　が混在しています。
  =TEXTSPLIT(A1,"x",,,0)　と大文字と文字を区別する「0」と指定すると、Xでは区切られません。
  =TEXTSPLIT(A1,"x",,,1)　と大文字と文字を区別しない「1」と指定すると、Xでも区切ることができました。
  
• ところで、「,」　と　「，」で区切りたい場合は区切り文字を配列で指定すればOKです。
  =TEXTSPLIT(A1,{",","，"})　としています。
  

pad_with(代替文字)

• サンプルデータ
  

  りんご,300,5,1500;みかん,400;ばなな,250,4,1000

• =TEXTSPLIT(A1,",",";") と、行方向と列方向に,と;で分割します。
  すると、データが不足したところに　#N/A とエラーが表示されます。
  
• このエラーの代わりに -(ハイフン)を表示します。
  =TEXTSPLIT(A1,",",";",,,"-")　と入力しています。
  

フラッシュフィルという機能をTEXTSPLIT関数で実行する

• よく使われている例で名前を苗字と名前に分割できます。
  これはフラッシュフィルの説明でよく使われるものです。
• サンプルデータ
  赤文字の3名の氏名は全角のスペースで区切られています。
  そのほかは半角のスペースで区切られています。
  

  	B	C	D	E
  2	No	氏名	苗字	名前
  3	1	葛西 祐基
  4	2	宮下 涼
  5	3	横田 まさし
  6	4	川井　美里
  7	5	平　奈央
  8	6	伊集院 満
  9	7	柴崎　優
  10	8	赤羽 美幸

• フラッシュフィルでは半角も全角も区切ることができます。
  TEXTSPLIT関数では　=TEXTSPLIT(C3,{" ","　"})　と半角スペースと全角スペースを配列で指定します。
  D3セルに数式を入力して、下方向へコピーします。
  

スポンサードリンク

PageViewCounter

Since2006/2/27