2つの値が等しいかどうかを調べるDELTA関数の使い方:Excel関数

スポンサードリンク

更新:2024/2/27;作成:2011/9/13

2つの値が等しいかどうかを調べます。　　　topへ
　デルタ
**=DELTA(数値1,[数値2])**
　　数値1：比較する数値
　　数値2：比較するもう一方の数値、省略可能ですが省略すると0を指定したことになります。
Excel2003以前のバージョンでは、この関数が使用できず、エラー値 #NAME? が返される場合は、分析ツールアドインを組み込む必要があります。

数値1=数値2 のとき1を返し、それ以外の場合は0を返します。
2つの数値を比較して、同じである場合は1を、異なる場合は0を返します。

文字列の比較は EXACT関数を使います。

DELTA関数とEXACT関数の動作の違う例

			DELTA関数	EXACT関数
数値	123	100	0	FALSE
	200	200	1	TRUE
文字列	Excel	Word	#VALUE!	FALSE
	Excel	Excel	#VALUE!	TRUE
日付	2024/7/10	2024/7/1	0	FALSE
	2024/7/10	45483	1	TRUE
時刻	8:10	7:50	0	FALSE
	8:40	8:40	1	TRUE

【問題1】選択問題の正解数を計算したいと思います。
各問題は5択であり、解答がC列に入力されています。D列には正しい答えが入力されています。
正答であれば1、誤答であれば0をE列に返しなさい。

解答と答えを比較して正答であれば1、誤答であれば0をE列に返しなさい。
E13セルには正解数を求めなさい。

	B	C	D	E
2	問題No	解答	答え	採点
3	問1	5	3	0
4	問2	2	2	1
5	問3	1	3	0
6	問4	2	2	1
7	問5	3	3	1
8	問6	2	4	0
9	問7	5	4	0
10	問8	1	3	0
11	問9	3	3	1
12	問10	1	2	0
13		正解数		4

実際は解答と答えは同じシートに無いのが普通と思われます。
DELTA関数の問題を作成するのに苦し紛れで書いたものです。

【問題1解答例】

DELTA関数を使って求めてみました。
正解数はSUM関数で求めることができます。

	B	C	D	E
2	問題No	解答	答え	採点
3	問1	5	3	=DELTA(C3,D3)
4	問2	2	2	=DELTA(C4,D4)
5	問3	1	3	=DELTA(C5,D5)
6	問4	2	2	=DELTA(C6,D6)
7	問5	3	3	=DELTA(C7,D7)
8	問6	2	4	=DELTA(C8,D8)
9	問7	5	4	=DELTA(C9,D9)
10	問8	1	3	=DELTA(C10,D10)
11	問9	3	3	=DELTA(C11,D11)
12	問10	1	2	=DELTA(C12,D12)
13		正解数		=SUM(E3:E12)

【別解】
1. 等しいか否かですので　E3セルは　=C3=D3　と論理式で書くことができます。
  ただし、これではTRUE/FALSEを返しますので　=(C3=D3)*1　とすると1または0を返します。
2. EXACT関数は文字列の比較ですが、今回のケースでも使用できます。
  =EXACT(C3,D3)　とすると、TRUE/FALSEを返しますので=EXACT(C3,D3)*1　とすると1または0を返します。
3. E3:E12セルの計算をせずに直接正解数を求めることもできます。
  =SUMPRODUCT((C3:C12=D3:D12)*1)　とすると　4　が返ります。

【問題2】合計の結果が等しいか検算をしたいと思います。

E列の値とC:E列の合計が一致しているかを調べ、正しいときは「○」、正しくないときは「×」を返しなさい。

	B	C	D	E	F	G
2	氏名	国語	数学	英語	合計	検算
3	今田浩次	80	85	77	242	○
4	内田あかり	70	65	62	198	×
5	江藤公正	90	88	81	259	○
6	岡田太郎	55	62	79	196	○
7	川口宏	77	64	70	210	×
8	木村次郎	64	75	61	200	○

【問題2の解答例】

DELTA関数を使って求めてみました。

	B	C	D	E	F	G
2	氏名	国語	数学	英語	合計	検算
3	今田浩次	80	85	77	242	=IF(DELTA(F3,SUM(C3:E3)),"○","×")
4	内田あかり	70	65	62	198	=IF(DELTA(F4,SUM(C4:E4)),"○","×")
5	江藤公正	90	88	81	259	=IF(DELTA(F5,SUM(C5:E5)),"○","×")
6	岡田太郎	55	62	79	196	=IF(DELTA(F6,SUM(C6:E6)),"○","×")
7	川口宏	77	64	70	210	=IF(DELTA(F7,SUM(C7:E7)),"○","×")
8	木村次郎	64	75	61	200	=IF(DELTA(F8,SUM(C8:E8)),"○","×")

=IF(DELTA(F3,SUM(C3:E3))=1,"○","×")　とするのが普通だと思います。
Excelのワークシート関数では「0」はFALSEとみなし、それ以外はTRUEとみなします。
入力の手間を省くため、=IF(DELTA(F3,SUM(C3:E3)),"○","×")　と　=1 を省略することもできます。
下記のようなことで理解できると思います。

【問題例3】A,B,Cの3つの値が等しいか否かを調べなさい。
判定で3つの値が等しい場合は ○　を等しくない場合は　× を表示しなさい。
【問題3の解答例】　E3セルに　=IF(AND(DELTA(B3,C3),DELTA(C3,D3)),"○","×")　と入力しました。
B3セルとC3セルの値が等しい、C3セルとD3セルが等しい　という2つの条件を満たせば、3つの値が等しいことになります。

または、DELTA関数を使わず、=IF(AND(B3=C3,C3=D3),"○","×")　とすることもできます。

複数の関数を使う場合、関数の挿入ボタンから関数の引数ダイアログを使って数式を作成する方法

数式 =IF(DELTA(SUM(C3:E3),F3),"○","×")　を関数の挿入ボタンから関数の引数ダイアログを使って数式を作成する操作手順です。

関数の挿入ボタンをクリックします。
関数の挿入ダイアログが表示されますので、関数の分類で「すべて表示」を選択します。
関数名で　IF を選択します。
[OK]ボタンをクリックします。
数式バーに　=IF()　と表示されます。
IF関数の論理式にカーソルを表示し、名前ボックスで「その他の関数」をクリックします。
関数名で　DELTA を選択し、[OK]ボタンをクリックします。
数式バーには　=IF(DELTA())　と表示されます。
DELTA 関数の引数ダイアログが表示されます。
数値1にカーソルを表示し、名前ボックスで[その他の関数]を選択します。
関数の挿入で SUM を選択し、[OK]ボタンをクリックします。
数式バーには　=IF(DELTA(SUM()))　と表示されます。
SUM関数の引数ダイアログで　数値1に　C3:E3 を指定します。
数式バーには　=IF(DELTA(SUM(C3:E3)))　と表示されます。
数式バーの　DELTA 部分をクリックして、DELTA関数の引数ダイアログを表示します。
数値2に　F3 を指定します。
数式バーには　=IF(DELTA(SUM(C3:E3),F3))　と表示されます。
数式バーの　IF の部分をクリックして、IF関数の引数ダイアログを表示します。
真の場合に ○ 、偽の場合に　× を入力します。
数式バーに　=IF(DELTA(SUM(C3:E3),F3),"○","×")　と数式が完成できました。
[OK]ボタンをクリックします。
G3セルの数式が入力できました。
オートフィルで下方向へ数式をコピーして完成です。

スポンサードリンク

よねさんのWordとExcelの小部屋 » エクセル関数一覧表 » DELTA関数の使い方

PageViewCounter
Counter
Since2006/2/27