コンボボックスの使い方:Excel VBA入門

スポンサードリンク

コンボボックスへデータを表示する	コンボボックスへセル範囲のデータを表示する
コンボボックスの値をセル範囲へ入力する

はじめに　　　topへ

このページではユーザーフォームにコンボボックスを配置して使用する方法を書いています。
ユーザーフォームの使い方は　Excel(エクセル) VBA入門：ユーザーフォームを利用する　をご覧ください。
ユーザーフォームはシートへ配置したフォームのボタンで表示するようにしています。
- シートにフォームのボタンを表示しています。このボタンには下のコード「myform1」を登録しています。
- 標準モジュールには以下のコードを書いて、ユーザーフォームを表示するようにしています。
  Sub myform1()
  　　UserForm1.Show
  End Sub
ユーザーフォームへはコンボボックスと、コマンドボタンを2個配置したものを使っています。
- このページで使用しているユーザーフォームは下図のようなものです。
- ［終了］ボタンはCommandButton2で下記のコードでユーザーフォームを閉じるようにしています。
  - Private Sub CommandButton2_Click()
    　　Unload Me
    End Sub

コンボボックスへデータを表示する　　　 topへ

AddItem メソッドで項目を設定する

コードの例

Private Sub UserForm_Initialize()
　　With ComboBox1
　　　　.AddItem "りんご"
　　　　.AddItem "みかん"
　　　　.AddItem "バナナ"
　　　　.AddItem "マンゴー"
　　End With
End Sub

実行画面

Columnプロパティで複数の項目を設定する

[構文]　object.ColumnCount [= Long]　：列数を設定します。
[構文]　object.ColumnWidths [= String]　：各列の幅を設定します。
[構文]　object.Column(column,row) [= Variant] 　：項目を設定します

コードの例
リストを配列myDataに読み込みコンボボックスへColumnプロパティで追加しています。

Private Sub UserForm_Initialize()
　　Dim myData(2, 2) As Variant
　　　　myData(0, 0) = 1001
　　　　myData(0, 1) = 1002
　　　　myData(0, 2) = 1003
　　　　myData(1, 0) = "りんご"
　　　　myData(1, 1) = "みかん"
　　　　myData(1, 2) = "バナナ"
　　　　myData(2, 0) = 100
　　　　myData(2, 1) = 150
　　　　myData(2, 2) = 200

　　　　With ComboBox1
　　　　　　.ColumnCount = 3
　　　　　　.ColumnWidths = "50;50;50"
　　　　　　.Column() = myData
　　　　End With
End Sub

実行画面

コンボボックスへセル範囲のデータを表示する　　　 topへ

RowSourceプロパティを利用します。
[構文]　object.RowSource [= String]
Listプロパティを利用します。
[構文]　object.List( row, column ) [= Variant]
複数列を表示するにはColumnCountプロパティを利用します。
[構文]　object.ColumnCount [= Long]
- 0 を設定すると、列はすべて表示されなくなります。
- -1 を設定すると、表示可能な列がすべて表示されます
列幅を指定するにはColumnWidthsプロパティを利用します。
[構文]　object.ColumnWidths [= String]
- 単位はポイント。他の単位を使用する場合は単位を明記します。
  空白または-1を指定すると、Excelの計算値になります。
  0を指定すると表示されません。

[例]Sheet1のA:C列の値をリストボックスに表示します。
- Sheet1

コードの例

RowSourceプロパティを利用した例

Private Sub UserForm_Initialize()
　　Dim lRow As Long
　　　　With Worksheets("Sheet1")
　　　　　　lRow = .Range("A" & Rows.Count).End(xlUp).Row
　　　　End With
　　　　With ComboBox1
　　　　　　.ColumnCount = 3
　　　　　　.ColumnWidths = "50;50;50"
　　　　　　.RowSource = "Sheet1!A2:C" & lRow
　　　　End With
End Sub

Listプロパティを利用した例
配列myDataに項目を読み込み、Listプロパティへ渡しています。

Private Sub UserForm_Initialize()
　　Dim lRow As Long
　　Dim i As Long, myCnt As Long
　　Dim myData
　　　　With Worksheets("Sheet1")
　　　　　　lRow = .Range("A" & Rows.Count).End(xlUp).Row
　　　　　　myData = .Range("A2:C" & lRow).Value
　　　　End With

　　　　With ComboBox1
　　　　　　.ColumnCount = 3
　　　　　　.ColumnWidths = "50;50;50"
　　　　　　.List = myData
　　　　End With
End Sub

実行例

コンボボックスの値をセル範囲へ入力する　　　 topへ

コンボボックスで選択した行はListIndex プロパティで取得できます。
- どの行も選択されていない時は-1を返します。
  1行目が選択されている時は0を返します。

コードの例です。
コンボボックスでどの行も選択されていない時はメッセージボックスで選択を促します。

ユーザーフォームに配置した「CommandButton1」をクリックしてシートへ書き込む例です。

Private Sub CommandButton1_Click()
　　Dim lRow As Long, i As Long
　　Dim ListNo As Long
　　　　ListNo = ComboBox1.ListIndex
　　　　　　If ListNo < 0 Then
　　　　　　　　MsgBox "いずれかの行を選択してください"
　　　　　　　　Exit Sub
　　　　　　End If
　　　　With Worksheets("Sheet2")
　　　　　　lRow = .Range("B" & Rows.Count).End(xlUp).Row
　　　　　　For i = 0 To 2
　　　　　　　　.Cells(lRow + 1, i + 2).Value = ComboBox1.List(ListNo, i)
　　　　　　Next i
　　　　End With
End Sub