Excel(エクセル)基本講座：四捨五入の関数

• エクセルでの数値の丸め処理に関する様々な関数について説明しています。
  • 四捨五入：ROUND関数,MROUND関数
  • 切り上げ：ROUNDUP関数,CEILING関数,EVEN関数,ODD関数
  • 切り捨て：ROUNDDOWN関数,FLOOR関数,INT関数,TRUNC関数
  • その他：MOD関数

四捨五入(ROUND)	切り上げ(ROUNDUP)	切捨て(ROUNDDOWN)
倍数に四捨五入(MROUND)	倍数に切り上げ(CEILING)	倍数に切り下げ(FLOOR)
剰余を求める(MOD)	偶数に切り上げ(EVEN)	その数値を超えない最大の整数(INT)
	奇数に切り上げ(ODD)	小数部を切り捨てる(TRUNC)

指定した桁数で四捨五入する　　topへ
　ラウンド
=ROUND(数値,桁数)
　　　桁数：四捨五入後の桁数を指定します。
　　　　　　小数点の位置が０となり、左側へ−１(１の桁），−２(１０の桁），−３(１００の桁)・・・
　　　　　　　　　　　　　　　　　　右側へ　 １(小数第１位)，２(小数第２位)・・・

【問題】各教科の平均点を、四捨五入後、整数と小数第1位の桁で表示しなさい。

• 	B	C	D
  2	氏名	国語	数学
  3	今田浩次	80	85
  4	内田あかり	70	65
  5	江藤公正	90	88
  6	岡田太郎	55	62
  7	川口宏	77	64
  8	木村次郎	64	75
  9	平均点(整数)	73	73
  10	平均点(小数第1位)	72.7	73.2

【解答例】

• 平均はAVERAGE関数を使います。
• 平均点のC9セルは　=AVERAGE(C3:C8)　となります。
• 四捨五入のC10セルはROUND関数と組み合わせて、
  =ROUND(AVERAGE(C3:C8),0)となります。(整数でまとめるので桁数は0です）

• 	B	C	D
  2	氏名	国語	数学
  3	今田浩次	80	85
  4	内田あかり	70	65
  5	江藤公正	90	88
  6	岡田太郎	55	62
  7	川口宏	77	64
  8	木村次郎	64	75
  9	平均点(整数)	=ROUND(AVERAGE(C3:C8),0)	=ROUND(AVERAGE(D3:D8),0)
  10	平均点(小数第1位)	=ROUND(AVERAGE(C3:C8),1)	=ROUND(AVERAGE(D3:D8),1)

【操作例】関数の挿入ボタンを使う方法

1. C9セルをクリックしてアクティブにします。
2. 【関数の挿入】ボタンをクリックし、『ROUND』を選択します。
3. 表示される【関数の引数】ダイアログで、
   • 【数値】の欄に、『AVERAGE(』とキーボードから入力します。前かっこ『（』まで入力します。
     シートのC3:C8セルをドラッグして選択すると、『AVERAGE(C3:C8』と表示されるので、
     後ろかっこ『）』をキーボードから入力します。
   • 【桁数】の欄に、整数値で四捨五入するので、『0』と入力します。
4. 【OK】ボタンをクリックします。
   

数式の修正方法　　　　　topへ

• 『=ROUND(AVERAGE(C3:C8),0）』を【関数の引数】ダイアログを使って修正する場合には?

1. 数式バーで、関数名の部分をクリックしてカーソルを表示します。
   • (例)上記数式のROUND関数の場合
     • 数式バーのROUNDの所をクリックしてカーソルを表示しています。
       
2. 【関数の挿入（fx）】ボタンをクリックします。
   カーソルのある関数の【関数の引数】ダイアログが表示され、修正可能となります。
   • (例)上記数式のROUND関数の場合
     • 【fx】ボタンをクリックすると、ROUND関数の「関数の引数」ダイアログが開きました。
       

5捨6入の計算　　　　　topへ

• 「5」は切り捨てて「6」から切り上げる場合
  1. 該当桁数の値を「-1」して、四捨五入する(ROUND関数を使う)
  2. 該当桁数の値に「4」加えて、切り捨てする(ROUNDDOWN関数を使う)
  3. 該当桁数の値を「-5」して、切り上げする(ROUNDUP関数を使う)
  ことが考えられます。
  

ROUND関数の桁数(引数)について

• C4:G7の計算結果は表示桁数を小数点以下3桁にしています。
  

ROUND関数の丸め処理について

• ワークシート関数の場合は"算術型"丸め処理で「.5」は常に切り上げられます。
• VBA関数の場合は"銀行型"丸め処理で「.5」は結果が偶数になるように丸められます。
  つまり、切り上げたり切り捨てられたりするということです。
  また、整数部分での丸めを行うことはできません。
• [XL2000]VBA の Round とワークシート関数 Round の違い
  http://support.microsoft.com/kb/225330/JA/
• JIS Z8401『数値の丸め方』
  http://www.bsddiary.net/doc/jis-z8401.html

ある値を基準に四捨五入したい　　topへ

• 【例】50単位で四捨五入した。
  • 25以上は50に切り上げ、25未満は切り捨てとしたい場合の例
  • CEILING,FLOOR関数およびMROUND関数はこのページで説明していますので参照願います。
    

数値を四捨五入し、ピリオド(.小数点) とカンマ(,桁区切り) を使った文字列に変換します　　topへ
　フィックスド
=FIXED(数値,桁数,桁区切り)
　　桁数：四捨五入する桁数を指定します。省略すると2(小数第2位)を指定したと見なされます。
　　桁区切り：TRUE/FALSEを指定します。省略するとFALSEと同じになります。

【使用例】

• 文字列に変換されることに注意してください。
  

  	B	C	D	E	F
  2		TRUE	FALSE	TRUE	FALSE
  3	1234.56	=FIXED(B3,1,TRUE)	=FIXED(B3,1,FALSE)	1234.6	1,234.6
  4	-1234.56	=FIXED(B4,1,TRUE)	=FIXED(B4,1,FALSE)	-1234.6	-1,234.6
  5	1234.56	=FIXED(B5,-1,TRUE)	=FIXED(B5,-1,FALSE)	1230	1,230

指定した桁数で切り上げる　　　　topへ
　ラウンドアップ
=ROUNDUP(数値,桁数)
　　　桁数：切り上げ後の桁数を指定します。
　　　　　　小数点の位置が0となり、左側へ-1(1の桁），-2(10の桁），-3(100の桁)・・・
　　　　　　　　　　　　　　　　　　右側へ1(小数第1位)，2(小数第2位)・・・

【問題】　

• テレビとパソコンの販売価格を決めたいと思います。
• それぞれの販売価格は1000円単位に切り上げることにします。

• 	B	C	D	E
  2
  3	品名	標準価格	値引率(%)	販売価格
  4	テレビ	50,000	12	44,000
  5	パソコン	210,000	12	185,000

【解答例】

• 値引後の価格は　「標準価格*（100-値引率)/100」となります。
• 1000円単位に切り上げるには、ROUNDUP関数の桁数に「-3」を入れます。

• 	B	C	D	E
  2
  3	品名	標準価格	値引率(%)	販売価格
  4	テレビ	50,000	12	=ROUNDUP(C4*(100-D4)/100,-3)
  5	パソコン	210,000	12	=ROUNDUP(C5*(100-D5)/100,-3)

【操作例】関数の挿入ボタンを使う方法

1. E4セルをクリックしてアクティブにします。
2. 【関数の挿入】ボタンをクリックし、『ROUNDUP』を選択します。
3. 表示される【関数の引数】ダイアログで、
   • 【数値】の欄に、『C4*(100-D4)/100』とキーボードから入力します。
     セル番号の部分はシートの該当セルをクリックしても入力ができます。
   • 【桁数】の欄に、100円単位で切り上げするので、『-3』と入力します。
4. 【OK】ボタンをクリックします。
   

ROUNDUP関数の桁数(引数)について　　　　　topへ

• C4:G7の計算結果は表示桁数を小数点以下3桁にしています。
  

指定した桁数で切り捨てる　　topへ
　ラウンドダウン
=ROUNDDOWN(数値,桁数)
　　　桁数：切り捨て後の桁数を指定します。
　　　　　　小数点の位置が0となり、左側へ-1(1の桁），-2(10の桁），-3(100の桁)・・・
　　　　　　　　　　　　　　　　　　右側へ1(小数第1位)，2(小数第2位)・・・

【問題】テレビとパソコンを販売しました。それぞれの消費税（5％で1円未満は切り捨て）はいくらでしょうか?

• 	B	C	D	E
  2
  3	品名	販売価格	台数	消費税
  4	テレビ	43,888	1	2,194
  5	パソコン	185,888	1	9,294

【解答例】

• 消費税は「販売価格*台数*0.05」となります。
  または、「販売価格*台数*5%」　でもOKです。
• 1円未満は切り捨てますので、ROUNDDOWN関数を使い、桁数は「0」を入力します。

• 	B	C	D	E
  2
  3	品名	販売価格	台数	消費税
  4	テレビ	43,888	1	=ROUNDDOWN(C4*D4*0.05,0)
  5	パソコン	185,888	1	=ROUNDDOWN(C5*D5*0.05,0)

【操作例】

• 詳細はROUNDUPと同様のため省略します。
• 【関数の引数】ダイアログの設定は下図のようになります。
• 

ROUNDDOWN関数の桁数(引数)について　　　　　topへ

• C4:G7の計算結果は表示桁数を小数点以下3桁にしています。
  

基準値の倍数の近い値に切り上げる　　　topへ
　シーリング
=CEILING(数値,基準値)
　　　ケース単位で発注する場合に、必要なケース数を求めるときなどに使います。
　　　(数値と基準値の符号が一致する必要があります)

【問題】　

• 鉛筆とノートの在庫が少なくなりました。鉛筆とノートを必要量購入します。
• 問屋さんへの発注はケース単位で発注しなければなりません。何ケース発注すればよいでしょうか？

• 	B	C	D	E	F
  2		数量	基準値
  3	品名	必要量	1ケースの本数	発注本数	発注ケース数
  4	鉛筆	50	12	60	5
  5	ノート	40	12	48	4

【解答1例】

• ケース単位で発注する場合のケース数の求め方です。
• 必要な量50を発注するには、ケース単位では5ケース、本数は60を注文することになります。
• 12×4=48　　12×5=60　必要数は50なので12の倍数で50に近い60に切り上げます。
  E4セルは =CEILING(C4,12) となります。またはD4セルの「12」を使うと =CEILING(C4,D4) となります。

• 	B	C	D	E	F
  2		数量	基準値
  3	品名	必要量	1ケースの本数	発注本数	発注ケース数
  4	鉛筆	50	12	=CEILING(C4,D4)	=E4/D5
  5	ノート	40	12	=CEILING(C5,D5)	=E5/D5

【問題2】

• 出勤時間と退社時間が記入されています。
  1. 勤務時間をD3,D4セルに求めなさい。ただし休憩時間は無視します。
  2. 基準時間で切り上げて時給を支払いますので、支払う時間をF3,F4セルに求めなさい。

  	B	C	D	E	F
  2	出社時刻	退社時刻	勤務時間	基準時間(分)	支払単位時間
  3	8：00	17：12	9：12	0：30	9：30
  4	8：37	16：20	7：43	0：30	8：00

【解答2例】

1. 勤務時間=退社時間-出社時間
2. 支払単位時間は切り上げて計算しますので、CEILING関数を使います。
   =CEILING(D3,E3)　または、=CEILING(D3,"0:30")　でもOKです。

• 	B	C	D	E	F
  2	出社時刻	退社時刻	勤務時間	基準時間(分)	支払単位時間
  3	8：00	17：12	=C3-B3	0：30	=CEILING(D3,E3)
  4	8：37	16：20	=C4-B4	0：30	=CEILING(D4,E4)

  F3,F4セルがシリアル値で表示されたら、表示形式を時刻に変更します。

1. F3:F4セルを範囲選択します。
2. 【書式】→【セル】を選択します。
3. 下記の設定にします。
   

基準値の近い倍数に切り下げる　　　topへ
　フロアー
=FLOOR(数値,基準値）
　(数値と基準値の符号が一致する必要があります)

除数で割ったときの余りを求める
　モッド
=MOD(数値,除数)

【問題】

• 鉛筆とノートの在庫が少なくなりました。鉛筆とノートを必要量購入します。
• 問屋さんへ何ケース、何本　発注すればよいでしょうか？オレンジのセルに数式を入れなさい。

• 	B	C	D	E	F	G
  2		数量	基準値
  3	品名	必要量	1ケースの本数	ケースでの発注本数	発注ケース数	発注単品数
  4	鉛筆	50	12	48	4	2
  5	ノート	40	12	36	3	4

【解答例】

• 必要な最小ケース数はFLOOR関数、端数はMOD関数で求めます。
• １２×４＝４８　　１２×５＝６０　必要数は５０なので１２の倍数の４８に切り下げます。
  =FLOOR(C4,D4)　または　=FLOOR(C4,12)　となります。
• 50÷12＝４　余り２　(この計算の余り２を求める)
  =MOD(C4,D4)　または=MOD(C4,12) となります。

• 	B	C	D	E	F	G
  2		数量	基準値
  3	品名	必要量	1ケースの本数	ケースでの発注本数	発注ケース数	発注単品数
  4	鉛筆	50	12	=FLOOR(C4,D4)	=E4/D4	=MOD(C4,D4)
  5	ノート	40	12	=FLOOR(C5,D5)	=E5/D5	=MOD(C5,D5)

【問題2】

• 出勤時間と退社時間が記入されています。
  1. 勤務時間をD3,D4セルに求めなさい。ただし休憩時間は無視します。
  2. 基準時間で切り捨てて時給を支払いますので、支払う時間をF3,F4セルに求めなさい。

  	B	C	D	E	F
  2	出社時刻	退社時刻	勤務時間	基準時間(分)	支払単位時間
  3	8：00	17：12	9：12	0：30	9：00
  4	8：37	16：20	7：43	0：30	7：30

【解答2例】

1. 勤務時間＝退社時間−出社時間
2. 支払単位時間は切り捨てて計算しますので、FLOOR関数を使います。
   =FLOOR(D3,E3)　または　=FLOOR(D3,"0:30")　となります。

• 	B	C	D	E	F
  2	出社時刻	退社時刻	勤務時間	基準時間(分)	支払単位時間
  3	8:00	17:12	=C3-B3	0:30	=FLOOR(D3,E3)
  4	8:37	16:20	=C4-B4	0:30	=FLOOR(D4,E4)

  F3,F4セルがシリアル値で表示されたら、表示形式を時刻に変更します。

【操作手順】

1. F3:F4セルを範囲選択します。
2. 【書式】→【セル】を選択します。
3. 下記の設定にします。
   

除算の商の整数部を返します　　　　　topへ
　クオウシェント
=QUOTIENT(分子,分母)
　　分子：被除数 (割られる数) を指定します。
　　分母：除数 (割る数) を指定します。
(注) この関数はメニューバーの【ツール】→【アドイン】で【分析ツール】を有効にする必要があります。

• 商の余り (小数部) を切り捨てる場合に、この関数を使います。

【例】

• 10÷3　の商を求めると、　=QUOTIENT(10,3)=3　となります。
• -10÷3　の商を求めると、　=QUOTIENT(-10,3)=-3　となります。

【蛇足】

• TRUNC関数と同じ結果が得られます。
  =TRUNC(10/3)=3　　=TRUNC(-10/3)-3　となります。
• ROUNDDOWN関数でも同じ結果が得られます。
  =ROUNDDOWN(10/3,0)=3　=ROUNDDOWN(-10/3,0)=-3　となります。

基準値の近い倍数に丸める(四捨五入)　　　topへ
　エムラウンド
=MROUND(数値,基準値）
　　　　　　CEILING関数とFLOOR関数の間みたいな関数です。
　(注) Excel2003以前のバージョンでは、この関数はメニューバーの【ツール】→【アドイン】で【分析ツール】を有効にする必要があります。

【例】

• 必要な個数に最も近いケース単位での個数を求めます。
• たとえば、50個欲しい場合、12個単位で　50を四捨五入するわけです。
• 50÷12＝4あまり2です。2は12の半分より小さいので切り捨てになり、結果は12×4＝48となります。
• 54個欲しい場合は、54÷12＝4あまり6です。
  6は12の半分以上なので切り上げて5になり、結果は12×5＝60となります。

• 	B	C	D	E	F	G	H
  2		数量	基準値
  3	品名	必要量	1ケースの本数	発注本数	答え	発注ケース数	答え
  4	鉛筆	50	12	=MROUND(C4,D4)	48	=E4/D4	4
  5	鉛筆	54	12	=MROUND(C5,D5)	60	=E5/D5	5
  6	ノート	61	12	=MROUND(C6,D6)	60	=E6/D6	5
  7	ノート	66	12	=MROUND(C7,D7)	72	=E7/D7	6

  • IEからのExcelへのエクスポートで#NAMEエラーが出る場合は、新しいブックを開き、IEからコピー、貼り付けしてみてください。

その数値を超えない最大の整数を返す　　　　topへ
　イント
=INT(数値)
　　数値を整数にします。小数点以下を切り捨てます。
　　数値が負の値の時は、数値を超えない整数になリます。

数値の小数部を切り捨てて、整数または指定した桁数に変換する
　トランク
=TRUNC(数値,桁数)
　　桁数は省略できます。省略時は0を指定したのと同じになります。
　　小数部を切り捨てる点は、INT関数と似ていますが、桁数を指定できるのと、数値が負の値の時も、単に小数点以下を切り捨てます。

【問題】

• 鉛筆とノートを購入しました。消費税（5％で1円未満は切り捨て）はいくら必要でしょうか?
• また、消費税込みでの支払金額はいくらでしょうか?

• 	B	C	D	E	F
  2
  3	品名	購入数	単価	消費税	支払金額
  4	鉛筆	50	50	125	2,625
  5	ノート	40	100	200	4,200

【解答例】

• 消費税は小数値を切捨てで計算するので、INT関数を使いました。
• なお、ROUNDDOWN関数を使っても同じ結果になります。=ROUNDDOWN(C4*D4*0.05,0)　
• また、求める値は正数なので、TRUNC関数でも同じ結果になります。=TRUNC(C4*D4*0.05)

• 	B	C	D	E	F
  2
  3	品名	購入数	単価	消費税	支払金額
  4	鉛筆	50	50	=INT(C4*D4*0.05)	=INT(C4*D4*1.05)
  5	ノート	40	100	=INT(C5*D5*0.05)	=INT(C5*D5*1.05)

INT関数とTRUNC関数の違い　　　　　topへ

• 負の値では異なった値を返します。
  

最も近い偶数に切り上げた値を返す　　　　topへ
　イーブン
=EVEN(数値）

数値を最も近い奇数に切り上げた値を返す
　オッド
=ODD(数値）

【使用例】C3に=EVEN(B3)、D3に=ODD(B3)と入力し、C11,D11までコピーした例です。

• 	B	C	D
  2	数値	EVEN	ODD
  3	1	2	1
  4	2	2	3
  5	3	4	3
  6	4	4	5
  7	0	0	1
  8	-1	-2	-1
  9	-2	-2	-3
  10	-3	-4	-3
  11	-4	-4	-5

PageViewCounter

Since2006/2/27