Excel(エクセル)基本講座：カウント(COUNT)の関数

エクセルでデータ数を数えるワークシート関数の説明をしています。
数値データのセル数(COUNT関数)、全てのセル数(COUNTA関数)、空白のセル数(COUNTBLANK関数)
条件付きでセル数を求める(COUNTIF関数)、複数条件でのセル数(DCOUNT関数,DCOUNTA関数,SUMPRODUCT関数)
区間のセル数(FREQUENC関数)の使い方を解説しています。

スポンサードリンク

数値データのセルの数を数える(COUNT関数)	空白を除く全てのセル数を数える(COUNTA関数)
空白のセルの数を数える(COUNTBLANK関数)	名前をつける
条件付きでカウントする(COUNTIF関数)	複数条件でカウントする関数 (DCOUNT,DCOUNTA,SUMPRODUCT)
複数条件付きでカウントする(COUNTIFS関数)
区間のセル数を数える(FREQUENC関数)

数値データのセルを数える　　　　　 topへ
　カウント
=COUNT(範囲）

文字や数値、式などのデータが入力されているセルを数える未入力セルは数えません。
　カウントエー
=COUNTA(範囲)

空白のセルを数える
　カウントブランク
=COUNTBLANK(範囲)

「未入力セル」と「""」(長さ0の文字列)ではカウントのされ方が違います。
- 未入力セルと「""」(長さ0の文字列)はCOUNTBLANK関数ではカウントされます。
- 「""」(長さ0の文字列)はCOUNTA関数ではカウントされます。
- 下図ではB2:B5セルにはA2:A5で説明しているデータが入力されています。

【問題1】

セル範囲E4:E10とF4:F10の中で、数値データが入力されているセルの個数はいくつですか。E12とF12に数式を入れなさい。
セル範囲E4:E10とF4:F10の中から文字や数値の入力されているセルの個数はいくつですか。E13とF13に数式を入れなさい。
セル範囲E4:E10とF4:F10の中から空白のセルの個数はいくつですか。E14とF14に数式を入れなさい。

	B	C	D	E	F	G
2	2003	年
3	年月日	項目名	コード	収入	支出	収支
4	4月1日	繰り越し	17	12,345		12,345
5	4月10日	給与収入	1	200,000		212,345
6	4月12日	教育・教養費	10	なし	50,000	162,345
7	4月15日	保険料	4		30,000	132,345
8	4月16日	雑収入	3	5,000		137,345
9	4月17日	税金	5	なし	35,000	102,345
10	4月20日	食費	6		13,500	88,845
11			合計	217,345	128,500	88,845
12		数値セルの数		3	4
13		文字セルの数		5	4
14		空白セルの数		2	3

【解答1例】

セルの値が数値のセルをカウントするには、COUNT関数を使います。
セルの値が文字列のセルをカウントするには、COUNTA関数を使います。
セルの値が未入力および""のセルをカウントするには、COUNTBLANK関数を使います。

	B	C	D	E	F	G
2	2003年
3	年月日	項目名	コード	収入	支出	収支
4	4月1日	繰り越し	17	12,345		12,345
5	4月10日	給与収入	1	200,000		212,345
6	4月12日	教育・教養費	10	なし	50,000	162,345
7	4月15日	保険料	4		30,000	132,345
8	4月16日	雑収入	3	5,000		137,345
9	4月17日	税金	5	なし	35,000	102,345
10	4月20日	食費	6		13,500	88,845
11			合計	217,345	128,500	88,845
12		数値セルの数		=COUNT(E4:E10)	=COUNT(F4:F10)
13		文字セルの数		=COUNTA(E4:E10)	=COUNTA(F4:F10)
14		空白セルの数		=COUNTBLANK(E4:E10)	=COUNTBLANK(F4:F10)

【問題2】平均点を求めなさい。ただし欠席者はカウントしません。

	B	C	D
2	2003年	国語	1学期
3	出席番号	氏　名	中　間
4	1	相沢一郎	48
5	2	井上次男	75
6	3	上野光男	欠席
7	4	小川純一郎	77
8	5	柿元正二	64
9	6	桑田啓助	0
10	7	小島啓太	28
11
12		平均点	48.7
13

【解答2例】

得点の合計　/　受験者数(得点の入力があるセルの数)　と求めることができます。
=SUM(D4:D10)/COUNT(D4:D10)
=AVERAGE(D4:D10)　としても文字列のセルはカウントされないので結果は同じです。
なお、空白と「0」は区別されるので、欠席の場合のようにカウントしない場合には空白か欠席と文字列を入力します。
得点が「0」の場合は「0」と入力しないとカウントされません。

	B	C	D
2	2003	年　国語	1学期
3	出席番号	氏　名	中　間
4	1	相沢一郎	48
5	2	井上次男	75
6	3	上野光男	欠席
7	4	小川純一郎	77
8	5	柿元正二	64
9	6	桑田啓助	0
10	7	小島啓太	28
11
12		平均点	=SUM(D4:D10)/COUNT(D4:D10)
13			=AVERAGE(D4:D10)

検索条件に合うセルを数える。　　　　　topへ
　カウントイフ
=COUNTIF(範囲,検索条件)
　　　検索条件に文字や式を使う時には「"」(半角の二重引用符)で囲みます。

完全一致の検索

【問題1】忘年会の出欠表があります。出席と欠席の人数を計算しなさい。

	B	C	D
2	忘年会出欠表
3	氏名	出欠
4	相沢太郎	出席	出席
5	井上啓太	欠席	4
6	上野裕一	出席	欠席
7	榎田浩一	出席	2
8	大川肇	出席
9	柿元仁志	欠席

【解答1例】

COUNTIF関数を使って求めます。

	B	C	D
2	忘年会出欠表
3	氏名	出欠
4	相沢太郎	出席	出席
5	井上啓太	欠席	=COUNTIF(C4:C9,"出席")
6	上野裕一	出席	欠席
7	榎田浩一	出席	=COUNTIF(C4:C9,"欠席")
8	大川肇	出席
9	柿元仁志	欠席

=COUNTIF(C4:C9,D4)　と　=COUNTIF(C4:C9,D6)　のように「出席」「欠席」をセル参照してもOKです。

COUNTIF関数の関数の引数ダイアログでの設定状態
- D5セルの場合：【範囲】C4:C9、【検索条件】出席　または　D4　とします。
- 関数の引数ダイアログ内では文字列を入力すると「"」が補完されますので、入力しなくても大丈夫です。
  検索条件に「出席」と入力しても数式は=COUNTIF(C4:C9,"出席")となります。

部分一致の検索 - ワイルドカード文字を使って数える　　　　　topへ

【問題】

忘年会の出欠表です。欠席の後ろに理由が記入されています。
「出席」「欠席」の文字を使わず、D4,D6のセル参照で、数式を書きなさい。

	B	C	D
2	忘年会出欠表
3	氏名	出欠
4	相沢太郎	出席	出席
5	井上啓太	欠席(海外出張)	4
6	上野裕一	出席	欠席
7	榎田浩一	出席	2
8	大川肇	出席
9	柿元仁志	欠席(国内出張)

【解答例】

セル参照とワイルドカード文字をつなげて書く時には「&」を使います。
出席の数を数えるには「出席」のセルだけを数えればよいので、D4セルの「出席を利用して、　=COUNTIF(C4:C9,D4)　とすることができます。
欠席の数は「欠席」の欠席理由が付いており、共通するのは「欠席」で始まる文字列ということです。
「欠席」で始るというのは「欠席*」とワイルドカードを使って書くことができます。
ここではD6セルの値「欠席」を利用するので、& を使って D6&"*" とします。

	B	C	D
2	忘年会出欠表
3	氏名	出欠
4	相沢太郎	出席	出席
5	井上啓太	欠席(海外出張)	=COUNTIF(C4:C9,D4)
6	上野裕一	出席	欠席
7	榎田浩一	出席	=COUNTIF(C4:C9,D6&"*")
8	大川肇	出席
9	柿元仁志	欠席(国内出張)

検索条件の様々な書き方の例　　　　　topへ

【問題2】

セル範囲　E4:E10　のなかで　10000以上のセルの個数はいくつですか。E12に数式を入れなさい。
セル範囲　C4：C10　のなかで　［給与収入］のセルの個数はいくつですか。E13に数式を入れなさい。
セル範囲　C4:C10の中で「○○○収入」のセルの個数はいくつですか。E14に数式を入れなさい。
(ヒント)検索条件にはワイルドカードを使うことができます。

	B	C	D	E	F	G
2	2003	年
3	年月日	項目名	コード	収入	支出	収支
4	4月1日	繰り越し	17	12,345		12,345
5	4月10日	給与収入	1	200,000		212,345
6	4月12日	教育・教養費	10	なし	50,000	162,345
7	4月15日	保険料	4		30,000	132,345
8	4月16日	雑収入	3	5,000		137,345
9	4月17日	税金	5	なし	35,000	102,345
10	4月20日	食費	6		13,500	88,845
11			合計	217,345	128,500	88,845
12		値が10,000以上セルの数		2
13		給与収入のセルの数		1
14		○○収入のセルの数		2

【解答2例】

	B	C	D	E	F	G
2	2003	年
3	年月日	項目名	コード	収入	支出	収支
4	4月1日	繰り越し	17	12,345		12,345
5	4月10日	給与収入	1	200,000		212,345
6	4月12日	教育・教養費	10	なし	50,000	162,345
7	4月15日	保険料	4		30,000	132,345
8	4月16日	雑収入	3	5,000		137,345
9	4月17日	税金	5	なし	35,000	102,345
10	4月20日	食費	6		13,500	88,845
11			合計	217,345	128,500	88,845
12		値が10,000以上セルの数		=COUNTIF(E4:E10,">=10000")
13		給与収入のセルの数		=COUNTIF(C4:C10,"給与収入")
14		○○収入のセルの数		=COUNTIF(C4:C10,"*収入")
15		○○収入の平均値		=SUMIF(C4:C10,"収入",E4:E10)/COUNTIF(C4:C10,"収入")

【COUNTIF】関数の設定状態
- E12セルの場合：　【範囲】　E4:E10　　【検索条件】　">=10000"　とします。
- なお、検索条件に文字列を使う場合、前後の『"』(ダブルクォーテーション）は入力しなくてもExcelが追加してくれます。

○○以上△△未満のセル数を数える　　　　　topへ

【問題3】

セル範囲　C4:C10　のなかで　50以上100未満のセルの個数はいくつですか。E12に数式を入れなさい。

	B	C
2	2005年
3	月　日	売り上げ
4	4月1日	100
5	4月10日	47
6	4月12日	20
7	4月15日	72
8	4月16日	45
9	4月17日	60
10	4月20日	110
11
12	50以上100未満のセルの数	2

【解答3例】

100未満のセル数から50未満のセル数を差し引きます。

	B	C
2	2005年
3	月　日	売り上げ
4	4月1日	100
5	4月10日	47
6	4月12日	20
7	4月15日	72
8	4月16日	45
9	4月17日	60
10	4月20日	110
11
12	50以上100未満のセルの数	=COUNTIF(C4:C10,"<100")-COUNTIF(C4:C10,"<50")

なお、考え方によっては以下のような数式を考えることができますので補足しておきます。
50や100を含むのか含まないのかを間違わないように指定するのがポイントです。

（おまけ1）文字の数を検索条件としてセル数を数える。

=COUNTIF(C4:C7,"*")　とすると、文字の入力されているセルを数えることができます。
=COUNTA(C4:C7)-COUNT(C4:C7)　と同じです。
文字数を条件とする場合は、ワイルドカードの「?」を利用して文字数を決めます。

下表ではC列のカウントの文字数を調べています。

3文字の文字を表すには「???」とすることができます。=COUNTIF(C4:C7,"???")　として求めることができます。
下表では「???」を「REPT("?",3)」で求めて、=COUNTIF(C4:C7,REPT("?",3)) としています。

	B	C	D
2
3	品　名	カウント
4	りんご	+++	3文字のセル数(答え：3）
5	みかん	++++	=COUNTIF(C4:C7,REPT("?",3))
6	ぶどう	+++	4文字のセル数(答え：1)
7	なし	+++	=COUNTIF(C4:C7,REPT("?",4))

(おまけ2)SUM関数との組み合わせ方

複数条件のセルをカウントするには加算すればよいのですが、SUM関数と組み合わせることもできます。
- =SUM(COUNTIF(C4:C9,{"○","◎"}))　は　=SUM({3,1})　となり、4　が返ります。

	B	C	D
2	算数のテスト結果
3	氏名	判定	判定が◎と○の人数
4	相沢太郎	○	=COUNTIF(C4:C9,"○")+COUNTIF(C4:C9,"◎")
5	井上啓太	○	=SUM(COUNTIF(C4:C9,{"○","◎"}))
6	上野裕一	×	答え：「4」となります。
7	榎田浩一	△
8	大川肇	◎
9	柿元仁志	○

検索値にセル参照と不等号を組み合わせる　　　　　topへ

【問題5】

　合格基準がD5セルで与えられています。このセルを参照してD7セルに合格者数を表示しなさい。

	B	C	D
2	算数のテスト結果
3	氏名	期　末
4	相沢太郎	45	合格基準(点数以上)
5	井上啓太	60	60
6	上野裕一	75	合格者数
7	榎田浩一	41	4
8	大川肇	88
9	柿元仁志	70

【解答5例】

セル参照と比較演算子をくっつける場合には「&」を使います。

	B	C	D
2	算数のテスト結果
3	氏名	期　末
4	相沢太郎	45	合格基準(点数以上)
5	井上啓太	60	60
6	上野裕一	75	合格者数
7	榎田浩一	41	=COUNTIF(C4:C9,">="&D5)
8	大川肇	88
9	柿元仁志	70

重複データのチェックをする　　　　　topへ

【問題6】

本の受注表を作成しました。ところが、入力に重複があります。
注文者は重複している2つ目以降の行に「重複」と表示しなさい。

	B	C	D
2	注文数
3	氏　名	注文数	Check
4	相沢太郎	1冊
5	井上啓太	1冊
6	相沢太郎	1冊	重複
7	榎田浩一	1冊
8	相沢太郎	1冊	重複
9	柿元仁志	1冊

【解答6例】　

検索範囲を検索条件以前のセル範囲として、カウントし1を超えたら(2以上なら)「重複」と表示します。
この後、オートフィルタを使ってCheck欄が「重複」の行を抽出し、行削除すれば重複のないデータが得られます。

参照するセル範囲が「$B$4:B4」という形にして、データの先頭から該当セルまでを範囲としています。

	B	C	D
2	注文数
3	氏　名	注文数	Check
4	相沢太郎	1冊	=IF(COUNTIF($B$4:B4,B4)>1,"重複","")
5	井上啓太	1冊	=IF(COUNTIF($B$4:B5,B5)>1,"重複","")
6	相沢太郎	1冊	=IF(COUNTIF($B$4:B6,B6)>1,"重複","")
7	榎田浩一	1冊	=IF(COUNTIF($B$4:B7,B7)>1,"重複","")
8	相沢太郎	1冊	=IF(COUNTIF($B$4:B8,B8)>1,"重複","")
9	柿元仁志	1冊	=IF(COUNTIF($B$4:B9,B9)>1,"重複","")

参考資料　　　　topへ

XL97: Countif 関数は、空白セルで機能しません。
http://support.microsoft.com/kb/161757/ja/
[XL2002]SUMIF、COUNTIF、COUNTBLANK 関数で#VALUE!エラー
http://support.microsoft.com/kb/260415/ja/
[XL2000]32以上の数値とハイフンを含む文字でSUMIFの結果が正しくない
http://support.microsoft.com/kb/416463/ja/
Excel(エクセル)基本講座：条件に一致するセルをカウントする(COUNTIF関数,COUNTIFS関数)

COUNTIFS関数：複数の検索条件に一致するセルの個数を返します。　Topへ
カウント　イフズ
COUNTIFS(検索条件範囲1,検索条件1,検索条件範囲2,検索条件2...)
　　Excel2007で追加された関数です。

条件は「条件1AND条件2...」のANDでの結果になります。

（例題）下表で身長170以上の男性の数を求めなさい。

	B	C	D	E
2	名前	性別	身長	身長170以上の男性の数
3	相沢	男	165	2
4	井上	女	148
5	池田	男	175
6	石井	女	155
7	上野	男	168
8	内田	女	161
9	内村	男	178

（解答例）

	B	C	D	E
2	名前	性別	身長	身長170以上の男性の数
3	相沢	男	165	=COUNTIFS(C3:C9,"男",D3:D9,">=170")
4	井上	女	148
5	池田	男	175
6	石井	女	155
7	上野	男	168
8	内田	女	161
9	内村	男	178

Excel2003以前では、SUMPRODUCT関数を利用して計算できます。
- E2セル：=SUMPRODUCT((D3:D9>170)*(C3:C9="男"))
Excel(エクセル)基本講座：条件に一致するセルをカウントする(COUNTIF関数,COUNTIFS関数)　もご覧ください。

複数の条件に合うデータ数を数える　　　　　 topへ
　ディーカウント
=DCOUNT(Database,フィールド,Criteria)

データベースの指定された列を検索し、条件を満たすレコードの中で数値が入力されているセルの個数を返します。

　ディーカウントエー
=DCOUNTA(Database,フィールド,Criteria)

データベースの指定された列を検索し、条件を満たすレコードの中の空白でないセルの個数を返します。
データベース関数及びVersionによる注意点はこちらを参照のこと

【問題1】

下記の表で、住所が鹿児島で、年齢が30以上の人数を求めなさい。
G3セルにはDCOUNT関数を使い、G4セルにはDCOUNTA関数を使ってみましょう。

	B	C	D	E	F	G
2	名前	住所	年齢	住所	年齢	件数
3	井上	宮崎	25	鹿児島	>=30	2
4	会田	鹿児島	30			2
5	上野	宮崎	24
6	岡田	鹿児島	33
7	釜元	鹿児島	26
8	木下	宮崎	33

【解答例1】

検索条件をE2:F3セルに入力します。
- 「鹿児島」and「>=30」ですので、同一行に書きます。
DCOUNT関数では『数値が入力されているセルの個数』をカウントします。
- 数値の入力されている項目名をフィールド「年齢=D2」に指定します。
- =DCOUNT(B2:D8,D2,E2:F3)
  または
  =DCOUNT(B2:D8,"年齢",E2:F3)
DCOUNTA関数は『空白でないセルの個数』をカウントします。
- フィールドにはB2,C2,D2のどれを使ってもOKです。
- =DCOUNTA(B2:D8,C2,E2:F3)
  または
  =DCOUNTA(B2:D8,"住所",E2:F3)
  　など

	B	C	D	E	F	G
2	名前	住所	年齢	住所	年齢	件数
3	井上	宮崎	25	鹿児島	>=30	=DCOUNT(B2:D8,D2,E2:F3)
4	会田	鹿児島	30			=DCOUNTA(B2:D8,C2,E2:F3)
5	上野	宮崎	24
6	岡田	鹿児島	33
7	釜元	鹿児島	26
8	木下	宮崎	33

【別解1】SUMPRODUCT関数を使った例

=SUMPRODUCT((C3:C8="鹿児島")*(D3:D8>=30))　となります。

【問題2】

下記の表で、住所が鹿児島で、年齢が25歳以上30歳以下の人数を求めなさい。
G4セルにはDCOUNT関数を使ってみましょう。なお、条件は　青色のセルを使いなさい。

	B	C	D	E	F	G
2	名前	住所	年齢
3	井上	宮崎	25
4	会田	鹿児島	30			2
5	上野	宮崎	24
6	岡田	鹿児島	33
7	釜元	鹿児島	26
8	木下	宮崎	33

【問題2の解答例】

住所が鹿児島で年齢が25歳以上30歳以下の人数を求める場合。
F2:G3のように項目名「年齢」と年齢の条件「>=25」「<=30」を並べて書くことで、「>=25」and「<=30」となります。
(注)同一行に項目名と条件を並べます。

	B	C	D	E	F	G
2	名前	住所	年齢	住所	年齢	年齢
3	井上	宮崎	25	鹿児島	>=25	<=30
4	会田	鹿児島	30			=DCOUNTA(B2:D8,C2,E2:G3)
5	上野	宮崎	24
6	岡田	鹿児島	33
7	釜元	鹿児島	26
8	木下	宮崎	33

【別解1】SUMPRODUCT関数を使った例

=SUMPRODUCT((C3:C8="鹿児島")*(D3:D8>=25)*(D3:D8<=30))　　と、なります。

データの頻度分布を、縦方向の数値の配列として返す(度数分布)　　　　　topへ
　フリークエンシー
=FREQUENCY(データ配列,区間配列)

この関数は配列数式として入力する必要があります。
入力時に[Ctrl]+[Shift｣+[Enter]で確定します。

【問題】

テスト結果があります。40点以下、70点以下、100点以下の人数を計算しなさい。

	B	C	D	E	F
2	算数のテスト結果
3	氏名	期末
4	相沢太郎	45		40	0
5	井上啓太	60		70	4
6	上野裕一	75		100	2
7	榎田浩一	41
8	大川肇	88
9	柿元仁志	70

【解答例】
1. E4:E6に計算する区間を入力します。
2. 計算結果を表示するセル範囲F4:F6を選択します。
3. F4セルに　=FREQUENCY(C4:C9,E4:E6)　と入力し、[Ctrl]+[Shift｣+[Enter]で確定します。
  または、=FREQUENCY(C4:C9,{40,70,100})　と区間を値で入力することもできます。
  (最大値が100と決まっている場合、上限を定めず=FREQUENCY(C4:C9,{40,70})とすることもできます)
  - 「関数の引数」ダイアログでの指定は下図のようにし、[Ctrl]+[Shift｣を押しながら「OK」ボタンをクリックします。
    (あらかじめセル範囲F4:F6を選択しておきます）

【別解】COUNTIF関数を使って計算します。

F4セル：=COUNTIF($C$4:$C$9,"<="&E4)
数値を数式内に書くと　=COUNTIF($C$4:$C$9,"<=40")　とします。
セル参照の時と値を書く時とは、ちょっと異なりますので注意してください。
F5セル：=COUNTIF($C$4:$C$9,"<="&E5)-COUNTIF($C$4:$C$9,"<="&E4)
F6セル：=COUNTIF($C$4:$C$9,"<="&E6)-COUNTIF($C$4:$C$9,"<="&E5)

	B	C	D	E	F
2	算数のテスト結果
3	氏名	期末
4	相沢太郎	45		40	=COUNTIF($C$4:$C$9,"<="&E4)
5	井上啓太	60		70	=COUNTIF($C$4:$C$9,"<="&E5)-COUNTIF($C$4:$C$9,"<="&E4)
6	上野裕一	75		100	=COUNTIF($C$4:$C$9,"<="&E6)-COUNTIF($C$4:$C$9,"<="&E5)
7	榎田浩一	41
8	大川肇	88
9	柿元仁志	70

スポンサードリンク

よねさんのWordとExcelの小部屋 » エクセル関数一覧表 » カウント(COUNT)の関数

PageViewCounter
Counter
Since2006/2/27

Excel(エクセル)基本講座：カウント(COUNT)の関数

数値データのセルを数える topへ カウント =COUNT(範囲）

文字や数値、式などのデータが入力されているセルを数える 未入力セルは数えません。 カウントエー =COUNTA(範囲)

空白のセルを数える カウントブランク =COUNTBLANK(範囲)

検索条件に合うセルを数える。 topへ カウントイフ =COUNTIF(範囲,検索条件) 検索条件に文字や式を使う時には「"」(半角の二重引用符)で囲みます。

完全一致の検索

部分一致の検索 - ワイルドカード文字を使って数える topへ

検索条件の様々な書き方の例 topへ

○○以上△△未満のセル数を数える topへ

（おまけ1）文字の数を検索条件としてセル数を数える。

(おまけ2)SUM関数との組み合わせ方

検索値にセル参照と不等号を組み合わせる topへ

重複データのチェックをする topへ

参考資料 topへ

COUNTIFS関数：複数の検索条件に一致するセルの個数を返します。 Topへ カウント イフズ COUNTIFS(検索条件範囲1,検索条件1,検索条件範囲2,検索条件2...) Excel2007で追加された関数です。

複数の条件に合うデータ数を数える topへ ディーカウント =DCOUNT(Database,フィールド,Criteria)

ディーカウントエー =DCOUNTA(Database,フィールド,Criteria)

【別解1】SUMPRODUCT関数を使った例

【別解1】SUMPRODUCT関数を使った例

データの頻度分布を、縦方向の数値の配列として返す(度数分布) topへ フリークエンシー =FREQUENCY(データ配列,区間配列)

数値データのセルを数える　　　　　 topへ
　カウント
=COUNT(範囲）

文字や数値、式などのデータが入力されているセルを数える未入力セルは数えません。
　カウントエー
=COUNTA(範囲)

空白のセルを数える
　カウントブランク
=COUNTBLANK(範囲)

検索条件に合うセルを数える。　　　　　topへ
　カウントイフ
=COUNTIF(範囲,検索条件)
　　　検索条件に文字や式を使う時には「"」(半角の二重引用符)で囲みます。

部分一致の検索 - ワイルドカード文字を使って数える　　　　　topへ

検索条件の様々な書き方の例　　　　　topへ

○○以上△△未満のセル数を数える　　　　　topへ

検索値にセル参照と不等号を組み合わせる　　　　　topへ

重複データのチェックをする　　　　　topへ

参考資料　　　　topへ

COUNTIFS関数：複数の検索条件に一致するセルの個数を返します。　Topへ
カウント　イフズ
COUNTIFS(検索条件範囲1,検索条件1,検索条件範囲2,検索条件2...)
　　Excel2007で追加された関数です。

複数の条件に合うデータ数を数える　　　　　 topへ
　ディーカウント
=DCOUNT(Database,フィールド,Criteria)

　ディーカウントエー
=DCOUNTA(Database,フィールド,Criteria)

データの頻度分布を、縦方向の数値の配列として返す(度数分布)　　　　　topへ
　フリークエンシー
=FREQUENCY(データ配列,区間配列)