1. Home » 
2. エクセル練習問題：目次 » 
3. 条件付きの平均の計算

条件付きの平均の計算：エクセル練習問題

更新:2025/9/22;作成:2011/7/14

問題1の解答例　　　　topへ

• 解答
  

  	B	C	D	E	F
  2	名前	性別	得点		平均
  3	相沢一郎	男	52		67.3
  4	井上浩二	男	74
  5	上野有紀	女	84
  6	内野武	男	77
  7	上田祥子	女	68
  8	江田早苗	女	59
  9	榎本高貴	男	77
  10	小田和樹	男	47

• 数式の例：平均はAVERAGE関数で求めることができます。
  • 構文：=AVERAGE(数値1,[数値2], ・・・)
    AVERAGE関数 に説明がありますので参照してください。
  F3セルには　=AVERAGE(D3:D10)　と入力します。
  

  	B	C	D	E	F
  2	名前	性別	得点		平均
  3	相沢一郎	男	52		=AVERAGE(D3:D10)
  4	井上浩二	男	74
  5	上野有紀	女	84
  6	内野武	男	77
  7	上田祥子	女	68
  8	江田早苗	女	59
  9	榎本高貴	男	88
  10	小田和樹	男	62

  • 小数点以下一桁での表示にするには、[ホーム]タブの[小数点以下の表示桁数を増やす]をクリックします。
    桁数が多い場合は[小数点以下の表示桁数を減らす]をクリックして調整します。
    
• 関数の引数ダイアログボックスを使う場合は、数値1に　D3:D10　と入力します。
  

問題2の解答例　　　　topへ

• 男の平均を求めなさい。結果は小数点以下1桁まで表示しなさい。
  解答
  

  	B	C	D	E	F
  2	名前	性別	得点		男の平均
  3	相沢一郎	男	52		65.4
  4	井上浩二	男	74
  5	上野有紀	女	84
  6	内野武	男	77
  7	上田祥子	女	68
  8	江田早苗	女	59
  9	榎本高貴	男	77
  10	小田和樹	男	47

AVERAGEIF関数で求める

• 数式の例：一つの条件での平均はAVERAGEIF関数で求めることができます。（Excel2007以降で使用できます。）
  • 構文：=AVERAGEIF(範囲,条件,[平均範囲])
  • AVERAGEIF関数 に説明がありますので参照してください。
  F3セルに　=AVERAGEIF(C3:C10,"男",D3:D10)　と入力します。
  
  • 小数点以下一桁での表示にするには、[ホーム]タブの[小数点以下の表示桁数を増やす]をクリックします。
    桁数が多い場合は[小数点以下の表示桁数を減らす]をクリックして調整します。
    
  AVERAGEIF関数の引数ダイアログボックスで、範囲に C3:C10　、条件に　"男"　、平均対象範囲に　D3:D10　と入力します。
  

FILTER関数を使って求める

• Excel for Microsoft 365、Excel2021以降ではFILTER関数が使えます。
• F3セルに　=AVERAGE(FILTER(D3:D10,C3:C10="男"))　と入力します。
  

SUMIF関数とCOUNTIF関数で求める

• Excel2003以前ではAVERAGEIF関数が使えませんが、SUMIF関数とCOUNTIF関数で求めることができます。
  男の平均=(男の合計)/(男の個数)　ですので、
  F3セルに　=SUMIF(C3:C10,"男",D3:D10)/COUNTIF(C3:C10,"男")　と入力します。
  とすることができます。
  • 構文：=SUMIF(範囲,検索条件,[合計範囲])
    構文：=COUNTIF(範囲,検索条件)
  • SUMIF関数　COUNTIF関数 に説明がありますので参照してください。
  

• 8月の平均を求めなさい。
  

  解答
  

  	B	C	D	E
  2	試験日	得点		8月の平均
  3	2025/7/1	66		77.5
  4	2025/7/2	71
  5	2025/8/4	78
  6	2025/8/5	69
  7	2025/8/6	84
  8	2025/8/7	79
  9	2025/9/1	72
  10	2025/9/2	68

AVERAGEIFS関数で求める

• 数式の例：複数条件の平均はAVERAGEIFS関数で求めることができます。（Excel2007以降で使用できます）
  • 構文：=AVERAGEIFS(平均範囲,条件範囲1,条件1,[条件範囲2,条件2], ・・・)
    AVERAGEIFS関数 に説明がありますので参照してください。
  E3セルに　=AVERAGEIFS(C3:C10,B3:B10,">=2025/8/1",B3:B10,"<2025/9/1")　と入力します。
  
  
  AVERAGEIFS関数の引数ダイアログボックスでは、平均対象範囲に C3:C10　、条件範囲1に B3:B10 、条件1に ">=2025/8/1"　、条件範囲2に B3:B10　、条件2に "2025/9/1" と入力します。
  

FILTER関数を使って求める

• Excel for Microsoft 365、Excel2021以降ではFILTER関数が使えます。
  FILTER関数については　FILTER関数でデータを抽出する　をご覧ください。
• F3セルに　=AVERAGE(FILTER(C3:C10,TEXT(B3:B10,"yyyy年m月")="2025年8月"))
  

配列関数を使って求める

• Excel for Microsoft 365，Excel2021以降のバージョンでは動的配列数式が使えます。
  E3セルに　=AVERAGE(IF(MONTH(B3:B10)=8,C3:C10))　と入力します。
  
  Excel2019以前のバージョンでは[Ctrl]+[Shift]+[Enter]で
  {=AVERAGE(IF(MONTH(B3:B10)=8,C3:C10))}　の形式で入力する必要があります。
  

SUMIF関数とCOUNTIF関数で求める

• 8月の合計/8月の数　で求めることができます。
  • 構文：=SUMIF(範囲,検索条件,[合計範囲])
    構文：=COUNTIF(範囲,検索条件)
    SUMIF関数　COUNTIF関数 に説明がありますので参照してください。
  • 2011年8月の合計は、SUMIF関数で　2025/8/1以上の合計から　2025/9/1以上の合計を差し引くことで求めることができます。
    個数も同様の考え方でCOUNTIF関数で求めることができます。
  • =(SUMIF(B3:B10,">=2025/8/1",C3:C10)-SUMIF(B3:B10,">=2025/9/1",C3:C10))
    /(COUNTIF(B3:B10,">=2025/8/1")-COUNTIF(B3:B10,">=2025/9/1"))
  

SUMPRODUCT関数を使って求める

• SUMPRODUCT関数を使って求めることもできます。
  「2025/8」が一致する行の得点を合計を、個数で割って求めることもできます。
  • 構文：=SUMPRODUCT(配列1,[配列2],[配列3],・・・)
    SUMPRODUCT関数 に説明がありますので参照してください。
  • 構文：=TEXT(値,表示形式)
    TEXT関数　に説明がありますので参照してください。
  • =SUMPRODUCT((TEXT(B3:B10,"yyyy/m")="2025/8")*C3:C10)
    /SUMPRODUCT((TEXT(B3:B10,"yyyy/m")="2025/8")*1)
  

DAVERAGE関数で求める

• 条件をシートに書き出すと、DAVERAGE関数で求めることができます。
  F2,G2にフィールド名を書き、F3,G3に条件を書きます。
  • 構文：=DAVERAGE(データベース,フィールド,検索条件)
    DAVERAGE関数 に説明がありますので参照してください。
  E3セルに　=DAVERAGE(B2:C10,2,F2:G3)　と入力します。
  

スポンサードリンク

PageViewCounter

Since2006/2/27