1. Home » 
2. エクセル練習問題：目次 » 
3. データをカウントする

エクセル練習問題：データをカウントする

問題1の解答例　　　　topへ

• 解答
  

  	B	C	D	E	F
  2	名前	性別	1回目のテスト		受験者数
  3	相沢一郎	男	52		6
  4	井上浩二	男	74		欠席者数
  5	上野有紀	女	欠席		2
  6	内野武	男	35
  7	上田祥子	女	欠席
  8	江田早苗	女	59
  9	榎本高貴	男	0
  10	小田和樹	男	47

• データのどこに着目するかで、色々な数式が考えられます。

COUNT関数、COUNTIF関数を使う

• 受験者には得点(数値)が入力されていて、欠席者には「欠席」と文字列が入力されていると、判断しました。
• 数値の数をカウントするにはCOUNT関数が使えます。
  受験者数は　=COUNT(D3:D10)　で求めることができます。
  • 構文：=COUNT(値1,[値2],・・・)
    COUNT関数 に説明がありますので参照してください。
• 欠席者数は「欠席」という文字の入力されているセル数を数えればよいので、COUNTIF関数が使えます。
  欠席者数は　=COUNTIF(D3:D10,"欠席")　で求めることができます。
  • 構文：=COUNTIF(範囲,検索条件)
    COUNTIF関数 に説明がありますので参照してください。

• 	B	C	D	E	F
  2	名前	性別	1回目のテスト		受験者数
  3	相沢一郎	男	52		=COUNT(D3:D10)
  4	井上浩二	男	74		欠席者数
  5	上野有紀	女	欠席		=COUNTIF(D3:D10,"欠席")
  6	内野武	男	35
  7	上田祥子	女	欠席
  8	江田早苗	女	59
  9	榎本高貴	男	0
  10	小田和樹	男	47

COUNTA関数を使う

• 受験者と欠席者とを合わせた数はCOUNTA関数で求めることができます。
  構文：構文：=COUNTA(値1,[値2],・・・)
  COUNTA関数 に説明がありますので参照してください。
  この値から、受験者数を差し引いたものが欠席者となるので、
  欠席者は　=COUNTA(D3:D10)-COUNT(D3:D10)　として求めることもできます。

• 	B	C	D	E	F
  2	名前	性別	1回目のテスト		受験者数
  3	相沢一郎	男	52		=COUNT(D3:D10)
  4	井上浩二	男	74		欠席者数
  5	上野有紀	女	欠席		=COUNTA(D3:D10)-COUNT(D3:D10)
  6	内野武	男	35
  7	上田祥子	女	欠席
  8	江田早苗	女	59
  9	榎本高貴	男	0
  10	小田和樹	男	47

COUNTA関数を使う

• 上のBとは逆に全員の数から欠席者の数を差し引いて受験者数を求める・・・といった考え方もできます。
• 受験者数　=COUNTA(D3:D10)-COUNTIF(D3:D10,"欠席")
• 欠席者数　=COUNTIF(D3:D10,"欠席")

• 	B	C	D	E	F
  2	名前	性別	1回目のテスト		受験者数
  3	相沢一郎	男	52		=COUNTA(D3:D10)-COUNTIF(D3:D10,"欠席")
  4	井上浩二	男	74		欠席者数
  5	上野有紀	女	欠席		=COUNTIF(D3:D10,"欠席")
  6	内野武	男	35
  7	上田祥子	女	欠席
  8	江田早苗	女	59
  9	榎本高貴	男	0
  10	小田和樹	男	47

問題2の解答例　　　topへ

• 解答
  

  	B	C	D	E	F
  2	名前	性別	判定		合格者の数
  3	相沢一郎	男	不合格		5
  4	井上浩二	男	合格
  5	上野有紀	女	合格
  6	内野武	男	合格
  7	上田祥子	女	合格
  8	江田早苗	女	不合格
  9	榎本高貴	男	合格
  10	小田和樹	男	不合格

COUNTIF関数を使う

• 「合格」と入力されたセルの数をカウントするのは、COUNTIF関数で求めることができます。
• 構文：=COUNTIF(範囲,検索条件)
  COUNTIF関数 に説明がありますので参照してください。

• 	B	C	D	E	F
  2	名前	性別	判定		合格者の数
  3	相沢一郎	男	不合格		=COUNTIF(D3:D10,"合格")
  4	井上浩二	男	合格
  5	上野有紀	女	合格
  6	内野武	男	合格
  7	上田祥子	女	合格
  8	江田早苗	女	不合格
  9	榎本高貴	男	合格
  10	小田和樹	男	不合格

SUMPRODUCT関数を使う

• SUMPRODUCT関数を使って求めることもできます。
  F3セルに　=SUMPRODUCT((D3:D10="合格")*1) 　と入力します。
• 構文：=SUMPRODUCT(配列1,[配列2],[配列3],・・・)
  SUMPRODUCT関数　に説明がありますので参照してください。

• 	B	C	D	E	F
  2	名前	性別	判定		合格者の数
  3	相沢一郎	男	不合格		=SUMPRODUCT((D3:D10="合格")*1)
  4	井上浩二	男	合格
  5	上野有紀	女	合格
  6	内野武	男	合格
  7	上田祥子	女	合格
  8	江田早苗	女	不合格
  9	榎本高貴	男	合格
  10	小田和樹	男	不合格

• 数式バーで　=SUMPRODUCT((D3:D10="合格")*1)　の　(D3:D10="合格")　部分を選択して、[F9]キーを押すと、選択している部分の計算結果を表示することができます。
  
  ↓
  下図のように、=SUMPRODUCT({FALSE;TRUE;TRUE;TRUE;TRUE;FALSE;TRUE;FALSE}*1)　と計算されるのがわかります。
  [Esc]キーを押すと元の数式(計算前の状態)に戻すことができます。
  
  ↓
  [Esc]キーで元の数式に戻し、数式バーで　=SUMPRODUCT((D3:D10="合格")*1)　の　(D3:D10="合格")*1　部分を選択して、[F9]キーを押します。
  =SUMPRODUCT({0;1;1;1;1;0;1;0})　と計算結果が表示されます。
  

• 解答
  

  	B	C	D	E	F
  2	名前	性別	判定		男の合格者の数
  3	相沢一郎	男	不合格		3
  4	井上浩二	男	合格
  5	上野有紀	女	合格
  6	内野武	男	合格
  7	上田祥子	女	合格
  8	江田早苗	女	不合格
  9	榎本高貴	男	合格
  10	小田和樹	男	不合格

COUNTIFS関数を使って複数条件でカウントする

• 複数条件のカウントはCOUNTIFS関数で求めることができます。（Excel2007以降で使用できます）
• 構文：COUNTIFS(条件範囲1,検索条件1,[条件範囲2,検索条件2]・・・)
  COUNTIFS関数 に説明がありますので参照してください。

• 	B	C	D	E	F
  2	名前	性別	判定		男の合格者の数
  3	相沢一郎	男	不合格		=COUNTIFS(C3:C10,"男",D3:D10,"合格")
  4	井上浩二	男	合格
  5	上野有紀	女	合格
  6	内野武	男	合格
  7	上田祥子	女	合格
  8	江田早苗	女	不合格
  9	榎本高貴	男	合格
  10	小田和樹	男	不合格

SUMPRODUCT関数を使って求める

• =SUMPRODUCT((C3:C10="男")*(D3:D10="合格"))
• 構文：=SUMPRODUCT(配列1,[配列2],[配列3],・・・)
  SUMPRODUCT関数 に説明がありますので参照してください。
• または、　=SUMPRODUCT((C3:C10&D3:D10="男合格")*1)　といった式でも求めることができます。

• 	B	C	D	E	F
  2	名前	性別	判定		男の合格者の数
  3	相沢一郎	男	不合格		=SUMPRODUCT((C3:C10="男")*(D3:D10="合格"))
  4	井上浩二	男	合格
  5	上野有紀	女	合格		または、↓
  6	内野武	男	合格		=SUMPRODUCT((C3:C10&D3:D10="男合格")*1)
  7	上田祥子	女	合格
  8	江田早苗	女	不合格
  9	榎本高貴	男	合格
  10	小田和樹	男	不合格

データベース関数　DCOUNTA関数を使って求める

• この問題ではDCOUNTA関数を使うことができます。
• 構文：=DCOUNTA(データベース,フィールド,検索条件)
  DCOUNT関数 に説明がありますので参照してください。
• 検索条件をG2:H2に入力した例です。
  F3セルは　=DCOUNTA(C2:D10,1,G2:H3)　としました。
  

  	B	C	D	E	F	G	H
  2	名前	性別	判定		男の合格者の数	性別	判定
  3	相沢一郎	男	不合格		=DCOUNTA(C2:D10,1,G2:H3)	男	合格
  4	井上浩二	男	合格
  5	上野有紀	女	合格
  6	内野武	男	合格
  7	上田祥子	女	合格
  8	江田早苗	女	不合格
  9	榎本高貴	男	合格
  10	小田和樹	男	不合格

作業列を利用すると容易な数式になります

• E列を作業列として、E3セルに以下のように入力します。
  =IF(AND(C3="男",D3="合格"),1,"0")
  

  	B	C	D	E	F
  2	名前	性別	判定	作業列	男の合格者の数
  3	相沢一郎	男	不合格	=IF(AND(C3="男",D3="合格"),1,"0")	=SUM(E3:E10)
  4	井上浩二	男	合格	=IF(AND(C4="男",D4="合格"),1,"0")
  5	上野有紀	女	合格	=IF(AND(C5="男",D5="合格"),1,"0")
  6	内野武	男	合格	=IF(AND(C6="男",D6="合格"),1,"0")
  7	上田祥子	女	合格	=IF(AND(C7="男",D7="合格"),1,"0")
  8	江田早苗	女	不合格	=IF(AND(C8="男",D8="合格"),1,"0")
  9	榎本高貴	男	合格	=IF(AND(C9="男",D9="合格"),1,"0")
  10	小田和樹	男	不合格	=IF(AND(C10="男",D10="合格"),1,"0")

• 男の合格者には「1」が入力されるので、=SUM(E3:E10)　で求めることができます。

• 	B	C	D	E	F
  2	名前	性別	判定	作業列	男の合格者の数
  3	相沢一郎	男	不合格	0	=SUM(E3:E10)
  4	井上浩二	男	合格	1
  5	上野有紀	女	合格	0
  6	内野武	男	合格	1
  7	上田祥子	女	合格	0
  8	江田早苗	女	不合格	0
  9	榎本高貴	男	合格	1
  10	小田和樹	男	不合格	0

スポンサードリンク

PageViewCounter

Since2006/2/27