1. Home » 
2. エクセル関数の技 » 
3. 関数を使って連番を入力する

関数を使って連番を入力する:Excel関数の技

• 関数を使って連番を入力する例です。
  オートフィルやフィルの機能を使って連番を入力することもできますが、それらについては下記のページをご覧ください。
  • Excel2010(エクセル2010)基本講座：オートフィル
  • Excel2010(エクセル2010)基本講座：連続データの作成

更新:2023/3/31;作成:2014/6/8

連番を作成する例　　topへ

行方向に連番を作成します。

SEQUENCE関数を使って行方向に連番を作成する
[Excel for Microsoft365、Excel2021]

• Excel for Microsoft365、Excel2021ではSEQUENCE関数が使えるようになりました。
  A1セルに　=SEQUENCE(18)　と入力するだけで、1〜18の連番を作成できます。
  SEQUENCE関数の詳細な使い方は SEQUENCE関数で連続した数値の配列を作成する をご覧ください。
  

ROW関数を使って行方向に連番を作成する
[Excel全バージョンで利用可]

1. A1セルに =ROW() と入力して、下方向へ数式をコピーします。
   
2. 途中の行から1,2,3と入力するには？
   1となる行の行番号が1となるように引き算をする方法が考えられます。
   
3. 行番号が1となるセル、例えば　A1セルからの行番号を計算することが考えられます。
   1としたいセルに　=ROW(A1) と入力して、下方向へコピーします。（細かいことですが、 A1でなくても　B1やC1などでも構いません。）
   

列方向に連番を作成します。

SEQUENCE関数を使って列方向に連番を作成する
[Excel for Microsoft365、Excel2021]

• A1セルに　=SEQUENCE(,18)　と入力するだけで、列方向へ 1〜18の連番を作成できます。
  SEQUENCE関数の構文は　=SEQUENCE(行,[列],[開始],[目盛り]) となっています。
  

COLUMN関数を使って列方向に連番を作成する
[Excel全バージョンで利用可]

• A1セルに =COLUMN()　と入力して、右方向へ数式をコピーします。
  
• 途中のセルから、1,2,3としたいときは行方向のケースと同じです。
  下図は C列から始めた例です。C4セルに =COLUMN(A1) と入力して、右方向へコピーしています。
  

飛び飛びのセルに連番を入力する　　topへ

SEQUENCE関数を使って飛び飛びのセルに連番を作成する
[Excel for Microsoft365、Excel2021]

• A1セルに　=SEQUENCE(12,,1,0.5) と入力するだけで、1から0.5刻みの連番を12個作成できます。
  SEQUENCE関数の構文は　=SEQUENCE(行,[列],[開始],[目盛り]) となっています。
  
• MOD関数を使って、余りが0でなかったら表示せず、余りが0であったら表示する(整数値のみを表示します)。
  =IF(MOD(SEQUENCE(12,,1,0.5),1)<>0,"",SEQUENCE(12,,1,0.5))
  

ROW関数を使って飛び飛びのセルに連番を作成する
[Excel全バージョンで利用可]

• 飛び飛びのセルに連番を入力するには、入力するセルの行番号を何らかの計算して1,2,3・・・とすればよいことになります。
• 1行おきに連番を入力するには、1,3,5・・・を1,2,3・・・となるように計算できればよいことになります。

1. ROW(A1)に　+1　した値を　/2 (2で割る)ことで、1行ごとに　1,2,3・・・とすることができます。
   
2. 途中の0.5　となるところを空白にします。
   0.5ということは割り切れない数値として区別できます。つまり、MOD((ROW(A1)+1),2)=0　余りが0であるかそうでないかで区別します。
   =IF(MOD((ROW(A1)+1),2)=0,(ROW(A1)+1)/2,"")
   
3. 2行おきや3行おきの場合は、下図のようになります。
   • 2行おきの場合　=IF(MOD((ROW(A1)+2),3)=0,(ROW(A1)+2)/3,"")
   • 3行おきの場合　=IF(MOD((ROW(A1)+3),4)=0,(ROW(A1)+3)/4,"")
   

複数セル単位で連番を入力する　　topへ

• 2個ずつの連番や、3個ずつの連番を作成したい場合も上記と同じように考えることができます。
  小数部分があるものは上の整数値に丸めればよいことになります。
• 2個ずつ連番を振る
  =FLOOR((ROW(A1)+1)/2,1)　としました。
  
• 3個ずつ連番を振る
  =FLOOR((ROW(A1)+2)/3,1)　としました。
  
• 4個ずつ連番を振る
  =FLOOR((ROW(A1)+3)/4,1)　としました。
  

スポンサードリンク

　PageViewCounter
　
　Since2006/2/27