重複しない2組のデータのリストを作成する:Excel VBA入門

ドロップダウンリストの連動をしたいときなどに利用するデータリストをVBAを使って作成してみます。

スポンサードリンク

はじめに　　　Topへ

種類と品名などが既に入力されているケースで、種類と品名の組み合わせのリストを作成したい場合があります。
例えば、入力規則のドロップダウンリストを作成するときなどの参照するリストとして使用したりします。
- 下図のようなデータが既に作成されています。
- VBAを使って下図のようなリストを作成します。
  横方向に「種類」、縦方向へ「品名」を配置したリストになっています。
ここではDictionaryオブジェクトを使って重複しないデータを取り出してリストを作成してみます。
- ここでは元になるデータおよび作成するリストはSheet3としていますので、ご注意ください。
  作成するリストは G2セルを基準とした範囲へ書き出しています。

myDicで重複しない「種類」を抽出しています。
この重複しない「種類」を配列 myKey に入れます。種類は myKey をシートへ横方向へ書き出しています。
次いで、各種類ごとに該当する「品名」を　ｍｙDic2 へ重複しない品名として抽出しています。
この品名はシートへ縦方向へ書き出しています。

Sub myDic()
　　Dim myDic As Object, myKey As Variant
　　Dim c As Variant, varData As Variant

　　'重複しない種類を抽出します
　　Set myDic = CreateObject("Scripting.Dictionary")
　　With Worksheets("Sheet3")
　　　　varData = .Range("A2", .Range("A" & Rows.Count).End(xlUp)).Value
　　End With

　　For Each c In varData
　　　　If Not c = Empty Then
　　　　　　If Not myDic.Exists(c) Then
　　　　　　　　myDic.Add c, Null
　　　　　　End If
　　　　End If
　　Next　
　　’種類をシートへ書き出します
　　myKey = myDic.Keys
　　With Worksheets("Sheet3")
　　　　.Range("G2").Resize(1, 100).ClearContents
　　　　.Range("G2").Resize(1, myDic.Count) = myKey
　　End With
'
'
'
　　Dim i As Long, j As Long
　　Dim varData2 As Variant
　　' 元データの種類と品名を配列へ読み込みます
　　With Worksheets("Sheet3")
　　　　varData2 = .Range("A2", .Range("B" & Rows.Count).End(xlUp)).Value
　　End With

　　'各種類ごとに重複しない品名を抽出します。
　　For i = LBound(myKey) To UBound(myKey)

　　　　Dim myDic2 As Object, myKey2 As Variant
　　　　Set myDic2 = CreateObject("Scripting.Dictionary")

　　　　For j = LBound(varData2) To UBound(varData2)
　　　　　　If varData2(j, 1) = myKey(i) Then
　　　　　　　　If Not myDic2.Exists(varData2(j, 2)) Then
　　　　　　　　　　myDic2.Add varData2(j, 2), Null
　　　　　　　　End If
　　　　　　End If
　　　　Next j

　　　　'品名をシートへ書き出します
　　　　myKey2 = myDic2.Keys
　　　　With Worksheets("Sheet3")
　　　　　　.Range("G3").Offset(0, i).Resize(myDic2.Count) = Application.WorksheetFunction.Transpose(myKey2)
　　　　End With

　　　　Set myDic2 = Nothing
　　　　Erase myKey2

　　Next i

　　Set myDic = Nothing
End Sub

Dictionaryについては　Excel VBA入門編：Dictionaryオブジェクトを利用する　をご覧ください。
入力規則については　Excel VBA 入門編：入力規則を設定する　をご覧ください。

スポンサードリンク

よねさんのWordとExcelの小部屋｜Excel(エクセル)講座の総目次｜Excel(エクセル) VBA入門：目次｜重複しない2組のデータのリストを作成する

PageViewCounter
　 Counter
　Since2006/2/27

重複しない2組のデータのリストを作成する:Excel VBA入門

はじめに Topへ

はじめに　　　Topへ