Excel(エクセル)基本講座：合計の関数(SUM,SUMIF)

• エクセルの合計に関する関数（SUM関数,SUMIF関数,DSUM関数,SUBTOTAL関数)
  およびオートサム(オートSUM)、定義した名前やワイルドカードを使う方法について説明しています。

合計の関数(SUM)	オートSUM	条件付き合計(SUMIF)
複数条件の合計(DSUM)	途中に小計を入れたい(SUBTOTAL)
名前をつける	ワイルドカード

合計します　　　topへ
　サム
=SUM(範囲)

• 合計の数式 =A1+A2+A3+A4+A5　は　=SUM(A1:A5) と書くことができます。
• A1〜A5セルのいずれかに文字列の値がある場合、
  「+」を使った数式はエラー(#VALUE!)になりますが、SUM関数を使うと文字列は無視して計算されます。

[A]連続した範囲の合計を求める　　　　topへ

【問題1】収入金額と支出金額の合計を求めなさい。

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月15日	繰越金	3月分繰越金	10,000
  4	4月19日	会費	会費(19人分)	7,600
  5	4月20日	図書費	新聞代		3,000
  6	4月25日	会費	会費(63人分)	25,200
  7	4月26日	図書費	新聞代		5,000
  8	5月10日	諸費	コピー代		4,800
  9	5月12日	図書費	本代		12,000
  10	5月18日	諸費	工具代		14,200
  11	5月20日	会費	会費(2人分)	800
  12			合計	43,600	39,000

【解答例】SUM関数を使った解答例です。

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月15日	繰越金	3月分繰越金	10,000
  4	4月19日	会費	会費(19人分)	7,600
  5	4月20日	図書費	新聞代		3,000
  6	4月25日	会費	会費(63人分)	25,200
  7	4月26日	図書費	新聞代		5,000
  8	5月10日	諸費	コピー代		4,800
  9	5月12日	図書費	本代		12,000
  10	5月18日	諸費	工具代		14,200
  11	5月20日	会費	会費(2人分)	800
  12			合計	=SUM(E3:E11)	=SUM(F3:F11)

オートSUMボタン『Σ』を使った入力方法　　　topへ

• さまざまな『�煤xの使い方は→オートサムボタンの使い方(オートSUMボタン)を参照してください。

1. 合計を表示するセルE12をクリックし、アクティブにします。
2. ツールバーの【Σ】オートSUMボタンをクリックします。
3. セルE11に青い枠が表示され、E12には『=SUM(E11)』と表示されます。
   • 下記の例では収入金額のセルE3〜E11に空白セルがあるため、正しい範囲が設定されません。
     （セル範囲 E3〜E11 に空白セルを含まなければ、正しく範囲が設定されます。）
   • 正しいセル範囲を指定します。
     1. E3:E11 をドラッグして指定します。
     2. 合計するセル範囲は、E3：E11ですので、E11セルの青枠線(カラーリファレンス)の上角にマウスポインタを重ねE3までドラッグします。
     
4. 青枠線でE3：E11を囲むと、数式は『=SUM(E3：E11)』と正しく設定できます。
5. 【Enter】キーを押します。(数式バーの左にある緑のチェックマークをクリックしても良い)
6. E12セルからオートフィルを使ってF12に数式をコピーします。

[B-1]不連続の範囲の合計を求める　　　　topへ

【問題2】収入と支出の合計をD8:D9セルに求めなさい。

• 	B	C	D	E	F
  2		会費(収入)	図書費(支出)	雑収入(収入)	諸費(支出)
  3	1月	25,000	12,000	2,000	4,200
  4	2月	32,000	8,200	1,500	5,120
  5	3月	28,000	11,000	1,100	6,200
  6	4月	31,000	4,200	1,600	2,520
  7
  8		収入の合計	122,200
  9		支出の合計	53,440

【解答例】

• 範囲と範囲の区切りには「,」(カンマ)を使います。
• =SUM(範囲1,範囲2,範囲3,・・・・)　の形式になります。

• 	B	C	D	E	F
  2		会費(収入)	図書費(支出)	雑収入(収入)	諸費(支出)
  3	1月	25,000	12,000	2,000	4,200
  4	2月	32,000	8,200	1,500	5,120
  5	3月	28,000	11,000	1,100	6,200
  6	4月	31,000	4,200	1,600	2,520
  7
  8		収入の合計	=SUM(C3:C6,E3:E6)
  9		支出の合計	=SUM(D3:D6,F3:F6)

(入力方法-1)　オートSUMボタンを使う方法　　　　topへ

1. D8セルをクリックしてアクティブにします。
2. オートSUM 【Σ】ボタンをクリックします。
3. セル範囲　C3:C6　をドラッグして選択します。
4. キーボードから『，』(カンマ)を入力します。
5. セル範囲　E3:E6　をドラッグして選択します。
6. 【Enter】キーを押します。
   

• マウス操作で、セル範囲　C3:C6　をドラッグして選択し、[Ctrl]キーを押しながらセル範囲　E3:E6　をドラッグして選択しても同じ様にできます。

(入力方法-2)　【関数の挿入】ボタンを使う方法　　　　topへ

1. D8セルをクリックしてアクティブにします。
2. 数式バーの関数の挿入【fx】ボタンをクリックし、表示される関数の挿入ダイアログで【SUM】を選択します。
3. 【関数の引数】ダイアログで、
   • 【数値1】の欄をクリックしてカーソルを表示し、セル範囲　C3:C6　をドラッグして選択します。
   • 【数値2】の欄をクリックしてカーソルを表示し、セル範囲　E3:E6　をドラッグして選択します。
4. 下図のように設定して、【OK】ボタンをクリックします。
   

[B-2]不連続の範囲の合計を求める　　　　　topへ

【問題3】集計表の合計(D10:D11)を完成しなさい。

• 	B	C	D
  2	月	項目名	金額
  3	4月	収入金額	54,000
  4		支出金額	38,500
  5	5月	収入金額	62,000
  6		支出金額	46,700
  7	6月	収入金額	57,000
  8		支出金額	58,900
  9
  10	合計	収入金額	173,000
  11		支出金額	144,100

【解答例】不連続な値の合計は、「，」(カンマ)で値を列記します。

• 	B	C	D
  2	月	項目名	金額
  3	4月	収入金額	54,000
  4		支出金額	38,500
  5	5月	収入金額	62,000
  6		支出金額	46,700
  7	6月	収入金額	57,000
  8		支出金額	58,900
  9
  10	合計	収入金額	=SUM(D3,D5,D7)
  11		支出金額	=SUM(D4,D6,D8)

【関連事項】SUM関数以外の方法

• SUMPRODUCT関数を使う方法
• 一行おきの合計については こちらも参照ください。

小計の関数(表示されているセル範囲の合計)など　　　topへ
　サブトータル
=SUBTOTAL(集計方法,範囲)
　　集計方法はExcel2002以前とExcel2003以降とで若干異なります。集計方法についてをご覧ください

集計方法について

• Excel2003以降では「非表示の値を無視する」ことが指定できるようになりました。
  なお、Excel2002以前ではオートフィルタをかけた状態での非表示セルは無視されますが、書式→行→非表示とした場合は計算されます。
  • 【例】セル範囲の合計をする場合、集計方法は「9」または「109」
    • 非表示の値も含める場合：=SUBTOTAL(9,A1:A10)
    • 非表示の値を無視する場合：　=SUBTOTAL(109,A1:A10)

  • 非表示の値も含める	非表示の値を無視する	関数
    Excel2002以前はこちらだけが指定できます	Excel2003以降はこちらも使用できます
    1	101	AVERAGE
    2	102	COUNT
    3	103	COUNTA
    4	104	MAX
    5	105	MIN
    6	106	PRODUCT
    7	107	STDEV
    8	108	STDEVP
    9	109	SUM
    10	110	VAR
    11	111	VARP

【問題1】表内の小計と合計を求めなさい。

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月19日	会費	会費(19人分)	7,600
  4	4月25日	会費	会費(63人分)	25,200
  5	5月20日	会費	会費(2人分)	800
  6			小計	33,600	0
  7	5月10日	諸費	コピー代		4,800
  8	5月18日	諸費	工具代		14,200
  9			小計	0	19,000
  10	4月20日	図書費	新聞代		3,000
  11	4月26日	図書費	新聞代		5,000
  12	5月12日	図書費	本代		12,000
  13			小計	0	20,000
  14			合計	33,600	39,000

【解答1例】

• SUBTOTAL関数で合計『9』を使った例です。
• SUBTOTALは範囲内に含まれるSUBTOTALの値は無視しますので、合計のセルE14:F14のような使い方ができます。

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月19日	会費	会費(19人分)	7,600
  4	4月25日	会費	会費(63人分)	25,200
  5	5月20日	会費	会費(2人分)	800
  6			小計	=SUBTOTAL(9,E3:E5)	=SUBTOTAL(9,F3:F5)
  7	5月10日	諸費	コピー代		4,800
  8	5月18日	諸費	工具代		14,200
  9			小計	=SUBTOTAL(9,E7:E8)	=SUBTOTAL(9,F7:F8)
  10	4月20日	図書費	新聞代		3,000
  11	4月26日	図書費	新聞代		5,000
  12	5月12日	図書費	本代		12,000
  13			小計	=SUBTOTAL(9,E10:E12)	=SUBTOTAL(9,F10:F12)
  14			合計	=SUBTOTAL(9,E3:E13)	=SUBTOTAL(9,F3:F13)

(入力方法)　【関数の挿入】ボタンを使う方法　　　topへ

1. E14セルをクリックしてアクティブにします。
2. 関数の挿入【fx】ボタンをクリックし、表示される関数の挿入ダイアログで【SUBTOTAL】を選択します。
3. 【関数の引数】ダイアログで、
   • 【集計方法】の欄を選択し、 9 をキーボードから入力します。
   • 【範囲1】の欄を選択し、シートのセル範囲 E3:E13 をドラッグして選択します。
4. 【OK】ボタンをクリックします。
   

オートフィルタとの組み合わせで表示セルのみの合計を計算する例です

• C10セルに「=SUBTOTAL(9,C2:C8)」と入力してあります。
• オートフィルタで合計行が含まれないように、表と合計行の間に空白行を挟みます。
  

1. リストA1:C8のいずれかのセルを選択し、【データ】→【フィルタ】→【オートフィルタ】を選択します。
2. クラスで「1」を選択。またはクラスで「2」を選択するとそれぞれ抽出されたデータの合計が表示されます。
   

   クラスで「1」を選択した例	クラスで「2」を選択した例

オートフィルタで抽出したデータに連続Noを付ける例です

• A2セルに「=SUBTOTAL(3,$C$2:C2)」と入力し、A8セルまでフィルハンドルをドラッグして、コピーします。
  集計方法に「3=COUNTA」を使って、C列の文字列のセル数を数えています。
  

1. クラスで「1」を選択。またはクラスで「2」を選択するとそれぞれ抽出されたデータに連続したNoが表示されます。
   

   クラスで「1」を選択した例	クラスで「2」を選択した例

条件付き合計　　topへ
　サムイフ
=SUMIF(検索範囲,検索条件,合計範囲)

• SUMPRODUCT関数を用いて、複数条件により合計を求めることもできます。→こちらで説明しています。

【問題】下の集計表で各項目名ごとの合計を計算しなさい。

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月15日	繰越金	3月分繰越金	10,000
  4	4月19日	会費	会費(19人分)	7,600
  5	4月20日	図書費	新聞代		3,000
  6	4月25日	会費	会費(63人分)	25,200
  7	4月26日	図書費	新聞代		5,000
  8	5月10日	諸費	コピー代		4,800
  9	5月12日	図書費	本代		12,000
  10	5月18日	諸費	工具代		14,200
  11	5月20日	会費	会費(2人分)	800
  12			合計	43,600	39,000
  13
  14	項目名	収入金額		支出金額
  15	会費	33,600		0
  16	図書費	0		20,000
  17	諸費	0		19,000

【解答例】

1. セルC15に入力する数式は、検索範囲C3:C11、検索条件は『会費』、合計範囲はE3:E11　となります。
   • =SUMIF(C3:C11,"会費",E3:E11）
     （注）文字列「会費」は「"」(ダブルクォーテーション)で囲みます。
     または
     =SUMIF(C3:C11,B15,E3:E11）
2. このままでは数式をコピーすると範囲の参照がずれてしまいますので、絶対参照に変更します。
   • 検索範囲：C3:C11は固定した範囲ですので、絶対参照で『$C$3:$C$11』とします。
   • 検索条件：『会費』はB15セルの値と同一であり、この列は変わらないので、列だけ絶対参照　にし、『$B15』とします。
   • 合計範囲：E3:E11ですが、この範囲も固定なので、絶対参照で『$E$3:$E$11』となります。
   • 支払金額は1列右に動きますので、行だけ絶対参照にし、『E$3:E$11』となります。
3. =SUMIF($C$3:$C$11,$B15,E$3:E$11)
   となります。
4. セルC15の数式をC16,C17,E15,E16,E17にコピーして完成です。
   

   	B	C	D	E	F
   2	月　日	項目名	適用	収入金額	支出金額
   3	4月15日	繰越金	3月分繰越金	10,000
   4	4月19日	会費	会費(19人分)	7,600
   5	4月20日	図書費	新聞代		3,000
   6	4月25日	会費	会費(63人分)	25,200
   7	4月26日	図書費	新聞代		5,000
   8	5月10日	諸費	コピー代		4,800
   9	5月12日	図書費	本代		12,000
   10	5月18日	諸費	工具代		14,200
   11	5月20日	会費	会費(2人分)	800
   12			合計	43,600	39,000
   13
   14	項目名	収入金額		支出金額
   15	会費	=SUMIF($C$3:$C$11,$B15,E$3:E$11)		=SUMIF($C$3:$C$11,$B15,F$3:F$11)
   16	図書費	=SUMIF($C$3:$C$11,$B16,E$3:E$11)		=SUMIF($C$3:$C$11,$B16,F$3:F$11)
   17	諸費	=SUMIF($C$3:$C$11,$B17,E$3:E$11)		=SUMIF($C$3:$C$11,$B17,F$3:F$11)
   18	相対参照では次のようになります。（$を取り除いた式になります)
   19	会費	=SUMIF(C3:C11,B15,E3:E11)		=SUMIF(C3:C11,B15,F3:F11)
   20	図書費	=SUMIF(C3:C11,B16,E3:E11)		=SUMIF(C3:C11,B16,F3:F11)
   21	諸費	=SUMIF(C3:C11,B17,E3:E11)		=SUMIF(C3:C11,B17,F3:F11)

(入力方法)　【関数の挿入】ボタンを使う方法　　　　topへ

1. C15セルをクリックしてアクティブにします。
2. 関数の挿入【fx】ボタンをクリックし、表示される関数の挿入ダイアログで【SUMIF】を選択します。
3. 【関数の引数】ダイアログで、
   • 【範囲】の欄を選択し、シートのC3:C11セルを選択します。絶対参照にするため【F4】キーを押して、$C$3:$C$11 とします。
   • 【検索条件】の欄を選択し、シートのB15セルを選択します。絶対参照にするため【F4】キーを押して　$B15 とします。
   • 【合計範囲】の欄を選択し、シートの　E3:E11セルを選択します。絶対参照にするため【F4】キーを押して、$E$3:$E$11 とします。
4. 【OK】ボタンをクリックします。
   

ワイルドカード文字　　　文字列の検索、置換時に使用します　　　　　topへ
　？は任意の 1 文字
　　例）鹿児島県や鹿児島市を指定したい場合1文字(県と市）だけ異なるので、「鹿児島？」とします。
　＊は任意の数の文字
　　例)鹿児島県　宮崎県　など　県を含む文字を指定したい場合、鹿児島（3文字）と宮崎（2文字）が異なるので「＊県」とします。
　　※　？や＊の検索には　~(チルダ)　を使用します。

【問題】下表の中の「PTA会費」、「児童会費」、「父兄会費」を集計表の【会費】欄に計算しなさい。

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月15日	繰越金	3月分繰越金	10,000
  4	4月19日	PTA会費	会費(19人分)	7,600
  5	4月20日	図書費	新聞代		3,000
  6	4月25日	児童会費	会費(63人分)	25,200
  7	4月26日	図書費	新聞代		5,000
  8	5月10日	諸費	コピー代		4,800
  9	5月12日	図書費	本代		12,000
  10	5月18日	諸費	工具代		14,200
  11	5月20日	父兄会費	会費(2人分)	800
  12			合計	43,600	39,000
  13
  14	項目名	収入金額
  15	会費	33,600

【解答例】

• 「PTA会費」、「児童会費」、「父兄会費」は全て【会費】という文字を最後に含みます。
  別な言い方をすれば、『「会費」で終わる文字列である』とも言えます。
• ワイルドカード文字「*」(アスタリスク:半角文字)を組み合わせて、『*会費』を検索条件とします。

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月15日	繰越金	3月分繰越金	10,000
  4	4月19日	PTA会費	会費(19人分)	7,600
  5	4月20日	図書費	新聞代		3,000
  6	4月25日	児童会費	会費(63人分)	25,200
  7	4月26日	図書費	新聞代		5,000
  8	5月10日	諸費	コピー代		4,800
  9	5月12日	図書費	本代		12,000
  10	5月18日	諸費	工具代		14,200
  11	5月20日	父兄会費	会費(2人分)	800
  12			合計	43,600	39,000
  13
  14	項目名	収入金額
  15	会費	=SUMIF(C3:C11,"*会費",E3:E11)

• 検索条件の書き方(例)
  
  • A1セルを参照する場合は「">"&A1」のように&でつなぎます。
• 【関連情報】
  • [XL2002]SUMIF、COUNTIF、COUNTBLANK 関数で#VALUE!エラー
    http://support.microsoft.com/kb/260415/JA/
  • [XL2000]32以上の数値とハイフンを含む文字でSUMIFの結果が正しくない
    http://support.microsoft.com/kb/416463/JA/

複数条件の合計　　　　　　topへ
　ディーサム
=DSUM(検索範囲,集計項目(フィールド),検索条件範囲）
　　　検索条件範囲を作成することによって、複数の条件で集計ができます。

OR条件

【問題】「図書費」または「諸費」の「支払金額」の合計を計算しなさい。(検索条件をC15:C16、計算結果をE15に表示します。)

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月15日	繰越金	3月分繰越金	10,000
  4	4月19日	会費	会費(19人分)	7,600
  5	4月20日	図書費	新聞代		3,000
  6	4月25日	会費	会費(63人分)	25,200
  7	4月26日	図書費	新聞代		5,000
  8	5月10日	諸費	コピー代		4,800
  9	5月12日	図書費	本代		12,000
  10	5月18日	諸費	工具代		14,200
  11	5月20日	会費	会費(2人分)	800
  12			合計	43,600	39,000
  13
  14		項目名		支出金額
  15				39,000
  16
  17

【解答例】

1. 検索条件に「図書費」と「諸費」をC14、C15セルに入力します。
   • 同一列に入力していますので「図書費」または「諸費」の”OR"条件になります。
   • （同一行に入力した場合は”AND”条件になります。）
2. 検索範囲はデータ表のB2:G11、集計項目はF2セルの"支出金額"、検索条件範囲はC14:C16となります。
   検索範囲には見出し「2」行目を含めた範囲とします。

【別解】

• 集計項目(フィールド)には列の位置を入力することもできます。
• 支出金額は検索範囲の左から5番目の列なので「5」と指定します。
  =DSUM(B2:G11,5,C14:C16)

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月15日	繰越金	3月分繰越金	10,000
  4	4月19日	会費	会費(19人分)	7,600
  5	4月20日	図書費	新聞代		3,000
  6	4月25日	会費	会費(63人分)	25,200
  7	4月26日	図書費	新聞代		5,000
  8	5月10日	諸費	コピー代		4,800
  9	5月12日	図書費	本代		12,000
  10	5月18日	諸費	工具代		14,200
  11	5月20日	会費	会費(2人分)	800
  12			合計	43,600	39,000
  13
  14		項目名		支出金額
  15		図書費		=DSUM(B2:G11,"支出金額",C14:C16)
  16		諸費		=DSUM(B2:G11,5,C14:C16)
  17				=DSUM(B2:G11,E14,C14:C16)

AND,OR条件　　　　　topへ

【問題】4月分の「図書費」または「諸費」の「支払金額」の合計を計算しなさい。検索条件はB14:D16、計算結果はE15に表示します。

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月15日	繰越金	3月分繰越金	10,000
  4	4月19日	会費	会費(19人分)	7,600
  5	4月20日	図書費	新聞代		3,000
  6	4月25日	会費	会費(63人分)	25,200
  7	4月26日	図書費	新聞代		5,000
  8	5月10日	諸費	コピー代		4,800
  9	5月12日	図書費	本代		12,000
  10	5月18日	諸費	工具代		14,200
  11	5月20日	会費	会費(2人分)	800
  12			合計	43,600	39,000
  13
  14	月　日	月　日	項目名	支出金額
  15				8,000
  16
  17

【解答例】

• 検索条件1：｢月　日」が「4/1以上」かつ(And)「5/1」より小さく　かつ(And)｢項目名｣が「図書費」　
• 検索条件2：「月　日」が「4/1以上」かつ(And)「5/1」より小さく　かつ(And)｢項目名」が「諸費」である
• 検索条件1と2はOR条件になります。よって、異なる行に条件を入力します。
  同一行はAND条件（かつ）、同一列はOR条件（または）での検索になります。

• 	B	C	D	E	F
  2	月　日	項目名	適用	収入金額	支出金額
  3	4月15日	繰越金	3月分繰越金	10,000
  4	4月19日	会費	会費(19人分)	7,600
  5	4月20日	図書費	新聞代		3,000
  6	4月25日	会費	会費(63人分)	25,200
  7	4月26日	図書費	新聞代		5,000
  8	5月10日	諸費	コピー代		4,800
  9	5月12日	図書費	本代		12,000
  10	5月18日	諸費	工具代		14,200
  11	5月20日	会費	会費(2人分)	800
  12			合計	43,600	39,000
  13
  14	月　日	月　日	項目名	支出金額
  15	>=4/1	<5/1	図書費	=DSUM(B2:G11,"支出金額",B14:D16)
  16	>=4/1	<5/1	諸費
  17

• その他のデータベース関数についてはこちらから

AND,OR,NOTで含まれる範囲について

• 検索条件は同一行内の条件がAND　行と行はOR　の条件となります。
• AND　：　A　AND　B　の場合　AかつB　　（AとBの重なった部分）
• OR　　：　A　OR　B　の場合　　AまたはB　（AとBのどちらかに含まれる部分)
• (集合の考え方と同じです)
  

範囲に名前をつける　　　　topへ

• 範囲に名前を付けると数式の意味がわかりやすくなります。

【設定例】

• 下のような表で「図書費」を計算する式は
  =SUMIF(C3:C11,"図書費",B3:F11)　となります。
• C3:C11に「項目名」、F3:F11に「支出金額」とセル範囲に名前を定義すれば、
  =SUMIF(項目名,"図書費",支出金額)　とすることができます。
  • 「もし範囲「項目名」の値が「図書費」であったら範囲「支出金額」の値を合計しなさい。」と、セル範囲を追わないでも、数式を理解しやすくなります。
  • (注) 定義した名前は「"」でくくりません。検索条件の「図書費」は文字列の値なので「"」でくくります。
  
  

名前の定義(A)：名前ボックスを利用する方法

1. 範囲を選択します。
2. [名前ボックス]をクリックして、名前を入力します。
3. 【Enter】キーを押します。
   

名前の定義(B)：メニューから設定する方法

1. 範囲を選択します。
2. メニューバーの[挿入]→[名前]→[定義]を選択します。
   

複数の範囲に一度に名前を付ける(名前の作成)　　　topへ

1. 名前を付けるセル範囲を上端行の「項目名」を含めて選択します。
   • 「C2:C11」を選択し、【Ctrl】キーを押しながら「F2:F11」を選択します。
2. メニューバーの【挿入】→【名前】→【作成】を選択します。
3. 上端行にチェックを付けて、「OK」をクリックします。
   • 「C3:C11」に「項目名」
   • 「F3:F11」に「動物」　と名前が定義されます。
     
   

数式に名前を付ける　　　　topへ

• セル範囲と同じように、数式にも名前を付けることができます。

1. メニューバーの【挿入】→【名前】→【定義】を選択します。
2. 名前に「項目費計算」、参照範囲に「=SUMIF(項目名,"図書費",支出金額)」とそれぞれ定義した名前を入力します。
   • =SUMIF($C$3:$C$11,"図書費",$B$3:$F$11)とセル範囲でもOKです。
   
3. E15セルの計算式は定義した名前を使って「=項目費計算」とすれば、計算できます。
   

名前を付けた範囲の修正方法

• セル範囲などに名前を付けた後に、範囲を修正したい時は
  メニューバーの〔挿入〕→〔名前〕→〔定義〕を選択します。
• 修正したい名前を選択し、参照範囲を修正します。
  

オートSUM ボタンのいろんな使い方　　　　topへ

• 合計はよく使う関数なので、ツールバーにオートSUMボタンが準備してあります。
• 以下の方法は「合計｣の時に使えます。

［A-1］一度に縦横の合計を出す　　　topへ

1. 合計するセルから合計を表示するセルまでを含めて選択します。
   • B3:E6セルを選択します。
2. 【オートSUM】ボタンをクリックします。
   
   
3. E3:E9とB9:D9セルに合計が表示されました。
   

［A-2］一度に縦横の合計を出す　　　　　topへ

1. 合計を表示するセルを選択します。
   • E3:E9を選択し、【Ctrl】キーを押しながらB9:D9を選択します。
2. 【オートSUM】ボタンをクリックします。
   
3. 選択したセル範囲に合計が表示されました。
   • B9セルは『=SUM(B3:B8)』となっています。
   

PageViewCounter

Since2006/2/27