1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. 稼働日を求める(WORKDAY関数・WORKDAY.INTL関数の使い方)

稼働日を求める(WORKDAY・WORKDAY.INTL関数の使い方):Excel関数

指定された稼動日数だけ前/後の日付を求めます　　　topへ
　ワークデイ
=WORKDAY(開始日,日数,[祭日])
　　　指定した稼働日数の前/後の日付に対応する値を返します。稼動日とは、土曜、日曜、および指定された祭日を除く。
　(注)　Excel2003以前のバージョンでは、エラー値 #NAME? が返される場合は、分析ツール アドインを組み込む必要があります。

• 基本的には土日を除いた日数を計算することができますが、指定した日にちを除くこともできます。
  構文の引数で「祭日」と書いてある部分に特定の日付を指定すればよいので、会社での土日以外の休日を当てることもできます。
  翌営業日など次の平日(土日や祭日を除く)を求めることもできます。
• 土日を除く○日後/前を返すことができますので、土日祝なら前の（次の）平日を返すこともできます。
• 【問題1】2013年1月10日に請求書を発行します。　支払日は請求日から5営業日とします。
  支払日を求めなさい。ただし祝日は考慮しないものとします。

  	B	C
  2	請求日	2013年1月10日
  3	支払日	2013年1月17日

  • (参考)2013年1月のカレンダーは下表のようになっています。
    1/10から土日を除くと　1/11、1/14、1/15、1/16、1/17　となり、5日後は2013/1/17となります。
    この問題では祝日は考慮しないので 1/14 も営業日としてカウントします。
    
• 問題1の解答例　WORKDAY関数を使った例です。(祭日は考慮していません)
  C3セルに　=WORKDAY(C2,5)　と入力します。
  
• 関数の引数ダイアログボックスを使う場合
  1. C3セルを選択して、[関数の挿入]ボタンをクリックします。
     
  2. 関数の分類で「すべて表示」を選択し、関数名で WORKDAY を選択します。
     [OK]ボタンをクリックします。
     
  3. WORKDAY関数の引数、開始日に C2 、日数に 5 を入力します。
     
  4. C3セルに =WORKDAY(C2,5) と数式が入力され、　セルには 2013年1月17日　と表示します。
     
  • C3セルにシリアル値が表示されたら、[Ctrl]+[1]でセルの表示形式のダイアログボックスを表示します。
    表示形式を「日付」の「2012年3月14日」に変更します。
    下図はExcel for Microsoft365です。ロケールは「日本語」、カレンダーの種類は「グレゴリオ暦」とします。
    

• 【問題2】2013年1月10日に請求書を発行します。　支払日は請求日から5営業日とします。
  ただし、土日と祭日は営業日として数えません。支払日を求めなさい。
  

  	B	C	D	E	F
  2	請求日	2013年1月10日		祝日一覧
  3	支払日	2013年1月18日		2013/1/1	元旦
  4				2013/1/14	成人の日
  5				2013/2/11	建国記念日

• 問題2の解答例
  • 2013/1/10から土日と祭日を除くと　1/11、1/15、1/16、1/17、1/18　となり、5日後は2013/1/18となります。
    
  • 祝日を考慮する場合は、祝日の表を作成します。引数の[祭日]の部分に祝日のセル範囲　E3:E5　を指定します。
  • C3セルには　=WORKDAY(C2,5,E3:E5)　と入力します。
    
  • C3セルにシリアル値が表示されたら、表示形式を「日付」の「2001年3月14日」に変更します。
  • 祭日に祝日一覧の日付のセル範囲 E2:E4 を指定します。
    

• 【問題3】2013年1月8日に請求書を発行します。　支払日は5日後とします。
  ただし、支払日が土日や祭日にあたる場合は支払日は翌日とします。支払日を求めなさい。
  

  	B	C	D	E	F
  2	請求日	2013年1月8日		祝日一覧
  3	支払日	2013年1月15日		2013/1/1	元旦
  4				2013/1/14	成人の日
  5				2013/2/11	建国記念日

  • 1/8から5日後は13日ですが、日曜日にあたります。
    14日は祭日なので、支払日は　2013/1/15　となります。
    
• 問題3の解答例
  祝日を考慮する場合は、祝日の表を作成します。引数の[祭日]の部分に祝日のセル範囲　E3:E5　を指定します。
  C3セルには　=WORKDAY(C2+4,1,E3:E5)　と入力します。
  支払日の前日を C2+4で求めて　(ここで C2+5-1　と5日後の前の日を計算しています)、翌日(WORKDAY関数の第2引数を1とします)が土日や祭日を除いた平日を返すように、WORKDAY関数を使って求めます。
  • 次の平日を出す場合 → Workday(開始日-1,1,祭日）
    ちなみに、前の平日を求めるとき→ Workday(開始日+1,-1,祭日)
  

• 【問題4】演奏会が2013/1/18に決定しました。演奏会の5日前の平日に発券を開始することになりました。
  いつから発券すればよいでしょう?
  (土日、祭日に発券することはできません。)
  

  	B	C	D	E	F
  2	演奏会	2013年1月18日		祝日一覧
  3	発券開始日	2013年1月11日		2013/1/1	元旦
  4				2013/1/14	成人の日
  5				2013/2/11	建国記念日

  • 1/18から5日前は13日ですが、日曜日にあたります。
    12日は土曜なので、その前の平日は　2013/1/11　となります。
    
• 問題4の解答例
  祝日を考慮する場合は、祝日の表を作成します。引数の[祭日]の部分に祝日のセル範囲　E3:E5　を指定します。
  C3セルには　=WORKDAY(C2-4,-1,E3:E5)　と入力します。
  発券する日の次の日を　C2-4　で求めて　(ここで C2-5+1　と5日前の日の次の日を計算しています)、前の日(WORKDAY関数の第2引数を-1とします)が土日や祭日を除いた平日を返すように、WORKDAY関数を使って求めます。
  • 次の平日を出す場合 → Workday(開始日-1,1,祭日）
    ちなみに、前の平日を求めるとき→ Workday(開始日+1,-1,祭日)
  

指定された稼動日数だけ前/後の日付を求めます　　　topへ
　ワークデイ インターナショナル
=WORKDAY.INTL(開始日,日数,[週末],[祭日])
　(注)　Excel2010で追加された関数です。

• 従来のWORKDAY関数に[週末]が追加された形です。土日以外の非稼働日に対応できるようになっています。
• 開始日から起算して指定した稼働日数だけ前または後の日付のシリアル値を返します。
  週末、祝日として指定した日はすべて、稼働日と見なされません。
• 週末の指定方法
  

  週末番号	週末の曜日
  1または省略	土曜日と日曜日
  2	日曜日と月曜日
  3	月曜日と火曜日
  4	火曜日と水曜日
  5	水曜日と木曜日
  6	木曜日と金曜日
  7	金曜日と土曜日
  11	日曜日
  12	月曜日
  13	火曜日
  14	水曜日
  15	木曜日
  16	金曜日
  17	土曜日

• 週末の指定は7桁の文字列での指定もできます。
  月曜日から始まる各曜日を表し、1は非稼働日を表し、0は稼働日を表します。
  上の表に無い月曜日と水曜日を休みとしたいときは"1010000"と指定します。
  

  月	火	水	木	金	土	日
  1	0	1	0	0	0	0

• 【問題1】 2013年1月10日に請求書を発行します。　支払日は請求日から5営業日とします。
  支払日を求めなさい。ただし、祝日は考慮しないものとします。
  

  	B	C
  2	請求日	2013年1月10日
  3	支払日	2013年1月17日

  • (参考)2013年1月のカレンダーは下表のようになっています。
    1/10から土日を除くと　1/11、1/14、1/15、1/16、1/17　となり、5日後は2013/1/17となります。
    この問題では祝日は考慮しないので 1/14 も営業日としてカウントします。
    
• 問題1の解答例
  WORKDAY.INTL関数を使った例です。(祭日は考慮していません)
  C3セルに　=WORKDAY.INTL(C2,5)　と入力します。
  WORKDAY関数でも=WORKDAY(C2,5)　で求めることができます。
  

  	B	C
  2	請求日	2013年1月10日
  3	支払日	=WORKDAY.INTL(C2,5)
  4
  5

• 【問題2】2013年1月10日に請求書を発行します。　支払日は請求日から5営業日とします。
  支払日を求めなさい。ただし、祝日は休みとします。
  

  	B	C	D	E	F
  2	請求日	2013年1月10日		祝日一覧
  3	支払日	2013年1月18日		2013/1/1	元旦
  4				2013/1/14	成人の日
  5				2013/2/11	建国記念日

• 問題2の解答例
  (参考)2013年1月のカレンダーは下表のようになっています。
  1/10から土日を除くと　1/11、1/15、1/16、1/17、1/18　となり、5日後は2013/1/18となります。
  この問題では祝日は休みとしますので、 1/14 は営業日としてカウントしません。
  
  WORKDAY.INTL関数を使った例です。
  C3セルに　=WORKDAY.INTL(C2,5,E3:E5)　と入力します。
  WORKDAY関数でも　=WORKDAY(C2,5,E3:E5)　で求めることができます。
  

  	B	C	D	E	F
  2	請求日	2013年1月10日		祝日一覧
  3	支払日	=WORKDAY.INTL(C2,5,E3:E5)		2013/1/1	元旦
  4				2013/1/14	成人の日
  5				2013/2/11	建国記念日

• 【問題3】2013年1月10日に請求書を発行します。　支払日は請求日から5営業日とします。
  支払日を求めなさい。ただし、水曜日と祝日を休みとします。土日は営業日とします。
  

  	B	C	D	E	F
  2	請求日	2013年1月10日		祝日一覧
  3	支払日	2013年1月17日		2013/1/1	元旦
  4				2013/1/14	成人の日
  5				2013/2/11	建国記念日

  • (参考)2013年1月のカレンダーは下表のようになっています。
    1/10から土日を除くと　1/11、1/12、1/13、1/15、1/17　となり、5日後は2013/1/17となります。
    この問題では祝日と水曜日は休みとしますので、 1/14 と1/16 は営業日としてカウントしません。
    
• 問題3の解答例　 WORKDAY.INTL関数を使った例です。
  C3セルに　=WORKDAY.INTL(C2,5,14,E3:E5)　と入力します。
  

  	B	C	D	E	F
  2	請求日	2013年1月10日		祝日一覧
  3	支払日	=WORKDAY.INTL(C2,5,14,E3:E5)		2013/1/1	元旦
  4				2013/1/14	成人の日
  5				2013/2/11	建国記念日

  
  数式を手入力すると、週末はヒントのリストから選択することができます。
  リスト内は　↓(カーソルキー)で選択し、[Tab]キーで決定します。
  
  • 関数の引数ダイアログを利用すると、開始日に C2 、日数に 5 、週末に 14、祭日に E3:E5 と指定します。
    
  • 週末を　"0010000" と指定することもできます。
    

    月	火	水	木	金	土	日
    0	0	1	0	0	0	0

    
    

• 【問題4】 2013年1月9日(水曜日)に請求書を発行します。　支払日は請求日から5営業日とします。
  支払日を求めなさい。ただし、月曜日と木曜日を休みとします。土日、祝日は営業日とします。
  

  	B	C
  2	請求日	2013年1月9日
  3	支払日	2013年1月16日

  • (参考)2013年1月のカレンダーは下表のようになっています。
    1/9から月曜日と木曜日を除くと　1/11、1/12、1/13、1/15、1/16　となり、5日後は2013/1/16となります。
    この問題では月曜日と木曜日は休みとしますので、 1/14 は営業日としてカウントしません。
    
• 問題4の解答例
  WORKDAY.INTL関数を使った例です。(祭日は考慮していません)
  C3セルに　=WORKDAY.INTL(C2,5,"1001000")　と入力します。
  • 月曜日と木曜日は休みとしますので、引数[週末]に　"1001000" とします。
    (月火水木金土日で休みにするところを1、そうでないところは0とします)
    

    月	火	水	木	金	土	日
    1	0	0	1	0	0	0

  	B	C
  2	請求日	2013年1月9日
  3	支払日	=WORKDAY.INTL(C2,5,"1001000")

  • 関数の引数ダイアログを使う場合は、　週末に　　"1001000" とし、祭日は空欄のままにします。
    

• 参考：似たような関数で NETWORKDAYS.INTL 関数があります。こちらは指定された期間の稼動日数を求めます。
  (注)　Excel2010で追加された関数です
  詳細は　NETWORKDAYS.INTL関数　の使い方をご覧ください。

スポンサードリンク

PageViewCounter

Since2006/2/27