CSVファイルを読み込む:Excel VBA入門

スポンサードリンク

CSVファイルを読み込む　　　topへ

CSVファイルをExcelのシートに書き出す方法です。
まずは、下記のように単に　,(カンマ)で区切られたデータを読み込んでみたいと思います。
下図はCSVファイルをメモ帳で開いた様子です。

コードは下表のようにしました。

Sub Sample0()
　　Dim myFileName As Variant
　　Dim Fcn As Long
　　Dim i As Long
　　Dim buf As String
　　Dim tmp As Variant

　　myFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　Title:="CSVファイルの選択")
　　If myFileName = False Then
　　　　　Exit Sub
　　End If

　　With Worksheets("Sheet1")

　　　　Open myFileName For Input As #1

　　　　Do Until EOF(1)
　　　　　　Line Input #1, buf
　　　　　　Fcn = Fcn + 1
　　　　　　tmp = Split(buf, ",")

　　　　'書き出し
　　　　　　For i = LBound(tmp) To UBound(tmp)
　　　　　　　　.Cells(Fcn + 1, i + 1).Value = tmp(i)
　　　　　　Next i

　　　　Loop
　　　　Close #1

　　End With
End Sub

実行後のExcelのシート
- 1行目の列見出しは事前に入力しています。
  コードでは2行目以降にCSVファイルのデータを書き出しています。

A列は頭に0が付いた文字列にしたい、またB列は文字列になっているのでシリアル値にしたい　と思います。
コードは下表のように赤字の部分を修正しました。

頭にゼロが付いているA列は　セルの表示形式を文字列にしてから読み込んだデータを文字列にして入力しています。
日付のB列は　表示形式を日付の形式にしてから、読み込んだデータを日付データにして入力しています。

Sub Sample0a()
　　Dim myFileName As Variant
　　Dim Fcn As Long
　　Dim i As Long
　　Dim buf As String
　　Dim tmp As Variant

　　myFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　Title:="CSVファイルの選択")
　　If myFileName = False Then
　　　　　Exit Sub
　　End If

　　With Worksheets("Sheet1")

　　　　Open myFileName For Input As #1

　　　　Do Until EOF(1)
　　　　　　Line Input #1, buf
　　　　　　Fcn = Fcn + 1
　　　　　　tmp = Split(buf, ",")

　　　　'書き出し
　　　　　　.Cells(Fcn + 1, 1).NumberFormatLocal = "@"
　　　　　　.Cells(Fcn + 1, 1).Value = CStr(tmp(0))
　　　　　　.Cells(Fcn + 1, 2).NumberFormatLocal = "yyyy年m月d日"
　　　　　　.Cells(Fcn + 1, 2).Value = DateValue(tmp(1))

　　　　　　For i = 2 To UBound(tmp)
　　　　　　　　.Cells(Fcn + 1, i + 1).Value = tmp(i)
　　　　　　Next i

　　　　Loop
　　　　Close #1

　　End With
End Sub

実行後の状態は下図のようになります。

データが　""(ダブルクォーテーション)でくくられているケース　　　topへ

CSVファイルのデータが""(ダブルクォーテーション)でくくられているケースがありました。
行の最初のデータが""(ダブルクォーテーション)でくくられています。
上記の　Sample0aを実行すると、""(ダブルクォーテーション)が表示されてしまいました。

最初のデータについて、最初と最後の文字が　" であったときは、途中の文字だけを　Mid関数で取り出すようにしました。

Sub Sample0b()
　　Dim myFileName As Variant
　　Dim Fcn As Long
　　Dim i As Long
　　Dim buf As String
　　Dim tmp As Variant

　　myFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　Title:="CSVファイルの選択")
　　If myFileName = False Then
　　　　　Exit Sub
　　End If

　　With Worksheets("Sheet1")

　　　　Open myFileName For Input As #1

　　　　Do Until EOF(1)
　　　　　　Line Input #1, buf
　　　　　　Fcn = Fcn + 1
　　　　　　tmp = Split(buf, ",")

　　　　'書き出し
　　　　　　If Left(tmp(0), 1) = """" And Right(tmp(0), 1) = """" Then
　　　　　　　　tmp(0) = Mid(tmp(0), 2, Len(tmp(0)) - 2)
　　　　　　End If

　　　　　　.Cells(Fcn + 1, 1).NumberFormatLocal = "@"
　　　　　　.Cells(Fcn + 1, 1).Value = CStr(tmp(0))
　　　　　　.Cells(Fcn + 1, 2).NumberFormatLocal = "yyyy年m月d日"
　　　　　　.Cells(Fcn + 1, 2).Value = DateValue(tmp(1))

　　　　　　For i = 2 To UBound(tmp)
　　　　　　　　.Cells(Fcn + 1, i + 1).Value = tmp(i)
　　　　　　Next i

　　　　Loop
　　　　Close #1

　　End With
End Sub

実行後の状態：A列の""(ダブルクォーテーション)を消すことができました。

データが　""(ダブルクォーテーション)でくくられ　,(カンマ)が含まれているケース　　　topへ

データが　""(ダブルクォーテーション)でくくられ　,(カンマ)が含まれているケースがありました。
Excelのシートでセルの表示形式に桁区切りを設定している状態で、CSVファイルとして書き出すとこのようなデータになるようです。
ここでは下図のようなデータを使っています。
"1,520"　や　"1,320,550" といったようなデータがあります。
上記のSample0b　を実行すると、　,カンマで区切られてしまいます。
例えば、　"1,520"　は　"1　と　520"　の2つのデータに区切られています。
"1,320,550" は　"1　と　320　と　550" の3つのデータに区切られています。

データの最初が　"(ダブルクォーテーション)　で始まっていて、最後に"(ダブルクォーテーション)で終わっているデータまでは1つとしてまとめる必要があると考えました。

読み込み時の配列に読み込んだデータ　tmp　を"の状態に応じて　配列mp2　へまとめ直しています。

Sub Sample1()
　　Dim myFileName As Variant
　　Dim Fcn As Long
　　Dim i As Long, j As Long
　　Dim buf As String
　　Dim tmp As Variant
　　Dim tmp2() As Variant
　　Dim cnt As Integer
　　Dim myflag As Boolean

　　　　myFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　Title:="CSVファイルの選択")
　　　　If myFileName = False Then
　　　　　　Exit Sub
　　　　End If

　　With Worksheets("Sheet1")

　　　　Open myFileName For Input As #1

　　　　Do Until EOF(1)
　　　　　　Line Input #1, buf
　　　　　　Fcn = Fcn + 1
　　　　　　tmp = Split(buf, ",")
　　　　　　myflag = False
　　　　　　cnt = 0

　　　　　　For i = LBound(tmp) To UBound(tmp)

　　　　　　　　If myflag = False And Left(tmp(i), 1) = """" And Right(tmp(i), 1) = """" Then
　　　　　　　　　　cnt = cnt + 1
　　　　　　　　　　ReDim Preserve tmp2(cnt)
　　　　　　　　　　tmp2(cnt) = Mid(tmp(i), 2, Len(tmp(i)) - 2)

　　　　　　　　ElseIf myflag = False And Left(tmp(i), 1) <> """" And Right(tmp(i), 1) <> """" Then
　　　　　　　　　　cnt = cnt + 1
　　　　　　　　　　ReDim Preserve tmp2(cnt)
　　　　　　　　　　tmp2(cnt) = tmp(i)

　　　　　　　　ElseIf Left(tmp(i), 1) = """" And Right(tmp(i), 1) <> """" Then
　　　　　　　　　　cnt = cnt + 1
　　　　　　　　　　ReDim Preserve tmp2(cnt)
　　　　　　　　　　tmp2(cnt) = Mid(tmp(i), 2, Len(tmp(i)))
　　　　　　　　　　myflag = True

　　　　　　　ElseIf myflag = True And Left(tmp(i), 1) <> """" And Right(tmp(i), 1) <> """" Then
　　　　　　　　　tmp2(cnt) = tmp2(cnt) & tmp(i)

　　　　　　　ElseIf myflag = True And Left(tmp(i), 1) <> """" And Right(tmp(i), 1) = """" Then
　　　　　　　　　tmp2(cnt) = tmp2(cnt) & Left(tmp(i), Len(tmp(i)) - 1)
　　　　　　　　　myflag = False
　　　　　　　End If

　　　　　　Next i

　　　　　　'書き出し
　　　　　　　　For i = 1 To UBound(tmp2)
　　　　　　　　　　.Cells(Fcn + 1, i).Value = tmp2(i)
　　　　　　　　Next i

　　　　Loop
　　　　Close #1

　　End With
End Sub

実行後の状態
- 書き出し部分は状況に応じて　Sample0a～0b　のような対処を行います。
  ここでは何も処理はしていません。
  ここの目的はD,F列の数値の書き出し方です。

スポンサードリンク

よねさんのWordとExcelの小部屋｜Excel(エクセル)講座の総目次｜Excel(エクセル) VBA入門：目次｜CSVファイルを読み込む

PageViewCounter
　 Counter
　Since2006/2/27

CSVファイルを読み込む:Excel VBA入門

CSVファイルを読み込む topへ

データが ""(ダブルクォーテーション)でくくられているケース topへ

データが ""(ダブルクォーテーション)でくくられ ,(カンマ)が含まれているケース topへ

CSVファイルを読み込む　　　topへ

データが　""(ダブルクォーテーション)でくくられているケース　　　topへ

データが　""(ダブルクォーテーション)でくくられ　,(カンマ)が含まれているケース　　　topへ