1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. LET関数の使い方(数式で名前・値の変数を定義する)

LET関数の使い方(数式で名前・値の変数を定義する):Excel関数

更新:2025/2/1;作成:2020/9/18

数式で変数を使用することができます　　　topへ
　レッツ
=LET(名前1,名前1の値,計算または名前2,[名前2の値,計算または名前3],・・・)

• LET関数をExcel for Microsoft365 で使用できるようになっていました。(記 2020/9/18)
  取り急ぎ、この新しい関数を使用できるようになったことのご報告です、細かな使い方は順次追加していこうと思います。
  ちなみに、Excelのバージョンは 2008 (ビルド 13127.20408 クイック実行) となっていました。
• LET関数はExcel for Microsoft365,Excel2021,Excel2024で使用できます。

LET関数の構文と引数

• 構文は英文では下のように書かれています、
  = LET (name1、name_value1、calculation_or_name2、[name_value2、calculation_or_name3...])
  

  引数	説明
  名前1 name1	最初に割り当てる名前。 文字で始まる必要があります。 数式の出力であったり、範囲の構文と競合していたりしてはなりません。
  名前1の値 name_value1	名前1に割り当てられている値
  計算 calculation	LET 関数内のすべての名前を使用する計算。 LET 関数の最後の引数でなければなりません。
  または 名前2	2つ目の名前 を使い場合は名前2の値,計算が必要になります。

• LET関数の構文は下図のように、関数のヒント、ヘルプ内での解説を使用しています。
  
• LET関数は「論理」の中に分類されています。
  
  
  

LET関数の使用例

• 非常に簡単な例です、変数名を x として、この変数 ｘ の値を 5 としています。
  計算式を x*100 としています。
  計算結果は500となります。
• 名前2を使った例です。
  名前2に y 、名前2の値に 10 、計算式を x*y　としました。
  計算結果は50となります。
• 

LET関数を使った数式の作成例1

• 消費税の軽減税率8%と消費税率10%の計算をLET関数を使ってみました。
  数式は
  =LET(軽減税率,8%,消費税率,10%,
  ROUNDDOWN(C2*
  (IF(D2="軽減税率",軽減税率,IF(D2="消費税率",消費税率,0))),0))
  としました。
  さて、可読性が高くなっていますでしょうか?・・・センスが問われそうな気がします。
  

LET関数を使った数式の作成例2

• 下表から売上数の多い順に果物の名前を表示する数式を作成してみます。
  

  	B	C	D
  2	日付	果物	売上数
  3	2025/1/10	みかん	36
  4	2025/1/14	ブドウ	45
  5	2025/1/18	りんご	26
  6	2025/1/22	いちご	22
  7	2025/1/26	みかん	24
  8	2025/1/30	ブドウ	29
  9	2025/2/3	いちご	45
  10	2025/2/7	りんご	11
  11	2025/2/11	みかん	11
  12	2025/2/15	りんご	19
  13	2025/2/19	いちご	17
  14	2025/2/23	ブドウ	15
  15	2025/2/27	みかん	22
  16	2025/3/3	りんご	36
  17	2025/3/7	みかん	12

• 重複のない果物のリスト(F3セル)は　=UNIQUE(C3:C17)　として求めることができます。
  果物の売上数(G3セル)は　=SUMIF(C3:C17,F3#,D3:D17)　で計算できます。
  売上数の多い順に果物の名前を表示する(H3セル)には　=SORTBY(F3#,G3#,-1)　とすることができます。
  この最後のリスト H3:H6 が求めたいリストになります。
  
• これを1つの数式で求めると
  =SORTBY(UNIQUE(C3:C17),SUMIF(C3:C17,UNIQUE(C3:C17),D3:D17),-1)
  となります。
  
• この計算を LET関数で作成してみます。
  C3:C17を範囲1
  D3:D17を範囲2
  UNIQUE(範囲1)で取り出すリストを 果物
  と名前を設定して、LET関数で書くと
  =LET(範囲1,C3:C17,
  範囲2,D3:D17,
  果物,UNIQUE(範囲1),
  となります。
• 最後に、計算式　SORTBY(果物,SUMIF(範囲1,果物,範囲2),-1))　を書けば
  =LET(範囲1,C3:C17,
  範囲2,D3:D17,
  果物,UNIQUE(範囲1),
  SORTBY(果物,SUMIF(範囲1,果物,範囲2),-1))
  となります。
  
  

LET関数を使った数式の作成例3

• リストをテーブルに変換して　Tbl_売上表　としています。
  LET関数を使って、果物のリストと売上数を計算してみます。
  
• 果物の順番はこのような感じになりました。
  上のLET関数の数式と同じですが、テーブルに変換していますので表記がちょっと異なっています。
  =LET(範囲1,Tbl_売上表[果物],
  範囲2,Tbl_売上表[売上数],
  果物,UNIQUE(範囲1),
  SORTBY(果物,SUMIF(範囲1,果物,範囲2),-1))
  
• 売上数の計算は以下のようにしました。
  =LET(範囲1,Tbl_売上表[果物],
  範囲2,Tbl_売上表[売上数],
  果物,UNIQUE(範囲1),
  並べ替え,SORTBY(果物,SUMIF(範囲1,果物,範囲2),-1),
  SUMIF(範囲1,並べ替え,範囲2))
  
• HSTACK関数を使って、並べ替えと売上を2列に並べています。
  この数式は Excel for Microsoft365で使用できます。
  =LET(範囲1,Tbl_売上表[果物],
  範囲2,Tbl_売上表[売上数],
  果物,UNIQUE(範囲1),
  並べ替え,SORTBY(果物,SUMIF(範囲1,果物,範囲2),-1),
  売上,SUMIF(範囲1,並べ替え,範囲2),
  HSTACK(並べ替え,売上))
  

スポンサードリンク

PageViewCounter

Since2006/2/27