1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. 指定された行・列の配列を返すCHOOSEROWS関数・CHOOSECOLS関数の使い方

指定された行・列の配列を返すCHOOSEROWS関数・CHOOSECOLS関数の使い方:Excel関数

更新:2024/12/17;作成:2022/9/5

• CHOOSEROWS関数・CHOOSECOLS関数がExcel for Microsoft 365 で使用することができるようになりました。(2022/9/2に確認しました)
  Excel2024（2024/10/2から市販されました)でも使用できるようになりました。

指定された列の配列を返す
　チューズ　コール(カラムズ)
=CHOOSECOLS(array,col_num1,[col_num2],...)

CHOOSECOLS関数の引数

• CHOOSECOLS関数の引数(現時点では英語表記になっています。)
  

  引数		意味
  array	必須	セル範囲や配列
  col_num1	必須	返される最初の列番号。
  col_num2	省略可	返される追加の列番号

CHOOSECOLS関数の使用例

• データリストから必要な列だけを取り出したり、列を並べ替えたりすることができます。
  いろいろな関数と組み合わせて使用することが多い関数です。

• B1:E5セルに入力されている配列の列が1番目と2番目のデータを抽出します。
  B8セルには　=CHOOSECOLS(B1:E5,1,2)　と入力しています。
  =CHOOSECOLS(B1:E5,{1,2})とすることもできます。
  
• 列を入れ替えることもできます。
  ２列目と1列目とを入れ替えて表示します。
  =CHOOSECOLS(B1:E5,2,1)
  =CHOOSECOLS(B1:D5,{2,1})
  

CHOOSECOLS関数の引数の列数を負の値で指定する

• 指定する行番号を負の値で指定すると、後ろから列を指定することができます。
  =CHOOSECOLS(B1:E5,-4,-1)　と、-4,-1として最終行から4番目と1番目の列を指定しています。
  =CHOOSECOLS(B1:E5,{-4,-1}) とすることもできます。
  

CHOOSECOLS関数の引数の列数をSEQUENCE関数で指定する

• B1:E5セルに入力されている配列の列が1番目と2番目のデータを抽出します。
  B8セルには　=CHOOSECOLS(B1:E5,SEQUENCE(2,,1,2))　と入力しています。
• SEQUENCE(2,,1,2) で　={1;3}　を返します。
  =SEQUENCE(行,[列],[開始],[目盛り])なので、2行1列に１から増分２の配列を入れるので、{1,3}　を返します。
  
• 

取り出す列をXMATCH関数で指定する

• 「商品」と「発注数」の離れたデータを取り出したいときは？
  B7:C7セルに「商品」と「発注数」と入力してある場合は
  XMATCH関数を使って　XMATCH(B7:C7,B1:E1)　として、1,3 を返すので、
  =CHOOSECOLS(B2:E5,XMATCH(B7:C7,B1:E1))　とすることができます。
  XMATCH関数の使い方は　XMATCH関数の使い方　をご覧ください。
  

XLOOKUP関数で返される範囲のデータの一部を切り出す

• XLOOKUP関数で返される範囲のデータの一部を切り出すこともできます。
  商品名「みかん」の産地〜発注数の連続したデータを取り出す場合は　XLOOKUP(B8,B2:B5,C2:E5)　でOKです。
  産地と発注数と不連続のデータは　=CHOOSECOLS(XLOOKUP(B12,B2:B5,C2:E5),XMATCH(C11:D11,C1:E1))　とすることができます。
  XLOOKUP関数の使い方は　XLOOKUP関数で範囲や配列を検索する　をご覧ください。
  

配列やセル範囲をテーブルにすると・・・

• セル範囲B1:D5セルをテーブルに変換しました。
  テーブル名は　果物　としました。
  テーブルの列が1番目と3番目のデータを抽出します。
  B8セルには　=CHOOSECOLS(果物,1,3)　と入力しています。
  

指定された行の配列を返す
　チューズ　ロウズ
=CHOOSEROWS(array,row_num1,[row_num2],...)

CHOOSEROWS関数の引数

• CHOOSEROWS関数の引数(現時点では英語表記になっています。)
  

  引数		意味
  array	必須	セル範囲や配列
  row_num1	必須	返される最初の行番号
  row_num2	省略可	返される追加の行番号

CHOOSEROWS関数の使用例

• B2:D5セルに入力されている配列の行が2番目と3番目のデータを抽出します。
  B8セルには　=CHOOSEROWS(B2:D5,2,3)　と入力しています。
  =CHOOSEROWS(B2:D5,{2,3})　とすることもできます。
  

CHOOSEROWS関数の引数の行数を負の値で指定する

• 指定する行番号を負の値で指定すると、後ろの行や列を指定することができます。
  =CHOOSEROWS(B2:D5,-1,-3)　と、-1,-3として最終行から1番目と3番目の行を指定しています。
  

CHOOSEROWS関数の引数の行数を関数で指定する

• 指定する行番号をSEQUENCE関数で指定することができます。
  構文は=SEQUENCE(行,列,開始,目盛り)ですので　2,3を指定するにはSEQUENCE(1,2,2,1)となります。
  =CHOOSEROWS(B2:D5,SEQUENCE(1,2,2,1))
• SEQUENCE(1,2,2,1)　は　{2,3}が返されます。
  
• 
• 商品名の「みかん」と「パイン」で検索したい時は
  XMATCH({"みかん","パイン"},B2:B5)　として {2;4} を返すことができます。
  =CHOOSEROWS(B2:D5,XMATCH({"みかん","パイン"},B2:B5))　とします。
• XMATCH関数の使い方は　XMATCH関数の使い方　をご覧ください。
  
• 商品名の「みかん」と「パイン」がセルに入力されているときは？
  XMATCH(B7:B8,B2:B5) で　{2;4} を返すので、
  =CHOOSEROWS(B2:D5,XMATCH(B7:B8,B2:B5))　とします。
  

配列やセル範囲をテーブルにすると・・・

• セル範囲B1:D5セルをテーブルに変換しました。
  テーブル名は　果物　としました。
  テーブルの行が1番目と3番目のデータを抽出します。
  B8セルには　=CHOOSEROWS(果物,1,3)　と入力しています。
  

スポンサードリンク

PageViewCounter

Since2006/2/27