エクセル練習問題：列の検索・行の検索

スポンサードリンク

問題　　　　topへ

問題1：B列～D列に商品の単価リストがあります。このリストからデータを取り出して　E列～I列の販売実績の商品名と販売金額を埋めなさい。　　問題1の解答

販売金額は　販売数×単価　で求めることとします。

	B	C	D	E	F	G	H	I
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数	販売金額
4	果物-01	りんご	180		果物-02		10
5	果物-02	みかん	130		果物-01		10
6	果物-03	バナナ	140		果物-03		10

問題2：B列～D列に商品の単価リストがあります。このリストからデータを取り出して　E列～H列の販売実績の商品名と販売金額を埋めなさい。　　問題2の解答

販売金額は　販売数×単価　で求めることとします。

	B	C	D	E	F	G	H	I
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数	販売金額
4	野菜-01	大根	150		野菜-03		20
5	野菜-02	白菜	120		果物-02		15
6	野菜-03	ピーマン	50		果物-01		18
7	果物-01	りんご	180		野菜-02		21
8	果物-02	みかん	130
9	果物-03	バナナ	140

問題3：問題1と同じ「商品の単価リスト」があります。このリストからF列のコードを求めなさい。　　問題3の解答

	B	C	D	E	F	G	H
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数
4	野菜-01	大根	150			ピーマン	20
5	野菜-02	白菜	120			みかん	15
6	野菜-03	ピーマン	50			大根	18
7	果物-01	りんご	180			バナナ	21
8	果物-02	みかん	130
9	果物-03	バナナ	140

問題4：F列～J列に判定基準の表があります。この基準でD列に得点の判定をしなさい。　　問題4の解答

判定基準は0以上40未満は「不可」、40以上60未満は「可」、60以上80未満は「良」、80以上は「優」を意味します。
D列の得点を判定をしなさい。

	B	C	D	E	F	G	H	I	J
2	名前	得点	判定		判定基準
3	相沢一郎	52			得点(以上)	0	40	60	80
4	井上浩二	74			判定	不可	可	良	優
5	上野有紀	84
6	内野武	32
7	上田祥子	68
8	江田早苗	59
9	榎本高貴	80
10	小田和樹	60

問題1の解答例　　　　 topへ

解答
この問題のポイントは商品単価リストのコードが昇順に並んでいるところです。

	B	C	D	E	F	G	H	I
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数	販売金額
4	果物-01	りんご	180		果物-02	みかん	10	1,300
5	果物-02	みかん	130		果物-01	りんご	10	1,800
6	果物-03	バナナ	140		果物-03	バナナ	10	1,400

LOOKUP関数を使う方法	VLOOKUP関数を使う方法
XLOOKUP関数を使う方法

LOOKUP関数を使う方法

商品単価リストのコードが昇順に並んでいるので、LOOKUP関数を使うことができます。
=LOOKUP(検査値,検査範囲,対応範囲)　　[ベクトル形式]
=LOOKUP(検査値,配列)　[配列形式]
詳しい説明は　LOOKUP関数　を参照してください。

LOOKUP関数のベクトル形式で数式を作成すると

G4セルは　=LOOKUP(F4,$B$4:$B$6,$C$4:$C$6)　としました。
I4セルは　=LOOKUP(F4,$B$4:$B$6,$D$4:$D$6)*H4　としました。

	B	C	D	E	F	G	H	I
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数	販売金額
4	果物-01	りんご	180		果物-02	=LOOKUP(F4,$B$4:$B$6,$C$4:$C$6)	10	=LOOKUP(F4,$B$4:$B$6,$D$4:$D$6)*H4
5	果物-02	みかん	130		果物-01	=LOOKUP(F5,$B$4:$B$6,$C$4:$C$6)	10	=LOOKUP(F5,$B$4:$B$6,$D$4:$D$6)*H5
6	果物-03	バナナ	140		果物-03	=LOOKUP(F6,$B$4:$B$6,$C$4:$C$6)	10	=LOOKUP(F6,$B$4:$B$6,$D$4:$D$6)*H6

[関数の挿入]ボタンを使う場合の操作手順
1. 数式を入力するセル G4 を選択します。
  数式バーの横の[関数の挿入]ボタンをクリックします。
2. 関数の挿入ダイアログボックスで関数の分類で「すべて表示」を選択します。
  LOOKUP関数は[検索/行列]に分類されているので、関数の分類で[検索/行列]を選択するのが正道かもしれませんが、使いたい関数がどの分類になっているのかを覚えるのはちょっと面倒・・・というわけで、「すべて表示」を使って説明しています。
  関数名で LOOKUP を選択して、[OK]ボタンをクリックします。
3. 引数の選択が表示されますが、ここでは　検査値,検査範囲,対応範囲の[ベクトル形式]を使うので、そのまま[OK]ボタンをクリックします。
4. LOOKUP関数の引数ダイアログボックスで、検査値に　F4　、検査範囲に　$B$4:$B$6　と絶対参照の型で指定します。
  対応範囲も　$C$4:$C$6　と絶対参照の型で指定します。
  この数式を下方向にコピーするので、絶対参照としています。
  - 検査値 F4も　G4セルの数式を I4セルにコピーして利用する場合は　$F4　と複合参照にするのが正道と思われます。
    ここの手順を書いた後で気づきましたので、書き足しておきます。 F4 でも一手間増えるだけですので大差はないのですが・・・
5. G4セルを選択して、フィルハンドルを下方向へドラッグして数式をコピーします。
6. G4セルを選択して、[Ctrl]+[C]でコピーし、I4セルを選択して[Ctrl]+[V]で貼り付けます。
  数式バーの数式をクリックしてカーソルを数式バー内に表示すると、カラーリファレンスが表示されます。
  カラーリファレンスの枠を正しい位置へドラッグして数式を修正することができます。
  
  ↓
7. 数式バーで数式の後ろに　*H4　と販売数を掛けて数式は完成ですので、[Enter]キーを押します。
  - [Enter]キーを押す代わりに、[入力]ボタンをクリックして、数式を入力することもできます。
8. I4セルを選択して、フィルハンドルを下方向へドラッグして数式をコピーします。

LOOKUP関数の配列形式で数式を作成すると

G4セルは　=LOOKUP(F4,$B$4:$C$6)　としました。
I4セルは　=LOOKUP(F4,$B$4:$D$6)*H4　としました。

	B	C	D	E	F	G	H	I
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数	販売金額
4	果物-01	りんご	180		果物-02	=LOOKUP(F4,$B$4:$C$6)	10	=LOOKUP(F4,$B$4:$D$6)*H4
5	果物-02	みかん	130		果物-01	=LOOKUP(F5,$B$4:$C$6)	10	=LOOKUP(F5,$B$4:$D$6)*H5
6	果物-03	バナナ	140		果物-03	=LOOKUP(F6,$B$4:$C$6)	10	=LOOKUP(F6,$B$4:$D$6)*H6

[関数の挿入]ボタンを使う場合の操作手順
1. 数式を入力するセル G4 を選択します。
  数式バーの横の[関数の挿入]ボタンをクリックします。
2. 関数の挿入ダイアログボックスで関数の分類で「すべて表示」を選択します。
  関数名で LOOKUP を選択して、[OK]ボタンをクリックします。
3. 配列形式を使う場合、引数の選択で「検査値,配列」を選択します。
4. 関数の引数は下図のように変化しますので、検査値に　F4　、配列に　$B$4:$C$6　とします。
5. G4セルに　=LOOKUP(F4,$B$4:$C$6)　と入力されました。
6. I4セルは同様に、=LOOKUP(F4,$B$4:$D$6)*H4　とします。
7. G4セルとI4セルの数式を下方向へコピーして完成です。

VLOOKUP関数を使う方法

検索される列が左端列にあるので、VLOOKUP関数は使うことができます。
商品単価リストの検索するコードは昇順に並んでいるので、引数の検索の型を省略することができます。(または TRUE とします)
VLOOKUP関数の構文：=VLOOKUP(検索値,範囲,列番号,[検索の型])
詳しい説明は　VLOOKUP関数　を参照してください。

商品の単価リストのコードは昇順に並んでいますので、検索の型は省略できます。
G4セルは　=VLOOKUP(F4,$B$4:$D$6,2)　としました。
I4セルは　=VLOOKUP(F4,$B$4:$D$6,3)*H4　で単価を取り出して販売数を乗じます。

	B	C	D	E	F	G	H	I
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数	販売金額
4	果物-01	りんご	180		果物-02	=VLOOKUP(F4,$B$4:$D$6,2)	10	=VLOOKUP(F4,$B$4:$D$6,3)*H4
5	果物-02	みかん	130		果物-01	=VLOOKUP(F5,$B$4:$D$6,2)	10	=VLOOKUP(F5,$B$4:$D$6,3)*H5
6	果物-03	バナナ	140		果物-03	=VLOOKUP(F6,$B$4:$D$6,2)	10	=VLOOKUP(F6,$B$4:$D$6,3)*H6

G4セルでVLOOKUP関数の引数ダイアログボックスを使う場合は、検索値に　F4　、範囲に　$B$4:$D$6　、列番号に 2 と入力します。
I4セルでは　=VLOOKUP(F4,$B$4:$D$6,3)*H4　と列番号を 3 にし、販売数を　*H4　と掛けます。

INDEX関数を使う方法

INDEX関数を使うことができます。行位置を調べるのにMATCH関数を合わせて使います。
構文：=INDEX(範囲,行番号,[列番号],[領域番号])
INDEX関数　に説明がありますので参照してください。
構文：=MATCH(検査値,検査範囲,[照合の型])
MATCH関数　に説明がありますので参照してください。

商品の単価リストのコードは昇順に並んでいますので、MATCH関数の照合の型は省略できます。
G4セルは　=INDEX($C$4:$C$6,MATCH(F4,$B$4:$B$6))　としました。
I4セルは　=INDEX($D$4:$D$6,MATCH(F4,$B$4:$B$6))*H4　で単価を取り出して販売数を乗じます。

	B	C	D	E	F	G	H	I
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数	販売金額
4	果物-01	りんご	180		果物-02	=INDEX($C$4:$C$6,MATCH(F4,$B$4:$B$6))	10	=INDEX($D$4:$D$6,MATCH(F4,$B$4:$B$6))*H4
5	果物-02	みかん	130		果物-01	=INDEX($C$4:$C$6,MATCH(F5,$B$4:$B$6))	10	=INDEX($D$4:$D$6,MATCH(F5,$B$4:$B$6))*H5
6	果物-03	バナナ	140		果物-03	=INDEX($C$4:$C$6,MATCH(F6,$B$4:$B$6))	10	=INDEX($D$4:$D$6,MATCH(F6,$B$4:$B$6))*H6

[関数の挿入]ボタンを使って、数式を作成する手順
1. G4セルを選択して、数式バーの横の[関数の挿入]ボタンをクリックします。
2. 関数の挿入ダイアログボックスの関数の分類で「すべて表示」を選択し、関数名で「INDEX」を選択します。
  [OK]ボタンをクリックします。
3. 引数の選択では「配列,行番号,列番号」が選択された状態で、[OK]ボタンをクリックします。
4. INDEX関数の引数ダイアログボックスの配列に $C$4:$C$6　と入力します。　(C4:C6セルを選択して、F4キーを押して絶対参照にします)
  行番号の欄内をクリックしてカーソルを表示します。
  名前ボックスの▼ボタンをクリックして、表示される最近使った関数のリストから　MATCH関数を選択します。
  MATCH関数がない場合は[その他の関数]を選択します。
5. 関数の挿入で　MATCH関数を選択して[OK]ボタンをクリックします。
6. 検査値に　$F4　、検査範囲に　$B$4:$B$6　と入力して、[OK]ボタンをクリックします。
7. G4セルに数式が入力されました。
  G4セルを選択して、フィルハンドルをG6セルまでドラッグして数式をコピーします。
8. G4セルを選択して、[Ctrl]+[C]でコピーします。
  I4セルを選択して[Ctrl]+[V]で数式を貼り付けます。
  数式バー内の数式をクリックすると、カラーリファレンスが表示されます。
  カラーリファレンスで青色のC4:C6の枠をドラッグして、D4:D6へ移動します。
  数式の後ろに　*H4　と入力します。
  数式を　=INDEX($D$4:$D$6,MATCH(F4,$B$4:$B$6))*H4　となるように修正します。
  修正ができたら[Enter]キーを押して入力を確定します。
9. I4セルを選択して、フィルハンドルをI6セルまでドラッグして数式をコピーします。
XLOOKUP関数を使う方法
- Microsoft365ではXLOOKUP関数やスピルの機能が使えるようになりました。
  G4セルには　=XLOOKUP(F4:F6,B4:B6,C4:C6)
  I4セルには　=XLOOKUP(F4:F6,B4:B6,D4:D6)*H4:H6
  と入力します。
  - XLOOKUP関数の使い方は　XLOOKUP関数で範囲や配列を検索する　をご覧ください。

問題2の解答例　　　　 topへ

解答
この問題のポイントは商品単価リストのコードが昇順に並んでいないところです。

	B	C	D	E	F	G	H	I
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数	販売金額
4	野菜-01	大根	150		野菜-03	ピーマン	20	1,000
5	野菜-02	白菜	120		果物-02	みかん	15	1,950
6	野菜-03	ピーマン	50		果物-01	りんご	18	3,240
7	果物-01	りんご	180		野菜-02	白菜	21	2,520
8	果物-02	みかん	130
9	果物-03	バナナ	140

VLOOKUP関数を使う方法	INDEX関数を使う方法
XLOOKUP関数を使う方法

VLOOKUP関数を使う方法

商品単価リストのコードが昇順に並んでいませんので、LOOKUP関数は使えません。
検索される列が左端列にあるので、VLOOKUP関数は使うことができます。
VLOOKUP関数の構文：=VLOOKUP(検索値,範囲,列番号,[検索の型])
詳しい説明は　VLOOKUP関数　を参照してください。

商品単価リストの検索するコードは昇順に並んでいないので、引数の検索の型をFALSE と指定する必要があります。(または 0 とします)
G4セルは　=VLOOKUP(F4,$B$4:$D$9,2,FALSE)　としました。
I4セルは　=VLOOKUP(F4,$B$4:$D$9,3,FALSE)*H4　で単価を取り出して販売数を乗じます。

	B	C	D	E	F	G	H	I
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数	販売金額
4	野菜-01	大根	150		野菜-03	=VLOOKUP(F4,$B$4:$D$9,2,FALSE)	20	=VLOOKUP(F4,$B$4:$D$9,3,FALSE)*H4
5	野菜-02	白菜	120		果物-02	=VLOOKUP(F5,$B$4:$D$9,2,FALSE)	15	=VLOOKUP(F5,$B$4:$D$9,3,FALSE)*H5
6	野菜-03	ピーマン	50		果物-01	=VLOOKUP(F6,$B$4:$D$9,2,FALSE)	18	=VLOOKUP(F6,$B$4:$D$9,3,FALSE)*H6
7	果物-01	りんご	180		野菜-02	=VLOOKUP(F7,$B$4:$D$9,2,FALSE)	21	=VLOOKUP(F7,$B$4:$D$9,3,FALSE)*H7
8	果物-02	みかん	130
9	果物-03	バナナ	140

G4セルでVLOOKUP関数の引数ダイアログボックスを使う場合は、検索値に F4 、範囲に $B$4:$D$9　、列番号に　2　、検索方法に FALSE　と入力します。

INDEX関数を使う方法

INDEX関数を使うことができます。行位置を調べるのにMATCH関数を合わせて使います。
構文：=INDEX(範囲,行番号,[列番号],[領域番号])
INDEX関数　に説明がありますので参照してください。
構文：=MATCH(検査値,検査範囲,[照合の型])
MATCH関数　に説明がありますので参照してください。

商品の単価リストのコードは昇順に並んでいないので、MATCH関数の照合の型を　0 と指定する必要があります。
G4セルは　=INDEX($C$4:$C$9,MATCH(F4,$B$4:$B$9,0))　としました。
I4セルは　=INDEX($D$4:$D$9,MATCH(F4,$B$4:$B$9,0))*H4　で単価を取り出して販売数を乗じます。

	B	C	D	E	F	G	H	I
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数	販売金額
4	野菜-01	大根	150		野菜-03	=INDEX($C$4:$C$9,MATCH(F4,$B$4:$B$9,0))	20	=INDEX($D$4:$D$9,MATCH(F4,$B$4:$B$9,0))*H4
5	野菜-02	白菜	120		果物-02	=INDEX($C$4:$C$9,MATCH(F5,$B$4:$B$9,0))	15	=INDEX($D$4:$D$9,MATCH(F5,$B$4:$B$9,0))*H5
6	野菜-03	ピーマン	50		果物-01	=INDEX($C$4:$C$9,MATCH(F6,$B$4:$B$9,0))	18	=INDEX($D$4:$D$9,MATCH(F6,$B$4:$B$9,0))*H6
7	果物-01	りんご	180		野菜-02	=INDEX($C$4:$C$9,MATCH(F7,$B$4:$B$9,0))	21	=INDEX($D$4:$D$9,MATCH(F7,$B$4:$B$9,0))*H7
8	果物-02	みかん	130
9	果物-03	バナナ	140

XLOOKUP関数を使う方法

Microsoft365ではXLOOKUP関数やスピルの機能が使えるようになりました。
XLOOKUP関数の使い方は　XLOOKUP関数で範囲や配列を検索する　をご覧ください。
XLOOKUP関数は完全一致で検索しますので、リストが昇順に並んでいなくても検索ができます。
G4セルには　=XLOOKUP(F4:F7,B4:B9,C4:C9)　と入力します。
I4セルには　=XLOOKUP(F4:F7,B4:B9,D4:D9)*H4:H7　と入力します。

問題3の解答例　　　　 topへ

解答

	B	C	D	E	F	G	H
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数
4	野菜-01	大根	150		野菜-03	ピーマン	20
5	野菜-02	白菜	120		果物-02	みかん	15
6	野菜-03	ピーマン	50		野菜-01	大根	18
7	果物-01	りんご	180		果物-03	バナナ	21
8	果物-02	みかん	130
9	果物-03	バナナ	140

INDEX関数を使う	OFFSET関数を使う
XLOOKUP関数を使う方法

INDEX関数を使う

商品名をキーに検索することになります。
商品名は昇順に並んでいないので、LOOKUP関数は使用できません。
また、商品単価リストで商品名はコードの右側の列にあるので、VLOOKUP関数は使えません。

INDEX関数を使うことにします。
商品名は昇順に並んでいないので、MATCH関数の照合の型を　0 と指定する必要があります。
F4セルの数式は　=INDEX($B$4:$B$9,MATCH(G4,$C$4:$C$9,0))　とします。

	B	C	D	E	F	G	H
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数
4	野菜-01	大根	150		=INDEX($B$4:$B$9,MATCH(G4,$C$4:$C$9,0))	ピーマン	20
5	野菜-02	白菜	120		=INDEX($B$4:$B$9,MATCH(G5,$C$4:$C$9,0))	みかん	15
6	野菜-03	ピーマン	50		=INDEX($B$4:$B$9,MATCH(G6,$C$4:$C$9,0))	大根	18
7	果物-01	りんご	180		=INDEX($B$4:$B$9,MATCH(G7,$C$4:$C$9,0))	バナナ	21
8	果物-02	みかん	130
9	果物-03	バナナ	140

OFFSET関数を使う

OFFSET関数とMATCH関数を組み合わせることもできます。
OFFSET関数の構文：=OFFSET(基準,行数,列数 [,高さ,幅]）
詳細な使い方は　OFFSET関数をご覧ください。

OFFSET関数で　基準を　B3セルにして、MATCH関数と組み合わせて求めることができます。
F4セルの数式は　=OFFSET($B$3,MATCH(G4,$C$4:$C$9,0),0)　としました。

	B	C	D	E	F	G	H
2	商品単価リスト				販売実績
3	コード	商品名	単価		コード	商品名	販売数
4	野菜-01	大根	150		=OFFSET($B$3,MATCH(G4,$C$4:$C$9,0),0)	ピーマン	20
5	野菜-02	白菜	120		=OFFSET($B$3,MATCH(G5,$C$4:$C$9,0),0)	みかん	15
6	野菜-03	ピーマン	50		=OFFSET($B$3,MATCH(G6,$C$4:$C$9,0),0)	大根	18
7	果物-01	りんご	180		=OFFSET($B$3,MATCH(G7,$C$4:$C$9,0),0)	バナナ	21
8	果物-02	みかん	130
9	果物-03	バナナ	140

XLOOKUP関数を使う方法

Microsoft365ではXLOOKUP関数やスピルの機能が使えるようになりました。
XLOOKUP関数の使い方は　XLOOKUP関数で範囲や配列を検索する　をご覧ください。
XLOOKUP関数は完全一致で検索しますので、リストが昇順に並んでいなくても検索ができます。
G4セルには　=XLOOKUP(G4:G7,C4:C9,B4:B9)　と入力します。

問題4の解答例　　　　 topへ

解答

	B	C	D	E	F	G	H	I	J
2	名前	得点	判定		判定基準
3	相沢一郎	52	可		得点(以上)	0	40	60	80
4	井上浩二	74	良		判定	不可	可	良	優
5	上野有紀	84	優
6	内野武	32	不可
7	上田祥子	68	良
8	江田早苗	59	可
9	榎本高貴	80	優
10	小田和樹	60	良

HLOOKUP関数で求める	LOOKUP関数で求める
INDEX関数で求める	XLOOKUP関数を使う方法

HLOOKUP関数で求める

判定基準は上端行にあります。得点をキーとして検索するにはHLOOKUP関数が利用できます。

構文：=HLOOKUP(検索値,範囲,行番号,[検索の型])
HLOOKUP関数　に説明がありますので参照してください。

［検索値］未満の最大値を求めるので、HLOOKUP関数の引数の検索の型は TRUE または省略します。
D3セルの数式は　=HLOOKUP(C3,$G$3:$J$4,2)　としました。

	B	C	D	E	F	G	H	I	J
2	名前	得点	判定		判定基準
3	相沢一郎	52	=HLOOKUP(C3,$G$3:$J$4,2)		得点(以上)	0	40	60	80
4	井上浩二	74	=HLOOKUP(C4,$G$3:$J$4,2)		判定	不可	可	良	優
5	上野有紀	84	=HLOOKUP(C5,$G$3:$J$4,2)
6	内野武	32	=HLOOKUP(C6,$G$3:$J$4,2)
7	上田祥子	68	=HLOOKUP(C7,$G$3:$J$4,2)
8	江田早苗	59	=HLOOKUP(C8,$G$3:$J$4,2)
9	榎本高貴	80	=HLOOKUP(C9,$G$3:$J$4,2)
10	小田和樹	60	=HLOOKUP(C10,$G$3:$J$4,2)

LOOKUP関数で求める

判定基準の得点の行(G3:J3セル)の値は昇順に並んでいますので、LOOKUP関数を使うことができます。

=LOOKUP(検索値,検索範囲,対応範囲)
LOOKUP関数は［検索値］と一致する値なないときは、［検索値］未満の最大値を検索します。

D3セルの数式は　 =LOOKUP(C3,$G$3:$J$4)　としました。

	B	C	D	E	F	G	H	I	J
2	名前	得点	判定		判定基準
3	相沢一郎	52	=LOOKUP(C3,$G$3:$J$4)		得点(以上)	0	40	60	80
4	井上浩二	74	=LOOKUP(C4,$G$3:$J$4)		判定	不可	可	良	優
5	上野有紀	84	=LOOKUP(C5,$G$3:$J$4)
6	内野武	32	=LOOKUP(C6,$G$3:$J$4)
7	上田祥子	68	=LOOKUP(C7,$G$3:$J$4)
8	江田早苗	59	=LOOKUP(C8,$G$3:$J$4)
9	榎本高貴	80	=LOOKUP(C9,$G$3:$J$4)
10	小田和樹	60	=LOOKUP(C10,$G$3:$J$4)

INDEX関数で求める

INDEX関数を使うことができます。列位置を調べるのにMATCH関数を合わせて使います。
構文：=INDEX(範囲,行番号,[列番号],[領域番号])
INDEX関数　に説明がありますので参照してください。
構文：=MATCH(検査値,検査範囲,[照合の型])
MATCH関数　に説明がありますので参照してください。

D3セルの数式は　=INDEX($G$4:$J$4,0,MATCH(C3,$G$3:$J$3))　としました。
INDEX関数の引数[行番号」は 0 とし、列番号を　MATCH(C3,$G$3:$J$3) で求めています。

	B	C	D	E	F	G	H	I	J
2	名前	得点	判定		判定基準
3	相沢一郎	52	=INDEX($G$4:$J$4,0,MATCH(C3,$G$3:$J$3))		得点(以上)	0	40	60	80
4	井上浩二	74	=INDEX($G$4:$J$4,0,MATCH(C4,$G$3:$J$3))		判定	不可	可	良	優
5	上野有紀	84	=INDEX($G$4:$J$4,0,MATCH(C5,$G$3:$J$3))
6	内野武	32	=INDEX($G$4:$J$4,0,MATCH(C6,$G$3:$J$3))
7	上田祥子	68	=INDEX($G$4:$J$4,0,MATCH(C7,$G$3:$J$3))
8	江田早苗	59	=INDEX($G$4:$J$4,0,MATCH(C8,$G$3:$J$3))
9	榎本高貴	80	=INDEX($G$4:$J$4,0,MATCH(C9,$G$3:$J$3))
10	小田和樹	60	=INDEX($G$4:$J$4,0,MATCH(C10,$G$3:$J$3))

XLOOKUP関数を使う方法

Microsoft365ではXLOOKUP関数やスピルの機能が使えるようになりました。
XLOOKUP関数の使い方は　XLOOKUP関数で範囲や配列を検索する　をご覧ください。
=XLOOKUP(検索値,検索範囲,戻り範囲,[見つからない場合],[一致モード],[検索モード])
XLOOKUP関数は[一致モード]を-1とすると、完全一致で検索しますが、見つからない場合は、次の小さなアイテムが返されます。
G4セルには　=XLOOKUP(C3:C10,G3:J3,G4:J4,"該当なし",-1) と入力します。

スポンサードリンク

Home｜エクセル練習問題：目次｜列の検索・行の検索

PageViewCounter
Counter
Since2006/2/27