文字列操作の関数(2):Excel VBA関数

スポンサードリンク

StrComp	StrConv	StrReverse
Asc	AscW	Chr	ChrW
Space	String	Split	Join	Filter

StrComp関数　　　 Topへ

文字列を比較します。

構文：StrComp(string1, string2[, compare])

string1：必ず指定します。文字列を指定します。
string2：必ず指定します。文字列を指定します。

compare：省略可能です。文字列比較のモードを指定します。
compare が Null 値の場合は、エラーが発生します。
compare を省略すると、Option Compare ステートメントの設定により比較モードが決まります。

定数	値	説明
vbUseCompareOption	-1	Option Compare ステートメントの設定を使用して比較を行います。
vbBinaryCompare	0	バイナリモードの比較を行います。
vbTextCompare	1	テキストモードの比較を行います。
vbDatabaseCompare	2	Microsoft Access の場合のみ有効。データベースに格納されている設定に基づいて比較を行います。

結果

内容	戻り値
string1 は string2 未満	-1
string1 と string2 は等しい	0
string1 は string2 を超える	1
String1 または string2 は Null 値	Null 値

使用例

Sub test1()
　Dim myStr1 As String, myStr2 As String
　　myStr1 = "EXCEL"
　　myStr2 = "Excel"
　　Range("A1").Value = StrComp(myStr1, myStr2, vbBinaryCompare)
　　Range("A2").Value = StrComp(myStr1, myStr2, vbTextCompare)
　　Range("A3").Value = StrComp(myStr1, myStr2)
End Sub

A1セルには「-1」が返ります。
A2セルには「0」が返ります。
A3セルには「-1」が返ります。

StrConv関数　　　 Topへ

文字列を指定した文字列に変換します。

構文：StrConv(string, conversion, LCID)

string：必ず指定します。変換する文字列を指定します。

conversion：必ず指定します。整数型 (Integer) の値を指定します。実行する変換の種類の値の合計を指定します。

定数	値	内容
vbUpperCase	1	文字列を大文字に変換します。
vbLowerCase	2	文字列を小文字に変換します。
vbProperCase	3	文字列の各単語の先頭の文字を大文字に変換します。
vbWide*	4*	半角文字 (1 バイト) を全角文字 (2 バイト) に変換します。
vbNarrow*	8*	全角文字 (2 バイト) を半角文字 (1 バイト) に変換します。
vbKatakana**	16**	ひらがなをカタカナに変換します。
vbHiragana**	32	カタカナをひらがなに変換します。
vbUnicode	64	システムの既定のコードページを使って文字列を Unicode に変換します。 Macintosh. では使用できないそうです
vbFromUnicode	128	文字列を Unicode からシステムの既定のコードページに変換します。 Macintosh. では使用できないそうです

* 国別情報の設定が中国、韓国、および日本の場合に適用されます。
** 国別情報の設定が日本の場合のみ有効です。

LCID：省略可能です。システムとは異なる国別情報識別子 (LCID) を指定できます。既定値はシステムが使用する LCID です。

使用例

Sub test2()
　Dim myStr1 As String
　　myStr1 = "Excel"
　　Range("B1").Value = StrConv(myStr1, 1)
　　Range("B2").Value = StrConv(myStr1, 2)
　　Range("B3").Value = StrConv(myStr1, 4)
End Sub

Ｂ1セルには「EXCEL」が返ります。
Ｂ1セルには「excel」が返ります。
Ｂ1セルには「Ｅｘｃｅｌ」が返ります。

StrReverse関数　　　 Topへ

文字の並びを逆にした文字列を返します。
使用例
- Sub test3()
  　　Range("A1").Value = StrReverse("ABCD")
  End Sub
- A1セルには「DCBA]が返ります。

Asc関数　　　 Topへ

文字列の先頭の文字コードを返します。
構文：Asc(string)
使用例
- Sub test4()
  　Dim myStr1 As String
  　　myStr1 = "ABC"
  　　Range("C1").Value = Asc(myStr1)
  End Sub
- C1セルには「65」が返ります。

AscW関数　　　 Topへ

Unicode文字セットの文字コードを返します。
Visual Basic for the Macintosh では、Unicode 文字列をサポートしていません。
構文：AscW(string)
使用例
- Sub test5()
  　Dim myStr1 As String
  　　myStr1 = "愛"
  　　Range("C2").Value = AscW(myStr1)
  End Sub
- C2セルには「24859」が返ります。

Chr関数　　　 Topへ

指定した文字コードに対応する文字を返します。
構文：Chr(charcode)
制御コードは以下のようになります。
Chr(9)：タブ
Chr(10)：ラインフィード文字
Chr(13)：キャリッジリターン
使用例
- Sub test6()
  　　Range("C3").Value = Chr(65)
  End Sub
- C3セルには「A」が返ります。

ChrW関数　　　 Topへ

指定した文字コードに対応するUnicode文字セットの文字を返します。
Visual Basic for the Macintosh では、Unicode 文字列をサポートしていません。
構文：Chr(charcode)
使用例
- Sub test7()
  　　Range("C4").Value = ChrW(24859)
  End Sub
- C3セルには「愛」が返ります。

Space関数　　　 Topへ

スペースからなる文字列を返します。
構文：Space(number)
使用例
- Sub test8()
  　　Range("A1").Value = Date & Space(2) & Time
  End Sub
- A1セルには「2008/11/2　10：20：40」のように日付と時刻の間にスペースが2個入ります。

String関数　　　 Topへ

指定した文字コード (ASCII またはシフト JIS コード) の文字、または文字列の先頭文字を、指定した文字数だけ並べた文字列を返します。
String(number, character)
- number：必ず指定します。文字をいくつ並べるのかを指定します。
- character：必ず指定します。文字の文字コード、または文字列式を指定します。
使用例
- Sub test9()
  　　Range("A1").Value = String(5, "A")
  　　Range("A2").Value = String(5, 66)
  End Sub
- A1セルには「AAAAA」が返ります。
  B1セルには「BBBBB]が返ります。

Split関数　　　 Topへ

Excel2000以降で使用可能です。
各要素ごとに区切られた文字列から 1 次元配列を作成します。

構文：Split(expression[, delimiter[, limit[, compare]]])

expression：必ず指定します。文字列と区切り文字を含んだ文字列式を指定します。
delimiter：省略可能です。文字列の区切りを識別する文字を指定します。
limit：省略可能です。返す配列の要素数を指定します。-1 を指定すると、すべての文字列を含んだ配列を返します。

compare：省略可能です。文字列式を評価するときに使用する文字列比較のモードを表す数値を指定します。

定数	値	説明
VbUseCompareOption	-1	Option Compare ステートメントの設定を使用して比較を行います。
vbBinaryCompare	0	バイナリモードで比較を行います。
vbTextCompare	1	テキストモードで比較を行います。
vbDatabaseCompare	2	Microsoft Access の場合のみ有効。データベースに格納されている設定に基づいて比較を行います。

使用例

Sub test10()
　Dim myStr As String, myData
　Dim i As Integer
　　myStr = "A,B,C,B,E"
　　myData = Split(myStr, ",")
　　For i = 0 To UBound(myData)
　　　　Cells(i + 1, 1).Value = myData(i)
　　Next i
End Sub

A1:E1セルにそれぞれ「A」「B」「C」「D」「E」を返します。

Join関数　　　 Topへ

Excel2000以降で使用可能です。
配列に含まれる各要素の文字列を結合した文字列を返します。
構文：Join(sourcearray [, delimiter])
- sourcearray：必ず指定します。結合する文字列を含む 1次元配列を指定します。
- delimiter：省略可能です。戻り値となる文字列を区切るのに使用する文字を指定します。
  省略すると、スペース (" ") が使用されます。
  長さ 0 の文字列 ("") である場合は、リスト内の文字列が区切り文字なしで結合されます。

使用例

A1:E1セルにそれぞれ「A」「B」「C」「D」「E」を入力してから実行します。

Sub test11()
　Dim myStr As String, myData(4)
　Dim i As Integer
　　For i = 1 To 5
　　　　myData(i - 1) = Cells(i, 1).Value
　　Next i
　　Range("B1").Value = Join(myData, "_")
End Sub

B1セルに「A_B_C_D_E」が返ります。

Filter関数　　　 Topへ

Excel2000以降で使用可能です。
配列の中から条件に一致する要素を返します。

構文：Filter(sourcesrray, match[, include[, compare]])

sourcearray：検索元の1次元配列を指定します。
match：検索する文字列を指定します。
include：省略可能です。Trueの場合、引数matchが含まれる要素を返します。
偽(False)の場合、引数matchが含まれない配列の要素を返します。

ｃompare：省略可能です。文字列式を評価するときに使用する文字列比較のモードを表す数値を指定します。

定数	値	説明
VbUseCompareOption	-1	Option Compare ステートメントの設定を使用して比較を行います。
vbBinaryCompare	0	バイナリモードで比較を行います。
vbTextCompare	1	テキストモードで比較を行います。
vbDatabaseCompare	2	Microsoft Access の場合のみ有効。データベースに格納されている設定に基づいて比較を行います。

設定する値については、次の「設定値」を参照してください。

使用例

A列に商品コードが入力されています。「A」を含む商品コードをC列に取り出します。

	A
1	商品コード
2	B001
3	B005
4	A008
5	A002
6	C002
7	D005
8	A007
9	B002
10	C001

一旦、セル範囲A2:A10を配列「myData」に取り出していますが、これは2次元配列なので、1次元配列「Flt_S」に配置しなおしています。
Filter関数で1次元配列「Flt_E」に該当する要素を取り出した後、シートのセルへ書き出しています。
- ちょっとややこしいのは、配列「myData」のインデックスは1から始まりますが、「Flt_E」は0からになります。
  Flt_SはReDim Flt_S(1 To UBound(myData))で、1からに指定しています。単にmyDataに合わせただけです。

Sub test12()
　　Dim myData
　　Dim Flt_S()
　　Dim Flt_E
　　Dim i As Long
　　　　myData = Range("A2", Range("A" & Rows.Count).End(xlUp))
　　　　ReDim Flt_S(1 To UBound(myData))
　　　　For i = LBound(myData) To UBound(myData)
　　　　　　Flt_S(i) = myData(i, 1)
　　　　Next i
　　　　Flt_E = Filter(Flt_S, "A", True)
　　　　For i = LBound(Flt_E) To UBound(Flt_E)
　　　　　　Cells(i + 1, 3) = Flt_E(i)
　　　　Next i
End Sub

実行後は下表のようになります。

	A	B	C
1	商品コード		A008
2	B001		A002
3	B005		A007
4	A008
5	A002
6	C002
7	D005
8	A007
9	B002
10	C001

スポンサードリンク

よねさんのWordとExcelの小部屋｜Excel(エクセル) VBA関数：目次｜文字列操作の関数(2)

PageViewCounter
　 Counter
　Since2006/2/27