1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. 条件付き平均の関数(AVERAGEIF関数,AVERAGEIFS関数の使い方)

条件付きで平均を求める関数(AVERAGEIFS関数,AVERAGEIF関数)の使い方:Excel関数

• 条件付きで平均を求める関数(AVERAGEIFS関数,AVERAGEIF関数)の使い方を解説しています。
  ともに、Excel2007で追加された関数です。(Exel2007,Excel2010,Excel2013,Excel2016,Excel2019 で使用できます)

更新:2024/6/29;作成:2016/3/14

はじめに

• 関数の引数の並びを見ると・・・混乱しませんか?
  AVERAGEIF(範囲,条件,平均対象範囲)
  AVERAGEIFS(平均範囲,検索条件範囲1,検索条件1,検索条件範囲2,検索条件2...)
  面倒なので、1つの条件でもAVERAGEIFS関数を使うことが便利な使い方ではないのかと思っています。
  AVERAGEIF関数は不要といってもいいのでは・・・?
• 関数の使い方の説明の順番を変更します。(記 2021/12/08)
  AVERAGEIF関数のところにもAVERAGEIFS関数での処理方法を追記します。

AVERAGEIFS関数：複数の検索条件に一致するすべてのセルの平均値 (算術平均) を返します。　　Topへ
アベレージ　イフズ
AVERAGEIFS(平均範囲,検索条件範囲1,検索条件1,検索条件範囲2,検索条件2...)
　　Excel2007で追加された関数です

• 複数の条件での平均値を求めるときにはAVERAGEIFS関数を利用します。
  AVERAGEIFS関数では引数の「平均範囲」を最初に指定するようになっていることに注意してください。AVERAGEIF関数では引数の3番目の指定になっているのと異なっています。
• ここでは下図のデータを使用しますので、コピーしてお使いください。
  

  	B	C	D	E	F	G	H	I	J	K
  2	番号	氏名	クラス	性別	年齢	得点		クラス	性別	平均得点
  3	1	上原嘉男	1	男	44	91		1	男	83.5
  4	2	森永彩芽	3	女	58	98		2	男
  5	3	古田恵	1	女	41	61		3	男
  6	4	太田千恵子	2	女	34	46		1	女
  7	5	豊田啓一	2	男	38	78		2	女
  8	6	新村遥奈	3	女	29	76		3	女
  9	7	坂元彩香	2	女	38	68
  10	8	坪井尚生	3	男	45	77
  11	9	西原舞	3	女	47	41
  12	10	中野野乃花	1	女	51	93
  13	11	岩渕佳代	2	女	44	61
  14	12	市村将文	3	男	58	66
  15	13	芦田公平	2	男	59	90
  16	14	高見美姫	1	女	34	81
  17	15	高山晴彦	1	男	65	76
  18	16	高島嘉子	1	女	53	85
  19	17	蛭田功一	2	男	46	60
  20	18	北奈那	1	女	42	84
  21	19	本田明莉	2	女	62	66
  22	20	東海林真依	3	女	63	92

• 【問題1】クラスが「1〜3」で性別が「男,女」の人の得点の平均値を求めなさい。
• 【問題1の解答例】
  1. K3セルに =AVERAGEIFS($G$3:$G$22,$D$3:$D$22,I3,$E$3:$E$22,J3)　と入力します。
     K8セルまでオートフィルで数式をコピーし、表示桁数を調整します。
     

• 【問題2】クラスが「1〜3」で性別が「男/女」の人の得点の平均値を求めなさい。
• 【問題2の解答例】
  • スピルが利用できる場合(Excel for Microsoft365,Excel2021以降)
    K3セルに　=AVERAGEIFS(G3:G22,D3:D22,I3:I8,E3:E22,J3:J8)　と入力します。
    

• 【問題3】20歳代、30歳代、40歳代、50歳代、60歳代の平均得点を計算しなさい
• 【問題3の解答例】
  • スピルが利用できる場合(Excel for Microsoft365,Excel2021,Excel2024)
    K3セルに　=AVERAGEIFS(G3:G22,F3:F22,">="&I3:I7,F3:F22,"<"&I3:I7+10)
    と条件1と条件2の書き方がポイントになります。
    
  • Spillが使えない場合
    K3セルに　=AVERAGEIFS($G$3:$G$22,$F$3:$F$22,">="&I3,$F$3:$F$22,"<"&I3+10)　と入力します。
    フィルハンドルをダブルクリック、またはK7セルまでドラッグして数式をコピーします。
    

比較演算子について

• 演算子	意味	論理式での使用例	結果
  >	より大きい	=A1>B1	A1がB1より大きいならTRUE、そうでなければFALSE
  >=	以上	=A1>=B1	A1がB1以上ならTRUE、そうでなければFALSE
  <	未満(より小さい)	=A1<B1	A1がB1未満(より小さい)ならTRUE、そうでなければFALSE
  <=	以下	=A1<=B1	A1がB1以下ならTRUE、そうでなければFALSE
  =	等しい	=A1=B1	A1とB1が等しいならTRUE、そうでなければFALSE
  <>	等しくない	=A1<>B1	A1とB1が等しくなければTRUE、そうでなければFALSE

ワイルドカード文字

• ワイルドカード文字
  　？(クエスチョンマーク)は任意の 1 文字
  　＊(アスタリスク)は任意の数の文字
  　？や＊を文字として検索するときには　~(チルダ)　を使用します。
• ワイルドカードとの組み合わせ例
  

  例	結果	例	結果
  =A*	Aで始まる	=?A	文字数が2で、2文字目がA
  =*A	Aで終わる	=?A*	左から2文字目がA
  =*A*	Aを含む	=*A?	右から2文字目がA
  <>*A*	Aを含まない

• ワイルドカード文字の使用例
  島*　「島で始まる」
  *島　「島で終わる」
  *島*　「島を含む」
  
  ?島　「2文字の文字列で2文字目が島」
  ??島　「3文字の文字列で3文字目が島」
• ワイルドカードの使用例
  47都道府県をワイルドカードで検索してCOUNTIF関数で数えています。
  =COUNTIF($B$2:$B$48,D$1)
  該当する県名を4行目以降に書き出しています。
  

AVERAGEIF関数：範囲内の条件に一致するすべてのセルの平均値を返します。　　　Topへ
アベレージ　イフ
AVERAGEIF(範囲,条件,平均対象範囲)
　　Excel2007で追加された関数です

• ここでは下表のデータを使って説明します。
  

  	B	C	D	E	F	G
  2	No	名前	性別	年齢	血液型	得点
  3	1	今泉真理	女	50	AB	61
  4	2	藤村美奈子	女	34	B	49
  5	3	寺田琉那	女	25	AB	61
  6	4	五十嵐篤	男	22	B	30
  7	5	大場龍雄	男	40	AB	73
  8	6	吉川好	女	28	A	45
  9	7	北章司	男	45	O	90
  10	8	土橋義昭	男	20	AB	61
  11	9	露木志帆	女	24	B	85
  12	10	野島昌彦	男	50	O	72
  13	11	山岡陽菜乃	女	45	A	81
  14	12	吉崎光雄	男	40	A	68
  15	13	水口勝昭	男	28	A	70
  16	14	結城真由	女	39	AB	59
  17	15	臼井幸也	男	32	A	38
  18	16	森岡果凛	女	34	B	41
  19	17	川村心	女	23	O	88

• 【問題1】性別が「女」と「男」の得点の平均をそれぞれ求めなさい。
• 【問題1の解答例】女の平均は　=AVERAGEIF(D3:D19,"女",G3:G19)
  男の平均は　=AVERAGEIF(D3:D19,"男",G3:G19)　で求めることができます。
  下図のように、女と男が入力してあり、J3:J4セルに数式を入力する場合は
  数式はJ3セルに　=AVERAGEIF($D$3:$D$19,I3,$G$3:$G$19)　と入力して、下に数式をコピーします。
  
  
• AVERAGEIFS関数で求めることができます。
  =AVERAGEIFS(G3:G19,D3:D19,"女")
  =AVERAGEIFS(G3:G19,D3:D19,"男")
• なお、Excel for Microsoft365のようにスピル(Spill)が利用できる場合は、
  =AVERAGEIFS(G3:G19,D3:D19,I3:I4) とすることができます。
  

• 【問題2】名前に「川」の文字を含む人の得点の平均を求めなさい。
• 【問題2の解答例】文字列の一部に「川」の文字を含むという条件はワイルドカードを利用します。
  条件に　*川*　とアスタリスク(*)を前後に配置します。
  数式は　=AVERAGEIF(C3:C19,"*川*",G3:G19)　とします。
  下図では説明のために条件と一致する箇所に色を付けています。
  
• AVERAGEIFS関数で求めることができます。
  =AVERAGEIFS(G3:G19,C3:C19,"*川*")
  

• 【問題3】名前が3文字の人の得点の平均を求めなさい。
• 【問題3の解答例】文字数が3という条件はワイルドカードの ? を3個並べることで指定することができます。
  数式は　=AVERAGEIF(C3:C19,"???",G3:G19)　としました。
  
• AVERAGEIFS関数で求めることができます。
  =AVERAGEIFS(G3:G19,C3:C19,"???")
  

スポンサードリンク

PageViewCounter

Since2006/2/27