LOOKUP関数の使い方:Excel関数

スポンサードリンク

2023/2/1

　ルックアップ
=LOOKUP(検査値,検査範囲,対応範囲)　　[ベクトル形式]
　　　対応範囲：1行/1列のみのセル範囲を指定。検査範囲と同じサイズであること。
　　(注)検査範囲の値は昇順に並べておく必要があります。英字の大文字と小文字は区別されません。
　　　　また、日本語文字を並べ替える場合「ふりがなを使用しない」で並べ替えます。
=LOOKUP(検査値,配列)　[配列形式]

なお、MicrosoftのヘルプではLOOKUP関数よりもVLOOKUP関数やXLOOKUP関数の使用を勧めています。

【問題】成績の評価を付けたいと思います。右の評価一覧表（G4:J6)にしたがって、D4:E6セルに数式を入力しなさい。

	B	C	D	E	F	G	H
2						評価一覧表
3	名前	得点	評価A		得点		評価A
4	今田	50	△		0	～	×
5	河野	20	×		40	～	△
6	山田	70	○		70	～	○

【解答例】
- LOOKUP関数の場合、得点欄(F列)の値以上の意味になります。得点欄(F列)は昇順に並んでいることが必要です。
  D4セルに　=LOOKUP(C4,$F$4:$F$6,$H$4:$H$6)　と入力して、下方向へ数式をコピーします。
  関数の挿入を使う場合は　関数の挿入ボタンを使って数式を作成する操作手順　をご覧ください。
【別解】配列形式を使うと、D4セルは以下のように書くこともできます。
- =LOOKUP(C4,$F$4:$H$6)
  (範囲の右端の列の値を返す。)
- =LOOKUP(C4,{0,"×";40,"△";70,"○"})
  =LOOKUP(C4,{0,40,70;"×","△","○"})
SPILL(スピル)機能を使う場合
- Excel2021、Excel for Microsoft365ではSpill(スピル)機能が利用できます。
  D4セルに　=LOOKUP(C4:C6,F4:F6,H4:H6)　と入力します。
  D4セルにだけ数式を入力するので、引数は相対参照でOKです。
- (参考)　LOOKUP関数のその他の用途（文字列から数値を取り出す方法など)
VLOOKUP関数を使う場合
- D4セルに =VLOOKUP($C4,$F$4:$H$6,3,TRUE) と入力して、下方向へ(D5:D6セルに)数式をコピーします。
  VLOOKUP関数の詳細な使い方は VLOOKUP関数の使い方(表からデータを検索する):Excel関数をご覧ください。
XLOOKUP関数を使う場合
- Microsoft365ではXLOOKUP関数が使用できるようになりました。
  D4セルに　=XLOOKUP(C4:C6,F4:F6,H4:H6,"",-1)　と入力します。
  引数の一致モードで -1 とするのがポイントです。
  一致モード -1 は「完全一致。見つからない場合は、次の小さなアイテムが返されます。」
  - XLOOKUP関数の詳細な使い方は　XLOOKUP関数で範囲や配列を検索する:Excel関数をご覧ください。

【問題2】下表のB3セルにコードを入力すると、C3:D3セルにF～H列の表から商品名と単価を検索して表示するように数式を入力しなさい。

	B	C	D	E	F	G	H
2	コード	商品名	単価		コード	商品名	単価
3	130	ぶどう	300		100	りんご	100
4					110	みかん	120
5					120	梨	200
6					130	ぶどう	300
7					140	柿	250
8					150	パイナップル	400

【解答例2A】ベクトル形式
- この問題では、D3セルの数式は　C3セルの値(商品名)を検査値にして単価を検索することも考えられます。
  しかし、商品名は昇順に並んでいないので、この商品名を検索値にしたLOOKUP関数は使えません。
  よって、検査値には昇順に並んでいるコードを使用することになります。
- C3セルには　=LOOKUP($B$3,$F$3:$F$8,G3:G8)　と入力します。
  =LOOKUP(検査値,検査範囲,対応範囲)　の検査値は　B3　、検査範囲は F3:F8 、対応範囲は G3:G8　となります。
  C3セルの数式を D3セルにコピーします。
  そのために、検査値は　$B$3　、検査範囲は $F$3:$F$8 は絶対参照とし、対応範囲の G3:G8 は相対参照にしています。
  D3セルの数式は　=LOOKUP($B$3,$F$3:$F$8,H3:H8)　となります。
【解答例2B】配列形式
- C3セルには　=LOOKUP($B$3,$F$3:G8)　と入力します。
  =LOOKUP(検査値,配列)　の検査値は　B3　、配列は F3:G8 となります。
  右のセル D3セルにコピーするために検査値は　$B$3　、配列は　$F$3:G8　と絶対参照にしています。
  D3セルの数式は　=LOOKUP($B$3,$F$3:H8)　となります。
VLOOKUP関数を使う場合
- C3セルに　=VLOOKUP($B3,$F$3:$H$8,COLUMN(B1))　と入力して、右方向へ（D3セルに) 数式をコピーします。
XLOOKUP関数を使う場合
- Microsoft365ではXLOOKUP関数が使用できるようになりました。
  C3セルに　=XLOOKUP(B3,F3:F8,G3:H8)　と入力します。