リストボックスの使い方:Excel VBA入門

複数選択についてはリストボックスでの複数選択をご覧ください。

スポンサードリンク

リストボックスへデータを表示する	リストボックスへセル範囲のデータを表示する
リストボックスの値をセル範囲へ入力する	リストボックスに列見出しを表示する
リストの先頭を変更する

リストボックスへデータを表示する　　　 topへ

AddItem メソッドで項目を設定する

下図はUserForm6にListbox1とCommandButton1とCommandButton2が配置されています。
ListBox1に表示された商品名を選択し、「入力」ボタンをクリックするとシートの入力されるようにします。

ユーザーフォームの初期化でListBox1に項目を表示します。

Private Sub UserForm_Initialize()
　　UserForm6.Caption = "商品名の入力"
　　With ListBox1
　　　　.AddItem "りんご"
　　　　.AddItem "みかん"
　　　　.AddItem "バナナ"
　　End With
End Sub

CommandButton1「入力」のコード

Private Sub CommandButton1_Click()
　　Dim lastRow As Long
　　With Worksheets("Sheet1")
　　　　lastRow = .Cells(Rows.Count, 1).End(xlUp).Row + 1
　　　　.Cells(lastRow, 1).Value = UserForm6.ListBox1.Value
　　End With
End Sub

CommandButton2「終了」のコード

Private Sub CommandButton2_Click()
　　Unload Me
End Sub
実行画面
標準モジュールには以下のように記述し、シートに配置したフォームのボタンから実行しています。

Sub myform6()
　　UserForm6.Show
End Sub

Columnプロパティで複数の項目を設定する

object.Column(column,row) [= Variant]
複数列を表示するにはColumnCountプロパティを利用します。
[構文]　object.ColumnCount [= Long]
- 0 を設定すると、列はすべて表示されなくなります。
- -1 を設定すると、表示可能な列がすべて表示されます
列幅を指定するにはColumnWidthsプロパティを利用します。
[構文]　object.ColumnWidths [= String]
- 単位はポイント。他の単位を使用する場合は単位を明記します。
  空白または-1を指定すると、Excelの計算値になります。
  0を指定すると表示されません。

ユーザーフォームの初期化でListBox1に複数列の項目を表示します。
下記の例は一旦、項目を配列(Variant)に入れ、配列からListBoxへ入れています。

Private Sub UserForm_Initialize()
Dim myData(2, 2) As Variant
　　UserForm6.Caption = "商品名の入力"
　　myData(0, 0) = 1001
　　myData(0, 1) = 1002
　　myData(0, 2) = 1003
　　myData(1, 0) = "りんご"
　　myData(1, 1) = "みかん"
　　myData(1, 2) = "バナナ"
　　myData(2, 0) = 100
　　myData(2, 1) = 150
　　myData(2, 2) = 200
　　With ListBox1
　　　　.ColumnCount = 3
　　　　.ColumnWidths = "50;50;50"
　　　　.Column() = myData
　　End With
End Sub

CommandButton1「入力」のコード

object.ListIndex [= Variant]　現在選択されている項目を返します。

Private Sub CommandButton1_Click()
Dim lastRow As Long
Dim i As Integer
　　With Worksheets("Sheet4")
　　　　lastRow = .Cells(Rows.Count, 1).End(xlUp).Row + 1
　　　　For i = 1 To 3
　　　　　　.Cells(lastRow, i).Value = ListBox1.List(ListBox1.ListIndex, i - 1)
　　　　Next i
　　End With
End Sub

CommandButton2「終了」のコード

Private Sub CommandButton2_Click()
　　Unload Me
End Sub
実行画面
標準モジュールには以下のように記述し、シートに配置したフォームのボタンから実行しています。

Sub myform6()
　　UserForm6.Show
End Sub

リストボックスへセル範囲のデータを表示する　　　 topへ

RowSourceプロパティを利用します。
[構文]　object.RowSource [= String]
Listプロパティを利用します。
[構文]　object.List( row, column ) [= Variant]
複数列を表示するにはColumnCountプロパティを利用します。
[構文]　object.ColumnCount [= Long]
- 0 を設定すると、列はすべて表示されなくなります。
- -1 を設定すると、表示可能な列がすべて表示されます
列幅を指定するにはColumnWidthsプロパティを利用します。
[構文]　object.ColumnWidths [= String]
- 単位はポイント。他の単位を使用する場合は単位を明記します。
  空白または-1を指定すると、Excelの計算値になります。
  0を指定すると表示されません。

[例]Sheet1のA:C列の値をリストボックスに表示します。
- Sheet1

RowSourceプロパティを利用した例

Private Sub UserForm_Initialize()
　　Dim lastRow As Long
　　　　With Worksheets("Sheet1")
　　　　　　lastRow = .Cells(Rows.Count, 1).End(xlUp).Row
　　　　End With
　　　　With ListBox1
　　　　　　.ColumnCount = 3
　　　　　　.ColumnWidths = "50;50;50"
　　　　　　.RowSource = "Sheet1!A1:C" & lastRow
　　　　End With
End Sub

Listプロパティを利用した例
一旦、配列(Variant)に入れ、配列からListBoxへ入れています。

Private Sub UserForm_Initialize()
　　Dim lastRow As Long
　　Dim myData
　　　　With Worksheets("Sheet1")
　　　　　　myData = .Range(.Cells(1, 1), .Cells(Rows.Count, 3).End(xlUp)).Value
　　　　End With
　　　　With ListBox1
　　　　　　.ColumnCount = 3
　　　　　　.ColumnWidths = "50;50;50"
　　　　　　.List = myData
　　　　End With
End Sub

CommandButton1「入力」のコード

object.ListIndex [= Variant]　現在選択されている項目を返します。

CommandButton2「終了」のコード

Private Sub CommandButton2_Click()
　　Unload Me
End Sub
標準モジュールのコード

Sub myform6()
　　Load UserForm6
　　UserForm6.Show
End Sub
実行例

リストボックスの値をセル範囲へ入力する　　　 topへ

リストボックスで選択した行はListIndex プロパティで取得できます。
- どの行も選択されていない時は-1を返します。
  1行目が選択されている時は0を返します。

コードの例です。

Listプロパティを利用した例です。
どの行も選択されていない場合はMｓｇBoxで注意を促して終了するようにしてあります。

Private Sub CommandButton1_Click()
　　Dim lRow As Long, i As Long
　　Dim ListNo As Long
　　　　ListNo = ListBox1.ListIndex
　　　　If ListNo < 0 Then
　　　　　　MsgBox "いずれかの行を選択してください"
　　　　　　Exit Sub
　　　　End If
　　　　With Worksheets("Sheet2")
　　　　　　lRow = .Range("B" & Rows.Count).End(xlUp).Row
　　　　For i = 0 To 2
　　　　　　.Cells(lRow + 1, i + 2).Value = ListBox1.List(ListNo, i)
　　　　Next i
　　　　.Cells(lRow + 1, 5).Value = TextBox1.Value
　　　　.Cells(lRow + 1, 6).Value = _
　　　　　　　　.Cells(lRow + 1, 4).Value * .Cells(lRow + 1, 5).Value
　　　　End With
　　　　TextBox1.Value = ""
　　　　End Sub

なお、ListBox1に使用したリストはSheet1のA:C列にあるものを利用した例です。

Private Sub UserForm_Initialize()
　　Dim lRow As Long
　　With Worksheets("Sheet1")
　　　　lRow = .Range("A" & Rows.Count).End(xlUp).Row
　　End With
　　With ListBox1
　　　　.ColumnCount = 3
　　　　.ColumnWidths = "50;50;50"
　　　　.RowSource = "Sheet1!A1:C" & lRow
　　End With
　　TextBox1.Value = ""
End Sub

実行画面の例です。

リストボックスに列見出しを表示する　　　 topへ

列見出しとしてリストの1行目を表示できます。
[構文]　object.ColumnHeads [= Boolean]

ColumnHeads=True　としています。.RowSource は "Sheet1!A2:C" & lRowと2行目以降としています。
列見出しは.RowSourceのひとつ前の行になります。

Private Sub UserForm_Initialize()
　　Dim lRow As Long
　　With Worksheets("Sheet1")
　　　　lRow = .Range("A" & Rows.Count).End(xlUp).Row
　　End With
　　With ListBox1
　　　　.ColumnCount = 3
　　　　.ColumnWidths = "50;50;50"
　　　　.RowSource = "Sheet1!A2:C" & lRow
　　　　.ColumnHeads = True
　　End With
　　TextBox1.Value = ""
End Sub

実行画面です。列見出しが表示され、列見出しはスクロールしません。

リストの先頭を変更する　　　 topへ

リストを上から順に選択していく場合、表示される先頭行をTopIndex プロパティで変更します。
縦に長いリストなど毎回、先頭からスクロールせずにすみそうです。

TopIndexに選択した行を代入した例です。

Private Sub CommandButton1_Click()
　　Dim lRow As Long, i As Long
　　Dim ListNo As Long
　　　　ListNo = ListBox1.ListIndex
　　　　If ListNo < 0 Then
　　　　　　MsgBox "いずれかの行を選択してください"
　　　　　　Exit Sub
　　　　End If
　　　　With Worksheets("Sheet2")
　　　　　　lRow = .Range("B" & Rows.Count).End(xlUp).Row
　　　　For i = 0 To 2
　　　　　　.Cells(lRow + 1, i + 2).Value = ListBox1.List(ListNo, i)
　　　　Next i
　　　　.Cells(lRow + 1, 5).Value = TextBox1.Value
　　　　.Cells(lRow + 1, 6).Value = _
　　　　　　　　.Cells(lRow + 1, 4).Value * .Cells(lRow + 1, 5).Value
　　　　End With
　　　　TextBox1.Value = ""
　　　　ListBox1.TopIndex = ListNo
End Sub

実行画面です。先に入力した「1003　バナナ　120」の行が先頭になっています。

スポンサードリンク

よねさんのWordとExcelの小部屋｜Excel(エクセル)講座の総目次｜Excel(エクセル) VBA入門：目次｜リストボックスの使い方

PageViewCounter
　 Counter
　Since2006/2/27

リストボックスの使い方:Excel VBA入門

リストボックスへデータを表示する topへ

AddItem メソッドで項目を設定する

Columnプロパティで複数の項目を設定する

リストボックスへセル範囲のデータを表示する topへ

リストボックスの値をセル範囲へ入力する topへ

リストボックスに列見出しを表示する topへ

リストの先頭を変更する topへ

リストボックスへデータを表示する　　　 topへ

リストボックスへセル範囲のデータを表示する　　　 topへ

リストボックスの値をセル範囲へ入力する　　　 topへ

リストボックスに列見出しを表示する　　　 topへ

リストの先頭を変更する　　　 topへ