SortedListクラスを利用する:Excel VBA入門

スポンサードリンク

はじめに　　　topへ

SortedListクラスは特定のキーによってソートされるリストを提供してくれます。
SortedListクラスを利用する方法を書いていますが、理解不足で間違った説明をしているかもしれません。
詳細は下記をご覧ください。
- SortedList クラス
  http://msdn.microsoft.com/ja-jp/library/system.collections.sortedlist.aspx
.NET FrameworkのSortedListクラスを利用しますので、.NET Frameworkがインストールされている必要があるようです。
この辺のことは下記のサイトをご覧ください。
- .NET Frameworkのバージョンを確認する方法
  http://www.atmarkit.co.jp/fwin2k/win2ktips/246checkvdnfw/checkvdnfw.html
ここで使用しているのはWindows 7(64bit) Excel2010(32bit)です。

SortedListオブジェクトを作成する　　　topへ

下表のKey（B列）と値（C列）をSortedListに格納して、並べ替えられた結果をE,F列に返します。
なお、この例ではB列のKeyは重複していないデータです。

コードの例

SortedListへ書き出すデータを配列xへ一旦読み込んで処理しています。

Sub test_A1()
　　Dim DataList As Object
　　Dim x, i As Long
　　　　Set DataList = CreateObject("System.Collections.SortedList")

　　　　x = Range("B2:C8").Value
　　　　For i = LBound(x) To UBound(x)
　　　　　　If DataList.Contains(x(i, 1)) = False Then
　　　　　　　　DataList.Add x(i, 1), x(i, 2)
　　　　　　End If
　　　　Next i
　　　　For i = 0 To DataList.Count - 1
　　　　　　Cells(i + 2, 5).Value = DataList.GetKey(i)
　　　　　　Cells(i + 2, 6).Value = DataList.GetByIndex(i)
　　　　Next i

　　　　Set DataList = Nothing

End Sub

実行すると、下図になります。
- Keyの昇順に並んでいるのがわかります。

なお、Keyが重複するときは?
- 最初の出てきたKeyの値が格納されています。
  - If DataList.Contains(x(i, 1)) = False Then　
    　　DataList.Add x(i, 1), x(i, 2)
    End If
    と条件を付けでデータを追加しているためです。
- 以下のような書き方をすると・・・重複したKeyは新しい値に書き換えられ、最後の値が格納されます。
  For i = LBound(x) To UBound(x)
  DataList.Item(x(i, 1)) = x(i, 2)
  Next i

ランダムに並べ替える　　　topへ

重複しないランダムな数値を得る方法　と比べると非常にシンプルなコードになっているのがわかります。

数値の1～10をランダムに並べ替える例です。
コードの例

Sub test_B1()
　　Dim i As Long
　　Dim DataList As Object
　　Dim x
　　　　Set DataList = CreateObject("System.Collections.SortedList")
　　　　Randomize

　　　　For i = 1 To 10
　　　　　　DataList.Item(Rnd()) = i
　　　　Next i

　　　　For i = 0 To DataList.Count - 1
　　　　　　Cells(i + 1, 1).Value = DataList.GetByIndex(i)
　　　　　　Cells(i + 1, 2).Value = DataList.GetKey(i)
　　　　Next i

　　　　Set DataList = Nothing

End Sub

実行すると、下図になります。
A列が数値1～10をランダムに並べたもので、B列が並べ替えに使用された乱数です。

重複なしの並べ替え　　　topへ

重複があるものから重複なしで並べ替えたものを得ることも可能です。
フィルタオプションの設定やDictionaryを利用して重複なしのデータを作成し、並べ替えるという手順が簡略化できそうです。

コードの例

Sub test_B2()
　　Dim i As Long
　　Dim DataList As Object
　　Dim x
　　　　Set DataList = CreateObject("System.Collections.SortedList")

　　　　x = Range("A1：A10").Value
　　　　For i = LBound(x) To UBound(x)
　　　　　　DataList.Item(x(i, 1)) = ""
　　　　Next i

　　　　For i = 0 To DataList.Count - 1
　　　　　　Cells(i + 1, 3).Value = DataList.GetKey(i)
　　　　Next i

　　　　Set DataList = Nothing

End Sub

実行すると下図のようになります。
なお、ひらがな、カタカナ、漢字が混在していると下図のようになりました。

主なメソッド　　　topへ

Add

Keyと値を追加する。
コードの例

Sub test_C1()
　　Dim i As Long
　　Dim DataList As Object
　　Dim x
　　　　Set DataList = CreateObject("System.Collections.SortedList")

　　　　x = Range("A1：B5").Value
　　　　For i = LBound(x) To UBound(x)
　　　　　　If DataList.Contains(x(i, 1)) = False Then
　　　　　　　　DataList.Add x(i, 1), x(i, 2)
　　　　　　End If
　　　　Next i

　　　　'キーと値を追加する
　　　　DataList.Add "マンゴー", 6

　　　　'書き出し
　　　　Range("D:E").ClearContents
　　　　For i = 0 To DataList.Count - 1
　　　　　　Cells(i + 1, 4).Value = DataList.GetKey(i)
　　　　　　Cells(i + 1, 5).Value = DataList.GetByIndex(i)
　　　　Next i

　　　　Set DataList = Nothing

End Sub

実行後の画面

Clear

SortedListオブジェクトからすべての要素を削除する。

コードの例：クリアして、「マンゴー」を追加した例。

Sub test_C1()
　　Dim i As Long
　　Dim DataList As Object
　　Dim x
　　　　Set DataList = CreateObject("System.Collections.SortedList")

　　　　x = Range("A1：B5").Value
　　　　For i = LBound(x) To UBound(x)
　　　　　　If DataList.Contains(x(i, 1)) = False Then
　　　　　　　　DataList.Add x(i, 1), x(i, 2)
　　　　　　End If
　　　　Next i

　　　　 'クリアする
　　　　DataList.Clear

　　　　'キーと値を追加する
　　　　DataList.Add "マンゴー", 6

　　　　'書き出し
　　　　Range("D:E").ClearContents
　　　　For i = 0 To DataList.Count - 1
　　　　　　Cells(i + 1, 4).Value = DataList.GetKey(i)
　　　　　　Cells(i + 1, 5).Value = DataList.GetByIndex(i)
　　　　Next i

　　　　Set DataList = Nothing

End Sub

実行後の画面

Remove

指定したキーを持つ要素を削除する。

コードの例：「りんご」を削除した例。

Sub test_C1()
　　Dim i As Long
　　Dim DataList As Object
　　Dim x
　　　　Set DataList = CreateObject("System.Collections.SortedList")

　　　　x = Range("A1：B5").Value
　　　　For i = LBound(x) To UBound(x)
　　　　　　If DataList.Contains(x(i, 1)) = False Then
　　　　　　　　DataList.Add x(i, 1), x(i, 2)
　　　　　　End If
　　　　Next i

　　　'要素を削除する
　　　　DataList.Remove ("りんご")

　　　　'書き出し
　　　　Range("D:E").ClearContents
　　　　For i = 0 To DataList.Count - 1
　　　　　　Cells(i + 1, 4).Value = DataList.GetKey(i)
　　　　　　Cells(i + 1, 5).Value = DataList.GetByIndex(i)
　　　　Next i

　　　　Set DataList = Nothing

End Sub

実行後の画面

スポンサードリンク

よねさんのWordとExcelの小部屋｜Excel(エクセル)講座の総目次｜Excel(エクセル) VBA入門：目次｜SortedListクラスを利用する

PageViewCounter
　 Counter
　Since2006/2/27

SortedListクラスを利用する:Excel VBA入門

はじめに topへ

SortedListオブジェクトを作成する topへ

ランダムに並べ替える topへ

重複なしの並べ替え topへ

主なメソッド topへ

Add