1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. FIND関数、SEARCH関数で文字列を検索する

FIND関数、SEARCH関数で文字列を検索する:Excel関数

• エクセルで文字列のデータを操作する時に使用するワークシート関数です。 文字を検索する関数(FIND関数,SEARCH関数)について説明しています。

更新:2024/2/27;作成:2005/9/24

文字列を検索するFIND関数とSEACH関数の違い

• 	FIND関数	SEARCH関数
  大文字と小文字の区別	〇	×
  ワイルドカードの使用	×	〇

FIND関数は大文字と小文字の区別をします。SEARCH関数は大文字と小文字の区別をしません。

• 下図の3行目のように、FIND関数では検索する文字がすべて大文字のEXCELはExcelとは異なると判定して、検索文字が存在しないとエラーを返します。
  一方、SEARCH関数では大文字のEXCELとExcelは同じとみなし、11という値を返しています。
  つまり、　Excel　という文字を検索するのに、SEARCH関数では EXCELでも ExcelでもOKですが、FIND関数では ExcelはOKですが、EXCELはNGということです。
  
  下図の例で、小文字の e を検索すると、FIND関数ではMicrosoft Excelの 14番目の e の位置を返します。
  SEARCH関数では 11番目の　Excel の大文字の E の位置を返します。(最初に出てくる e の位置で、大文字小文字は区別しないので)
  

FIND関数はワイルドカードは使用できません。SEARCH関数はワイルドカード（*や?)が使用できます。

• 志布志市　で検索するのは　FIND関数もSEACH関数も同じく可能です。
  ところが、志布志市*　とワイルドカードを使用した検索はFIND関数ではNGで(エラーとなります)、SEARCH関数ではOKです。
  

文字列が開始位置から何番目にあるかを返します　　　topへ
　ファインド
=FIND(検索文字列,対象,[開始位置])
　　(注)　英字の大文字と小文字を区別できる代わりに、ワイルドカード文字を使用することができません。

引数の開始位置について

• 開始位置は省略できます。省略すると1と同じ扱いになります。
  開始位置を2とすると、「鹿児島県鹿児島市山下町」の2文字目から検索するので2つ目の「鹿児島」の最初の位置「5」を返します。
  

• 問題1：下表のB列の住所から県名を除いた住所をC列に取り出しなさい。
  

  	B	C
  2	鹿児島県指宿市十町	指宿市十町
  3	宮崎県都城市姫城町	都城市姫城町
  ４	東京都新宿区西新宿	#VALUE!

• 問題1の解答例

  数式　=FIND("県",B2)　で　県の位置を求めます。県の位置は 4 となります。
  
  県の位置から後ろの文字を取り出せばよいので、=RIGHT(B2,LEN(B2)-FIND("県",B2))　としました。
  LEN(B2)で文字列の文字数を数えています。文字列の文字数から"県"の位置を差し引くと、残りの文字の数が求められます。
  RIGHT関数で「県」以降の残りの文字を取り出します。
  

  または、=MID(B2,FIND("県",B2)+1,LEN(B2))　として求めることもできます。
  

  「県」を含まない文字列の場合はエラー値　#VALUE!　が返されます。
  

都道府県名を削除する数式と都道府県名を取り出す数式

• 都道府県が混在している場合は、「県」が4文字目にある場合は5文字目以降を取り出し、4文字目に「県」がない場合は4文字目以降を取り出します。
  =IF(MID(B2,4,1)="県",MID(B2,5,LEN(B2)),MID(B2,4,LEN(B2)))　とすることができます。
  都道府県を取り出す場合は、「県」が4文字目にある場合は左から4文字を取り出し、4文字目に「県」がない場合は左から3文字を取り出します。
  =IF(MID(B2,4,1)="県",LEFT(B2,4),LEFT(B2,3))　となります。
  
• RIGHT関数、MID関数、LEN関数の使い方は 文字列を取り出す関数の使い方(LEFT関数、RIGHT関数、MID関数):Excel関数　をご覧ください。

• 問題2 下表に志布志市 市役所支所の住所が入力してあります。2つ目の「志布志」以下を取り出しなさい。
  

  	B	C
  2	鹿児島県志布志市志布志町志布志二丁目1番1号	志布志町志布志二丁目1番1号

• 問題2の解答例

  C2セルで1つめの志布志の位置を求めます。数式は　=FIND("志布志",B2)
  C3セルでは2つ目の「志布志」の位置を求めています。1つめの「志布志」の次から検索を開始しますので、
  =FIND("志布志",B2,FIND("志布志",B2)+1)　と 開始位置は +1 した位置から求めます。
  よって、MID関数で2つ目の「志布志」以降も文字列を取り出す数式　
  =MID(B2,FIND("志布志",B2,FIND("志布志",B2)+1),LEN(B2))　で求めました。
  

文字列が開始位置から何バイト目にあるかを返します　　　topへ
　ファインド ビー
=FINDB(検索文字列,対象,開始位置)
　　(注)　英字の大文字と小文字を区別できる代わりに、ワイルドカード文字を使用することができません。

• FIND関数が文字数で文字位置を求めるのに対し、FINDB関数はバイト数で求めます。
• 検索文字を変えて、FIND関数とFINDB関数とで返る値の違いを下図に示しています。
  D2セルの数式は =FIND(C2,$B$2) 、E2セルの数式は　=FINDB(C2,$B$2) としています。
  • E2セルが11となるのは、「用紙サイズ」が2バイト文字なので 5文字*2バイト=10　となり、「A」は11バイト目といった計算になります。
    漢字やひらがなは2バイト、半角英数や半角カタカナは1バイトと計算されます。
  

文字列が開始位置から何番目にあるかを返します　　　topへ
　サーチ
=SEARCH(検索文字列,対象,開始位置)
　　(注)　英字の大文字と小文字を区別できませんが、ワイルドカード文字を使用できます。

• 問題3：SEACH関数を使って、B列のサイズ(数値)をC,D列に書き出しなさい。
  

  	B	C	D
  2	201×297	201	297
  3	257×364	257	364

• 問題3の解答例

  B列のサイズの区切る文字　×の位置を探すには　SEARCH("×",B2)　とします。
  前の数値は左から　×の前までを取り出せばよいので、=LEFT(B2,SEARCH("×",B2)-1)　としました。
  後ろの数字は　×の次の位置から最後までを取り出せばよいので、　=MID(B2,SEARCH("×",B2)+1,LEN(B2))　としました。
  取り出す文字の数は数えてもよいのですが、文字列と同じ数を指定するのが楽なので、LEN(B2)　としています。
  

  	B	C	D
  2	201×297	=LEFT(B2,SEARCH("×",B2)-1)	=MID(B2,SEARCH("×",B2)+1,LEN(B2))
  3	257×364	=LEFT(B3,SEARCH("×",B3)-1)	=MID(B3,SEARCH("×",B3)+1,LEN(B3))

• なお、この数式で求めた結果は文字列になっています。
  数値に直すには　=LEFT(B2,SEARCH("×",B2)-1)*1　のように乗算をすると、Excelが数値に変換してくれます。
  または、=VALUE(LEFT(B2,SEARCH("×",B2)-1))　のようにVALUE関数を使います。

• 問題4：SEACH関数を使って、B列のサイズをC,D列に書き出しなさい。
  

  	B	C	D
  2	201*297	201	297

• 問題4の解答例

  B列のサイズの区切り文字は　*(アスタリスク)が使われています。
  このアスタリスクはワイルドカードにも使われている文字なので、特殊な検索が必要になります。
  *を検索するには、アスタリスクの前にチルダを付けて　~*　とします。数式は　SEARCH("~*",B2)　とします。
  

  	B	C	D
  2	201*297	=LEFT(B2,SEARCH("~*",B2)-1)	=MID(B2,SEARCH("~*",B2)+1,LEN(B2))

文字列が開始位置から何バイト目にあるかを返します　　　topへ
　サーチ ビー
=SEARCHB(検索文字列,対象,開始位置)
　　(注)　英字の大文字と小文字を区別できませんが、ワイルドカード文字を使用できます。

• SEARCH関数が文字数で文字位置を求めるのに対し、SEARCHB関数はバイト数で求めます。
• 検索文字を変えて、SEARCH関数とSEARCHB関数とで返る値の違いを下図に示しています。
  D2セルの数式は =SEARCH(C2,$B$2) 、E2セルの数式は　=SEARCHB(C2,$B$2) としています。
  

スポンサードリンク

PageViewCounter

Since2006/2/27