1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. 条件付きで最小値を求める

MINIFS関数の使い方(条件付きで最小値を求める):Excel関数

更新:2024/10/24;作成:2016/4/11

条件に合致したセルの最小値を求めます　　　
　ミン イフズ
=MINIFS(最小範囲,条件範囲1,条件1,[条件範囲2,条件2],・・・)

• 条件に合うセルの最小値を求める ことができます。
  複数の条件を指定した場合は、AND条件として計算されます。
• MINIFS関数はExcel2019,Excel for Microsoft 365で使用できます。

複数条件(AND条件)を満たす最小値を求める

• 	B	C	D	E	F	G	H
  2	販売店	種類	数量		販売店	種類	最小値
  3	姶良店	りんご	30		鹿児島店	りんご	34
  4	鹿児島店	りんご	34		鹿児島店	バナナ	71
  5	姶良店	りんご	41		鹿児島店	みかん	20
  6	鹿児島店	バナナ	80
  7	姶良店	りんご	62
  8	姶良店	バナナ	64
  9	鹿児島店	みかん	20
  10	鹿児島店	バナナ	71
  11	姶良店	みかん	63
  12	鹿児島店	りんご	61
  13	鹿児島店	みかん	43

• H3セルの数式は　=MINIFS($D$3:$D$13,$B$3:$B$13,F3,$C$3:$C$13,G3) とします。
  H3セルの数式を　H4:H5セルへコピー&貼り付けして完成です。
  

• H3セルの数式は　=MINIFS(D3:D13,B3:B13,F3:F5,C3:C13,G3:G5)　 とします。
  数式はH3セルだけに入力しますので、引数のセル範囲は相対参照でOKです。
  Spillの機能でF5セルまで数式があふれ出します。
  

【問題1の解答例3】MINIFS関数がつかえない場合は配列数式を利用することができます。

• H3セルに　{=MIN(IF(($B$3:$B$13=F3)*($C$3:$C$13=G3),$D$3:$D$13,""))}　とします。
  条件は論理積で ($B$3:$B$13=F3)*($C$3:$C$13=G3) とします。
  配列数式なので、=MIN(IF(($B$3:$B$13=F3)*($C$3:$C$13=G3),$D$3:$D$13,""))　と入力して、[Shift]+[Ctrl]+[Enter]　で入力します。すると数式が　{ }　でくくられた配列数式になります。
  H4:H5セルへH3セルの数式をコピーします。
  

【問題1の解答例4】Excel for Microsoft365ではFILTER関数でも同じ計算が可能です。

• H3セルに　=MIN(FILTER($D$3:$D$13,($B$3:$B$13=F3)*($C$3:$C$13=G3)))　と[Ctrl]+[Enter]で入力します。
  [Shift]+[↓]キーを押して、H3:H5セルを選択して、[Ctrl]+[D]でF3セルの数式をコピーします。
  
• ほかにもいろいろな方法がありますので　エクセル関数の技：条件付きで最大値、最小値を求める　をご覧ください。

複数条件(OR条件)を満たす最小値を求める

【問題2】 OR条件で複数条件の最小値を求める

• 販売店が鹿児島店または指宿店である、各果物の最小値を求めなさい。
  

  	B	C	D	E	F	G	H	I
  2	販売店	種類	数量		販売店	販売店	種類	最小値
  3	姶良店	りんご	30		鹿児島店	指宿店	りんご	47
  4	指宿店	りんご	47		鹿児島店	指宿店	バナナ	55
  5	姶良店	りんご	41		鹿児島店	指宿店	みかん	39
  6	鹿児島店	バナナ	80
  7	姶良店	りんご	62
  8	姶良店	バナナ	64
  9	指宿店	みかん	39
  10	指宿店	バナナ	55
  11	姶良店	みかん	63
  12	鹿児島店	りんご	61
  13	鹿児島店	みかん	43

• OR条件で求める場合は、各条件の最小値を求めて、それらの最小値をMIN関数で求めればよいです。
  =MIN(MINIFS(1つめの条件の最小値),MINIFS(2つめの条件の最小値))　のようなイメージです。
  I3セルには
  =MIN(MINIFS($D$3:$D$13,$B$3:$B$13,F3,$C$3:$C$13,H3),
  MINIFS($D$3:$D$13,$B$3:$B$13,G3,$C$3:$C$13,H3))
  と入力して、I4:I5セルに数式をコピーします。
  

0を除いた最小値を求める

• 【問題3】 B列で0を除いた最小値を求めなさい。
  ちなみに、=MIN(C2:C14)　では　0　となってしまいます。
  

  	B	C	D	E
  2				0を除いた最小値は？
  3	A	50
  4	B	85
  5	C	0
  6	A	35
  7	B	76
  8	C	17
  9	A	44
  10	B	0
  11	C	44
  12	A	24
  13	B	0
  14	C	83

• 【問題3の解答例】数式は　=MINIFS(C3:C14,C3:C14,"<>0")　となります。
  条件範囲を　C3:C14　として、条件を　"<>0"　(0と等しくない)　としています。
  
• 配列数式を使う場合は、{=MIN(IF(C3:C14<>0,C3:C14))}　とします。
  
• FILTER関数を使う場合は、=MIN(FILTER(C3:C14,C3:C14<>0))　とします。
  

スポンサードリンク

PageViewCounter

Since2006/2/27