よねさんのWordとExcelの小部屋｜Excel(エクセル)基本講座の総目次｜Excel(エクセル)関数一覧表｜最大/最小の関数

Excel(エクセル)基本講座：最大/最小の関数

最大値(MAX関数)、最小値(MIN関数)、大きい方からの順位の値(LARGE関数)、小さい方からの順位の値(SMALL関数)を求めるExcel関数の使い方を説明しています。
RANK関数は順位の関数へ移動しました。

最大値(MAX関数)	最小値(MIN関数)
大きい順(LARGE関数)	小さい順(SMALL関数)

範囲内の最大値を求めます　　　 topへ
　マックス
=MAX(範囲)

範囲内の最小値を求めます　　　
　ミン
=MIN(範囲)

最大値と最小値を求める(問題1)
上限や下限がある場合に使う方法(問題2～3)

【問題1】

各教科の最高点と最低点をC10:F11に求めなさい。
なお、C9:F9に平均点、F3:F8に合計も計算してみましょう。

	B	C	D	E	F
2	名前	国語	数学	英語	合計
3	井上	80	85	88	253
4	会田	70	65	58	193
5	上野	90	88	76	254
6	岡田	55	62	47	164
7	釜元	77	64	71	212
8	木下	64	75	69	208
9	平均点	72.7	73.2	68.2	214
10	最高点	90	88	88	254
11	最低点	55	62	47	164

【解答例】

最高点はMAX関数、最低点はMIN関数を使って求めます。
なお、平均はAVERAGE関数、合計はSUM関数を使います。

	B	C	D	E	F
2	名前	国語	数学	英語	合計
3	井上	80	85	88	=SUM(C3:E3)
4	会田	70	65	58	=SUM(C4:E4)
5	上野	90	88	76	=SUM(C5:E5)
6	岡田	55	62	47	=SUM(C6:E6)
7	釜元	77	64	71	=SUM(C7:E7)
8	木下	64	75	69	=SUM(C8:E8)
9	平均点	=AVERAGE(C3:C8)	=AVERAGE(D3:D8)	=AVERAGE(E3:E8)	=AVERAGE(F3:F8)
10	最高点	=MAX（C3:C8)	=MAX（D3:D8)	=MAX（E3:E8)	=MAX（F3:F8)
11	最低点	=MIN(C3:C8)	=MIN(D3:D8)	=MIN(E3:E8)	=MIN(F3:F8)

【問題2】

通勤距離が片道4Kmを超える場合、ガソリン代1Km当たり200円20日分支給されます。
ただし、一月の支給額は30,000円を上限とします。
各通勤距離のガソリン支給額を求めなさい。

B C

2 通勤距離(片道km) 支給額(円/月)

3 3 0

4 4 0

5 5 8,000

6 6 16,000

7 7 24,000

8 8 30,000

9 9 30,000

【解答2例】

ガソリン代が支給される通勤距離は4㎞を超えない場合は0とします。
MAX(0,B3-4)　とし、往復分の「2」、1Km当たりの「200」、支給日数の「20」をかけて、
MAX(0,B3-4)*2*20*200　とします。

支給金額の上限は「30,000」であるので、
=MIN(30000,MAX(0,B3-4)*2*20*200)　とします。

	B	C
2	通勤距離(片道km)	支給額(円/月)
3	3	=MIN(30000,MAX(0,B3-4)220*200)
4	4	=MIN(30000,MAX(0,B4-4)220*200)
5	5	=MIN(30000,MAX(0,B5-4)220*200)
6	6	=MIN(30000,MAX(0,B6-4)220*200)
7	7	=MIN(30000,MAX(0,B7-4)220*200)
8	8	=MIN(30000,MAX(0,B8-4)220*200)
9	9	=MIN(30000,MAX(0,B9-4)220*200)

【問題3】

勤務時間が9:00～17:00である時、出勤時刻と退勤時刻からこの時間帯に出社していた時間を求めなさい。
ただし、エラー処理や小数誤差の対策は考慮しないものとします。

　 B C D

2 出社時刻退社時刻勤務時間

3 8:25 15:30 6:30

4 10:15 16:20 6:05

5 10:35 18:00 6:25

【解答3例】

計算の起点は、出勤時刻と"9:00"の大きい方を取り出せばいいので、MAX(B3,"9:00")
計算の終点は、退勤時刻と"17:00"の小さい方を取り出せばいいので、MIN(C3,"17:00")

よって数式は　=MIN(C3,"17:00")-MAX(B3,"9:00")　となります。

	B	C	D
2	出社時刻	退社時刻	勤務時間
3	8:25	15:30	=MIN(C3,"17:00")-MAX(B3,"9:00")
4	10:15	16:20	=MIN(C4,"17:00")-MAX(B4,"9:00")
5	10:35	18:00	=MIN(C5,"17:00")-MAX(B5,"9:00")

大きいほうからの順位の数値を求める　　　 topへ
　ラージ
=LARGE(範囲,順位)

小さいほうからの順位の数値を求める
　スモール
=SMALL(範囲,順位)

【問題1-1】

合計得点の大きい方から第一位、第二位　および　最下位、ブービー(下から二番目)の得点とその名前を求めなさい。

	B	C	D	E	F	G	H	I
2	名前	国語	数学	英語	合計		得点	名前
3	井上	80	85	88	253	一位	254	上野
4	会田	70	65	58	193	二位	253	井上
5	上野	90	88	76	254
6	岡田	55	62	47	164	最下位	164	岡田
7	釜元	77	64	71	212	ブービー	193	会田
8	木下	64	75	69	208

【解答例1-1】

一位、二位は大きい方からの順位ですので、LARGE関数を使います。
最下位、ブービーは小さい方からの順位なので、SMALL関数を使います。
名前は　INDEX関数とMATCH関数を組み合わせて検索してみました。

	B	C	D	E	F	G	H	I
2	名前	国語	数学	英語	合計		得点	名前
3	井上	80	85	88	253	一位	=LARGE(F3:F8,1)	=INDEX($B$3:$B$8,MATCH(H3,$F$3:$F$8,0))
4	会田	70	65	58	193	二位	=LARGE(F3:F8,2)	=INDEX($B$3:$B$8,MATCH(H4,$F$3:$F$8,0))
5	上野	90	88	76	254
6	岡田	55	62	47	164	最下位	=SMALL(F3:F8,1)	=INDEX($B$3:$B$8,MATCH(H6,$F$3:$F$8,0))
7	釜元	77	64	71	212	ブービー	=SMALL(F3:F8,2)	=INDEX($B$3:$B$8,MATCH(H7,$F$3:$F$8,0))
8	木下	64	75	69	208

【問題1-2】

各教科の0点を除いた最低点をC9:D9に求めなさい。

	B	C	D
2	名前	テスト1	テスト2
3	井上	80	0
4	会田	70	65
5	上野	0	88
6	岡田	55	0
7	釜元	0	0
8	木下	64	75
9	最低点	55	65

0点の次に小さい値を求めればよいので、0点の数を求め、その次に小さい値をSMALL関数で求めます。
C9セルは=SMALL(C3:C8,COUNTIF(C3:C8,0)+1)　となります。

	B	C	D
2	名前	テスト1	テスト2
3	井上	80	0
4	会田	70	65
5	上野	0	88
6	岡田	55	0
7	釜元	0	0
8	木下	64	75
9	最低点	=SMALL(C3:C8,COUNTIF(C3:C8,0)+1)	=SMALL(D3:D8,COUNTIF(D3:D8,0)+1)

よねさんのWordとExcelの小部屋｜Excel(エクセル)基本講座の総目次｜Excel(エクセル)関数一覧表｜最大/最小の関数

PageViewCounter
Counter
Since2006/2/27