1. Home » 
2. エクセル関数の技 » 
3. IF関数で複数の条件を指定する(AND,OR,NOT)

IF関数で複数の条件を指定する(AND,OR,NOT):Excel関数の技

• IF関数で複数の条件を指定する方法です。ここでの複数の条件とは、対象のセルが異なるケースで説明します。
  IF関数を複数つなげて使う方法は　エクセル関数の技：IF関数のネスト(入れ子)の方法　をご覧ください。

更新:2024/2/20;作成:2014/7/9

IF関数で複数の条件を指定する　　topへ

• 論理式とは「指定した条件を満たすか否か」を数式で表します。
  • 例えば、A1セルの値が「得点が7０以上」という場合は A1>=70　という式で表します。
    A1セルの値が「得点が7０である」という場合は A1=70　という式で表します。
    A1セルの値が「得点が7０未満」という場合は A1<70　という式で表します。
    つまり、下表の比較演算子を使った数式で論理式を書きます。
    

    比較演算子	意味	使用例
    = (等号)	等しい	=A1=70
    > (大なり記号)	より大きい	=A1>70
    < (小なり記号)	より小さい	=A1<70
    >= (より大か等しい)	以上	=A1>=70
    <= (より小か等しい)	以下	=A1<=70
    <> (不等号)	等しくない	TRUE

• IF関数とAND関数、OR関数との組み合わせの例を示します。
  • 「すべての条件を満たす」という場合はAND関数を使って、=AND(論理式１，論理式2，・・・・)　と書きます。
  • 「いずれかの条件を満たす」という場合はOR関数を使って、=OR(論理式１，論理式2，・・・・)　と書きます。
  • 結果を否定したい場合はNOT関数を使って、　=NOT(論理式)　とすることもできます。
    すべての条件を満たさない」という場合はNOT関数でAND関数の結果を否定します。
    =NOT(AND(論理式１，論理式2，・・・・)　といった具合です。
  • 論理関数の詳細は　Excel基本講座：論理関数（AND,OR,NOT,XOR,IFERROR,IFNA)　をご覧ください。
• 下図のようなデータを使って具体例で説明します。
  

  	B	C	D	E	F
  2	名前	1回目	2回目	3回目	判定
  3	安藤	84	73	71	○
  4	井上	76	70	42
  5	上野	61	57	49
  6	岡田	92	71	73	○
  7	太田	70	58	48
  8	蒲池	64	40	52

IF関数でAND関数を使う例

• 条件例1：1回目〜3回目の結果がすべて70以上であれば合格と表示します。
  同じ条件でもいろいろな考え方ができるため、数式もいろいろなものが考えられます。
  1. C3>=70、D3>=70、E3>=70　のすべてを満足するので、　AND(C3>=70,D3>=70,E3>=70) とします。
     よって、　=IF(AND(C3>=70,D3>=70,E3>=70),"合格","")　といった数式が考えられます。
     

     	B	C	D	E	F
     2	名前	1回目	2回目	3回目	判定	F列の数式
     3	安藤	84	73	71	合格	=IF(AND(C3>=70,D3>=70,E3>=70),"合格","")
     4	井上	76	70	42		=IF(AND(C4>=70,D4>=70,E4>=70),"合格","")
     5	上野	61	57	49		=IF(AND(C5>=70,D5>=70,E5>=70),"合格","")
     6	岡田	92	71	73	合格	=IF(AND(C6>=70,D6>=70,E6>=70),"合格","")
     7	太田	70	58	48		=IF(AND(C7>=70,D7>=70,E7>=70),"合格","")
     8	蒲池	64	40	52		=IF(AND(C8>=70,D8>=70,E8>=70),"合格","")

     • ところがこの数式にはちょっとした落とし穴があります。
       例えば、D3セルに「欠席」といったような文字が入力されていたら？・・・・このような場合にも「合格」となります。
       
     • 3回とも出席していることが「合格」の隠れた条件であるとしたら、COUNT(C3:E3)=3　ともう一つ加える必要があります。
       =IF(AND(COUNT(C3:E3)=3,C3>=70,D3>=70,E3>=70),"合格","")
       
• 論理式をちょっと変えた数式も考えられます。
  1. すべてが70以上という条件は、最小値が70以上と読み替えることができます。
     すると、=IF(AND(COUNT(C3:E3)=3,MIN(C3:E3)>=70),"合格","")　となります。
     
  2. 裏読みすると、いずれかが70未満であれば"不合格"　でそれ以外なら「合格」とすることもできます。
     すると、=IF(OR(C3<70,D3<70,E3<70),"","合格")　となります。不合格のところは空欄処理して　"" としてあります。
     
  3. 上のCの条件を否定した数式を作成することもできます。
     Cの条件部分を否定して、=IF(NOT(OR(C3<70,D3<70,E3<70)),"合格","")　とすることもできます。
     
  4. ここの本題からは外れますが、*演算子や+演算子を利用することもできます。
     すべてが70以上の場合の論理式は(C3>=70)*(D3>=70)*(E3>=70)　ですので、
     =IF((C3>=70)*(D3>=70)*(E3>=70),"合格","")　とすることができます。
     いずれかが70未満であるという場合の論理式は　(C3<70)+(D3<70)+(E3<70)　ですので、
     =IF((C3<70)+(D3<70)+(E3<70),"","合格")　とすることができます。

IF関数でOR関数を使う例

• OR条件の例：1回目〜3回目の結果のいずれかが70以上であれば合格と表示します。
  C3>=70、D3>=70、E3>=70　のいずれかを満足するので、　OR(C3>=70,D3>=70,E3>=70) とします。
  よって、　=IF(OR(C3>=70,D3>=70,E3>=70),"合格","")　といった数式が考えられます。
  

  	B	C	D	E	F	G
  2	名前	1回目	2回目	3回目	判定
  3	安藤	84	73	71	合格	=IF(OR(C3>=70,D3>=70,E3>=70),"合格","")
  4	井上	76	70	42	合格	=IF(OR(C4>=70,D4>=70,E4>=70),"合格","")
  5	上野	61	57	49		=IF(OR(C5>=70,D5>=70,E5>=70),"合格","")
  6	岡田	92	71	73	合格	=IF(OR(C6>=70,D6>=70,E6>=70),"合格","")
  7	太田	70	58	48	合格	=IF(OR(C7>=70,D7>=70,E7>=70),"合格","")
  8	蒲池	64	40	52		=IF(OR(C8>=70,D8>=70,E8>=70),"合格","")

IF関数でNOT関数を使う例

• NOT条件の例：1回目〜3回目の結果のすべてが70点以上でなかったら不合格と表示します。
  すべてが70点以上であるという条件は　AND(C3>=70,D3>=70,E3>=70)
  すべてが70点以上でないという場合は　NOT(AND(C3>=70,D3>=70,E3>=70))　とします。
  よって、　=IF(NOT(AND(C3>=70,D3>=70,E3>=70)),"不合格","")　といった数式が考えられます。
  

  	B	C	D	E	F	G
  2	名前	1回目	2回目	3回目	判定
  3	安藤	84	73	71		=IF(NOT(AND(C3>=70,D3>=70,E3>=70)),"不合格","")
  4	井上	76	70	42	不合格	=IF(NOT(AND(C4>=70,D4>=70,E4>=70)),"不合格","")
  5	上野	61	57	49	不合格	=IF(NOT(AND(C5>=70,D5>=70,E5>=70)),"不合格","")
  6	岡田	92	71	73		=IF(NOT(AND(C6>=70,D6>=70,E6>=70)),"不合格","")
  7	太田	70	58	48	不合格	=IF(NOT(AND(C7>=70,D7>=70,E7>=70)),"不合格","")
  8	蒲池	64	40	52	不合格	=IF(NOT(AND(C8>=70,D8>=70,E8>=70)),"不合格","")

スポンサードリンク

　PageViewCounter
　
　Since2006/2/27