1. Home » 
2. Excel講座の総目次 » 
3. Excel講座 Q&A(Tips) » 
4. 住所から都道府県を取り出す/住所から都道府県を削除する

住所から都道府県を取り出す/住所から都道府県を削除する

更新:2026/6/24;作成:2018/2/21

住所から都道府県を取り出す　　　　Topへ

• 下記の住所からそれぞれ都道府県名を取り出してください。
  

  	B	C	D
  2	住所	都道府県を取り出す	都道府県を削除する
  3	北海道札幌市中央区北3条西	北海道	札幌市中央区北3条西
  4	岩手県盛岡市内丸	岩手県	盛岡市内丸
  5	埼玉県さいたま市浦和区高砂	埼玉県	さいたま市浦和区高砂
  6	千葉県千葉市中央区市場町	千葉県	千葉市中央区市場町
  7	東京都新宿区西新宿	東京都	新宿区西新宿
  8	神奈川県横浜市中区日本大通	神奈川県	横浜市中区日本大通
  9	京都府京都市上京区下立売通新町	京都府	京都市上京区下立売通新町
  10	大阪府大阪市中央区大手前	大阪府	大阪市中央区大手前
  11	和歌山県和歌山市小松原通	和歌山県	和歌山市小松原通
  12	岡山県岡山市北区内山下	岡山県	岡山市北区内山下
  13	広島県広島市中区基町	広島県	広島市中区基町
  14	宮崎県宮崎市橘通東	宮崎県	宮崎市橘通東
  15	鹿児島県鹿児島市鴨池新町	鹿児島県	鹿児島市鴨池新町

• 都道府県名には以下の規則が見られます。
  

  		文字数
  都	東京都	3文字
  道	北海道	3文字
  府	大阪府、京都府	3文字
  県	宮崎県、熊本県など	3文字
  県	鹿児島県、和歌山県、神奈川県	4文字

• 住所の左から4文字目が"県"であれば　鹿児島県、和歌山県、神奈川県のいずれかなので、4文字を取り出します。
  "県"ではなかったら、そのほかの都道府県名なので3文字を取り出せばよいと考えることができます。
• そのまま数式にすると、C3セルは
  =IF(MID(B3,4,1)="県",LEFT(B3,4),LEFT(B3,3))　
  となります。
• 取り出す文字数は4と3なのでLEFT関数の部分を一つにまとめることができそうです。
  =LEFT(B3,IF(MID(B3,4,1)="県",4,3))
  となりました。
• IF関数の部分を論理式に変更すると、
  =LEFT(B3,3+(MID(B3,4,1)="県"))
  とすることができます。
  (MID(B3,4,1)="県")がTRUEのときは 3+True=4　となり、FALSEのときは 3+False=3 となります。
• 
  

住所から都道府県を削除する　　　　Topへ

• 上の項で都道府県名を取り出すことができたので、
  取り出す都道府県名を空文字””に置き換えることで、都道府県を削除することができます。
  =SUBSTITUTE(B3,LEFT(B3,3+(MID(B3,4,1)="県")),"")
  

• 上記と同じように、4文字目に"県"が含まれるものと3文字で表示されるものの2パターンがあることになりますので
  4文字目が「県」である時は5文字目以降を、それ以外は4文字目以降を取り出せばよいと考えることができます。
• C3セルの数式は MID(B3,5,LEN(B3)-4)　と住所の文字数を数えて都道府県の文字数4（または3)を引いて取り出す文字数を計算しています。
  =IF(MID(B3,4,1)="県",MID(B3,5,LEN(B3)-4),MID(B3,4,LEN(B3)-3))
  MID関数では取り出す文字数が指定した文字列の数より多くてもエラーとなりませんので、
  MID(B3,5,LEN(B3))　としても同じ結果が得られます。
  よって、C4セルでは　=IF(MID(B3,4,1)="県",MID(B3,5,LEN(B3)),MID(B3,4,LEN(B3)))　としています。
  住所の文字数が100を超えることがないなら、=IF(MID(B3,4,1)="県",MID(B3,5,100),MID(B3,4,100))　とすることもできます。
• MID関数が2か所使われているので、これを一つにまとめたいと思います。
  =MID(B3,IF(MID(B3,4,1)="県",5,4),LEN(B3))
  とすることができます。
• 取り出す文字列は4文字以降か、5文字以降となるので
  =MID(B3,4+(MID(B3,4,1)="県"),LEN(B3))
  とすることができます。
• 
  

　PageViewCounter
　
　Since2006/2/27