対話型処理1(MsgBox関数):Excel VBA入門

スポンサードリンク

MsgBox関数　　　 topへ

MsgBox関数の構文
MsgBox(prompt,buttons,title,helpfile,context)

Prompt：省略不可、ダイアログボックスに表示する文字列を指定する。

【例1】「処理を継続しますか？」と表示する
- Sub rei16_01()
  　　MsgBox "処理を継続しますか?"
  End Sub

【例2】複数行の文字列を表示する時は改行コードを利用します。

ここでは定数、vbCrLfを使うことにします。

定数	値	内容
vbCr	Chr(13)	キャリッジリターン
vbLf	Chr(10)	ラインフィード
vbCrLf	Chr(13) + Chr(10)	キャリッジリターン+ラインフィード
vbTab	Chr(9)	タブ

Sub rei16_02()
　　MsgBox "処理を継続しますか?" & vbCrLf & "OKボタンをクリックします"
End Sub

Buttons：省略可、表示するボタンの種類を指定します。

各グループから1つを指定できます。その他は

定数	値	内容
ボタンの種類
vbOKOnly	0	[OK]ボタンのみを表示します。
vbOKCancel	1	[OK]ボタンと[キャンセル]ボタンを表示します。
vbAbortRetryIgnore	2	[中止]、[再試行]、および[無視]の3つのボタンを表示します。
vbYesNoCancel	3	[はい]、[いいえ]、および[キャンセル]の3つのボタンを表示します。
vbYesNo	4	[はい]ボタンと[いいえ]ボタンを表示します。
vbRetryCancel	5	[再試行]ボタンと[キャンセル]ボタンを表示します。
アイコンの表示
vbCritical	16	警告メッセージアイコンを表示します。
vbQuestion	32	問い合わせメッセージアイコンを表示します。
vbExclamation	48	注意メッセージアイコンを表示します。
vbInformation	64	情報メッセージアイコンを表示します。
標準ボタンの設定
vbDefaultButton1	0	第1ボタンを標準ボタンにします。
vbDefaultButton2	256	第2ボタンを標準ボタンにします。
vbDefaultButton3	512	第3ボタンを標準ボタンにします。
vbDefaultButton4	768	第4ボタンを標準ボタンにします。
モーダルの設定
vbApplicationModal	0	アプリケーションモーダルに設定します。メッセージボックスに応答するまで、現在選択中のアプリケーションの実行を継続できません。
vbSystemModal	4096	システムモーダルに設定します。メッセージボックスに応答するまで、すべてのアプリケーションが中断されます。
その他
vbMsgBoxHelpButton	16384	ヘルプボタンを追加します。
VbMsgBoxSetForeground	65536	最前面のウィンドウとして表示します。
vbMsgBoxRight	524288	テキストを右寄せで表示します。
vbMsgBoxRtlReading	1048576	テキストを、右から左の方向で表示します。

【例】「はい」「いいえ」のボタンを表示します。

Sub rei16_03()
　　MsgBox "処理を継続しますか?", vbYesNo
End Sub

選択したボタンによる戻り値を利用する

定数値内容

vbOK 1 [OK]

vbCancel 2 [キャンセル]

vbAbort 3 [中止]

vbRetry 4 [再試行]

vbIgnore 5 [無視]

vbYes 6 [はい]

vbNo 7 [いいえ]

【例】戻り値によって異なったことを実行する例です。

Sub rei16_04()
　Dim keizoku As Integer
　Dim myMsg As String
　keizoku = MsgBox("処理を継続しますか?", vbYesNo)
　　Select Case keizoku
　　　　Case vbYes　'　6としてもよい
　　　　　　myMsg = "「はい」をクリックしました。"
　　　　Case vbNo　　'　7としてもよい
　　　　　　myMsg = "「いいえ」をクリックしました。"
　　　　Case Else
　　　　　　myMsg = ""
　　End Select
　　Range("A1") = myMsg
End Sub

実行結果

【例】注意アイコンを表示し「いいえ」ボタン(第2ボタン)を標準にした例です。

Sub rei16_05()
　Dim keizoku As Integer
　Dim myMsg As String
　keizoku = MsgBox("処理を継続しますか?", vbYesNo + vbExclamation + vbDefaultButton2)
　　Select Case keizoku
　　　　Case vbYes
　　　　　　myMsg = "「はい」をクリックしました。"
　　　　Case vbNo
　　　　　　myMsg = "「いいえ」をクリックしました。"
　　　　Case Else
　　　　　　myMsg = ""
　　End Select
　Range("A1") = myMsg
End Sub

実行結果
「いいえ」ボタンが選択状態に(標準に)なっているのが分かります。

title：省略可、ダイアログのタイトルバーに表示する文字列を設定します。

【例】タイトルバーに「継続確認」と表示します。

Sub rei16_06()
　Dim keizoku As Integer
　Dim myMsg As String
　keizoku = MsgBox("処理を継続しますか?", vbYesNo, "継続確認")
　　Select Case keizoku
　　　　Case vbYes
　　　　　　myMsg = "「はい」をクリックしました。"
　　　　Case vbNo
　　　　　　myMsg = "「いいえ」をクリックしました。"
　　　　Case Else
　　　　　　myMsg = ""
　　End Select
　Range("A1") = myMsg
End Sub