セル内の文字の一部だけ色やサイズを変える:Excel VBA入門

スポンサードリンク

はじめに

セルに文字列が入力されていて、特定の文字列だけ目立たせたい・・・色を変える方法です。
一般機能では対象の文字列を選択しておいて、フォントの色を変更すればできます。

セル内の数字0～9の色やサイズを変える例

セルに入力された文字列に数字0,1,2・・・,8,9が含まれていたら、その数字を赤色にし、フォントサイズを14ポイントに変更してみます。
コードは標準モジュールに書きます。

【コード例A】

Like演算子を利用しています。
元の書式はフォントの色：自動、フォントサイズ：11point　とします。
数字をフォントの色：赤、フォントサイズ14pointに変更します。

Sub mojiiro()
　Dim myRng As Range
　Dim myStr As String
　Dim i As Integer
　　'----元の書式に設定する
　　For Each myRng In Selection
　　　　With myRng.Font
　　　　　　.ColorIndex = xlColorIndexAutomatic
　　　　　　.Size = 11
　　　　End With
　　　　’----セルの文字列を1文字ずつ順番に調べる
　　　　For i = 1 To Len(myRng)
　　　　　　myStr = Mid(myRng.Value, i, 1)
　　　　　　'----数字があったら書式を変更する
　　　　　　If myStr Like "[0-9]" Then
　　　　　　　　With myRng.Characters(Start:=i, Length:=1).Font
　　　　　　　　　　.ColorIndex = 3
　　　　　　　　　　.Size = 14
　　　　　　　　End With
　　　　　　End If
　　　　Next i
　　Next myRng
End Sub

実行前

↓
実行後

【コード例B】

正規表現(RegExpオブジェクト)を使ってみた例です
- RegExpオブジェクトにまとめていますので参照してください。

Sub mojiiro2()
　Dim RE, c
　Dim myRng As Range
　Dim myStr As String
　Dim i As Integer
　　Set RE = CreateObject("VBScript.RegExp")
　　With RE
　　　　.Pattern = "[0-9]"　　'----パターンを設定
　　　　.IgnoreCase = True
　　　　.Global = False

　　　　For Each myRng In Selection
　　　　　　For i = 1 To Len(myRng)
　　　　　　　　myStr = Mid(myRng.Value, i, 1)
　　　　　　　　If .Test(myStr) Then
　　　　　　　　　　With myRng.Characters(Start:=i, Length:=1).Font
　　　　　　　　　　　　.ColorIndex = 3
　　　　　　　　　　　　.Size = 14
　　　　　　　　　　End With
　　　　　　　　End If
　　　　　　Next i
　　　　Next myRng
　　End With
　Set RE = Nothing
End Sub

実行前

↓
実行後

【コード例C】

数字が2組あるとき、最初の1組だけ色を変える

Sub mojiiro3()
　Dim RE, c
　Dim myRng As Range
　Dim myStr As String
　Dim i As Integer
　　Set RE = CreateObject("VBScript.RegExp")
　　With RE
　　　　.Pattern = "[0-9]+"
　　　　.Global = False
　　　　For Each myRng In Selection
　　　　　　For Each c In .Execute(myRng.Value)
　　　　　　　　With myRng.Characters(c.firstindex + 1, c.Length).Font
　　　　　　　　　　.ColorIndex = 3
　　　　　　　　　　.Size = 14
　　　　　　　　End With
　　　　　　Next c
　　　　Next myRng
　　End With
　Set RE = Nothing
End Sub

実行前

↓
実行後

スポンサードリンク

よねさんのWordとExcelの小部屋｜Excel(エクセル) VBA入門：目次｜セル内の文字の一部だけ色やサイズを変える

PageViewCounter
　 Counter
　Since2006/2/27