Excel(エクセル)講座 Q&A(Tips)：計算関連 2/4(日付など)

成人の日、体育の日、海の日、敬老の日の求め方（ハッピーマンデイ　第2、第3月曜日の求め方）　　Topへ

第2月曜日を計算で求める

• =14-MOD(WEEKDAY(DATE(年,月,1))+4,7)
  • 年には求める年を西暦で入れます。（2003とか2004のように）
  • 月に1か10を入れます。
  • (例)2003年1月の成人の日は
    =14-MOD(WEEKDAY(DATE(2003,1,1))+4,7)
    となります。
• 上の数式の意味を考えるのは面倒と思ったら、日付を決め打ちする方法もあります。
  • A1セルに求めた月の1日がシリアル値で入力されているとします。
    =DATE(YEAR(A1),MONTH(A1),CHOOSE(WEEKDAY(A1),9,8,14,13,12,11,10))

第3月曜日を計算で求める

• 2003年から海の日(7月)と敬老の日(9月)は第3月曜日となりました。
  これらも同様に求められます。
• =21-MOD(WEEKDAY(DATE(年,月,1))+4,7)
  • (例)2003年7月の海の日は
    =21-MOD(WEEKDAY(DATE(2003,7,1))+4,7)
    となります。

　　　　　　(参考)　　祝日一覧表（2004年)

• 春分の日と秋分の日は政府が決定して、前年の2月に官報で発表されます。
  • 計算で求めるには
    春分の日= Int(20.8431 + 0.242194 * (年 - 1980) - Int((年 - 1980) / 4))
    秋分の日= Int(23.2488 + 0.242194 * (年 - 1980) - Int((年 - 1980) / 4))
    として、2099年までは求められるようですが、正確には前年の2月まで正解かどうかは判らないことになります。

生年月日から干支を求めたい　　　　Topへ

• 関数を使った例です
• B2セルに生年月日を入れます。
  

  	B	C
  2	2003/1/1	=MID("申酉戌亥子丑寅卯辰巳午未",MOD(YEAR(B2),12)+1,1)

• 干支は12年周期ですから年月日の入力されたセル（B2セル)の年を12で割り余りを求めます。
• 文字を取り出すために余り「0」では都合が悪いので「1」を加算します。
• 文字列『干支』の並びは計算結果の「1」に対応する「申」から並べておきます。

月の最終日(月末)を求める　　　Topへ

• DATE関数やEOMONTH関数を使います。
  (*)EOMONTH関数は、ツール →　アドイン　で 分析ツールにチェックを入れます。
  (参考) 日付の関数について

月末を求める

• 下の例は当月の月末を求める例です。
• 何ヶ月後の場合は赤字の数値を変更します。来月であれば、「+2」や「1」となります。
  

  	B	C	D
  2	2004/1/1	=DATE(YEAR(B2),MONTH(B2)+1,0)	2004/1/31
  3		=DATE(YEAR(B2),MONTH(A1)+1,1)-1	2004/1/31
  4		=EOMONTH(B2,0)	2004/1/31

土日、祝日を除いた月末を求める

• 土日、祝日を除いた月末を求めるにはWORKDAY関数を使い、祝日の表を作成します。
  この例ではD3：D4に作成しています。
• =WORKDAY(EOMONTH(A1,0)+1,-1,祝日)　　
• =WORKDAY(EOMONTH(A1,0)+1,-1,D2:D3)　
• のように、翌月の1日を基準に前の稼働日を求めればよいです。
  

  	B	C	D
  2	2005/4/1	=WORKDAY(EOMONTH(B2,0)+1,-1,D3:D4)	祝日
  3		=WORKDAY(DATE(YEAR(B2),MONTH(B2)+1,1),-1,D3:D4)	2005/4/29
  4			2005/5/3

　PageViewCounter
　
　Since2006/2/27