1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. IF関数＆IS関数

IF関数＆IS関数の使い方:Excel関数

• 条件判定（IF関数)および複数条件を設定する時のAND関数、OR関数の使い方、セルや数式の状態を調べるIS関数の説明をしています。

更新:2025/1/29;作成:2005/12/07

条件判定の関数　　　topへ
　イフ
=IF(論理式,値が真の場合,値が偽の場合）
　　論理式が満たされている場合は値が真の場合を表示し、満たされていない場合は値が真の場合を表示する。
　　(補足)　IF 関数は最大 64個(2003以前は7つ)まで組み合わせることができます。それを超える場合には他の関数を使って処理します。

• 【問題】国語の得点が60以上であれば[合格]、そうでなければ[不合格]と判定の列Dに表示しなさい。　

  	B	C	D
  2		国語	判定
  3	相沢恭子	80	合格
  4	今田浩次	50	不合格
  5	上田美香	30	不合格
  6	江口恭介	70	合格

• 【解答例】60以上であったら「合格」、そうでなかったら「不合格」とします。
  
  D3セルには　=IF(C3>=60,"合格","不合格")　と入力します。
  この数式は「もしC3セルの値が60以上であったら「合格」、そうでなかったら「不合格」としなさい」となります。
  

条件式(論理式)に使う記号(比較演算子)　　　　topへ

• 比較演算子	説明	演算子の意味
  A=B	AとBが等しい	イコール,等しい,
  A>B	AがBよりも大きい	大なり,より大きい
  A<B	AがBよりも小さい	小なり,より小さい,未満
  A>=B	AがB以上	以上,大なりイコール
  A<=B	AがB以下	以下,小なりイコール
  A<>B	AとBが等しくない	等しくない

未入力セルの空白処理　　　　　topへ

• 得点欄C3セルが空白の(入力されていない）場合にはD3セルに[不合格]と表示されてしまいます。
  
  それを防ぐのにIF関数を使います。 =IF(C3="","",IF(C3>=60,"合格","不合格"))
  「もし、C3セルが空白なら、空白にして、そうでなかったら、60以上で合格、それ以外は不合格とする」との意味合いで、IF関数を2重で使用しています。
  
• ISBLANK関数を使う方法もあります。
  =IF(ISBLANK(C3),"",IF(C3>=60,"合格","不合格"))
  「C4セルがブランクであったら""(長さ0の文字列)と表示しなさい、もしC3セルが60以上なら合格とし、それ以外(60未満)は不合格と表示しなさい。」との意味合いで、IF関数を2重で使用しています。
  

文字列の比較　　　　　topへ

• ここでは　C3="OK"　という式で条件判定を行うと　大文字/小文字の区別がされませんという例です。
• 【問題2】 C列に正解であったら「OK」と入力して、得点「25」を与えたいと思います。
  ところが入力ミスで「Ok」、「oK」とも入力されています。D列の得点を表示する式を入れなさい。
  

  	B	C	D
  2		国語	得点
  3	問題1-1	OK	25
  4	問題1-2	×	0
  5	問題2-1	oK	25
  6	問題2-2	Ok	25
  7	合計得点		75

• 【解答例】 C3="OK"　で条件判定を行うと　大文字/小文字の区別がされませんので　=IF(C3="OK",25,0)　で計算できます。
  
• 大文字と小文字の区別をしたい時はどうすればよいでしょうか?　(上の表で合計得点を25とするには？)
  大文字/小文字の区別する場合は下のEXACT関数を使います。

  • 文字列の比較　　　　topへ
    　イグザクト
    =EXACT(文字列1，文字列2）
    　　　2つの文字列を比較して、まったく同じである場合は TRUE を、そうでない場合は FALSE を返します。
    　　　英字の大文字と小文字は区別されます。

  • ちなみに、EXACT関数で大文字と小文字の区別をするときや文字の違いを　=EXACT(C3,"OK") として調べると、下図のE列のような結果となります。
    D3セルに　=IF(EXACT(C3,"OK"),25,0)　と入力して、D6セルまで数式をコピーします。
    これは「C3セルの値が OK と同じなら 25、 そうでなかったら 0 としなさい。」といった数式です。
    

時刻の比較　　　topへ

• 時刻の比較は小数誤差によってうまく処理されないことがあります。
  • TIMEVALUE関数でシリアル値に変換する
  • 時刻のシリアル値(小数値)を整数に直して比較する
  など、小数誤差の影響を受けないようにする必要があります。
• 数式　=IF(B2="9:00","OK","NG")　の場合、B2="9:00"　は左辺B2の値はシリアル値で、右辺の"9:00"は文字列なので、同じ値とはなりません。
  
• 数式　=IF(B2=TIMEVALUE("9:00"),"OK","NG")の場合、右辺をTIMEVALUE("9:00")でシリアル値にしていますので、同じ値と判定されます。
  
  • TIMEVALUE関数は長いので、"9:00"*1 と乗算にすることでExcelはシリアル値に変換してくれます。
    
• 数式　=IF(B2=TIME(9,0,0),"OK","NG")の場合、TIME(9,0,0)としてシリアル値での比較にしていますので、同じ値と判定されます。
  
• 数式　=IF(ROUND(B2*24*60,0)=ROUND("9:00"*24*60,0),"OK","NG")　の場合
  小数誤差を含んでいる可能性があるとき、左辺のROUND(B2*24*60,0)でB2セルの値を分単位の整数値に丸めています。
  右辺も同様に、ROUND("9:00"*24*60,0)として9：00を分単位の整数値に丸めています。
  こうすることで小数誤差の影響を排除することができます。
  

複数条件の判定　　　　topへ
=IF(AND(論理式1,論理式2,・・・),値が真の場合,値が偽の場合）
　　　　　論理式1　かつ　論理式2　かつ・・・・の場合、値が真の場合を返し、そうでない場合は値が偽の場合を返す。
=IF(OR(論理式1,論理式2,・・・),値が真の場合,値が偽の場合）
　　　　　論理式1　または　論理式2　または・・・・の場合、値が真の場合を返し、そうでない場合は値が偽の場合を返す。

• 【問題1】 国語と算数の両方が60以上の場合に[合格]それ以外は[不合格]としなさい。

  	B	C	D	E
  2		国語	算数	判定
  3	相沢恭子	80	85	合格
  4	今田浩次	60	90	合格
  5	上田美香	30	40	不合格
  6	江口恭介	70	50	不合格

• 【解答例1】
  • E3セル：=IF(AND(C3>=60,D3>=60),"合格","不合格")
    ”もしC3セルが60以上かつD3セルも60以上なら『合格』、そうでなければ『不合格』としなさい”となります。
    
• 【余談】AND関数を使用しない方法：論理演算子（論理積「*」）を使用する方法
  • セルE3に=IF((C3>=60)*(D3>=60),"合格","不合格")　とします。
    TRUE=1　FALSE=0　に置き換えて計算すると、TRUE*TRUE=1*1=1　以外の組み合わせは0(FALSE)になります。
    

• 【問題2】 国語か算数のどちらかが60以下であれば[不合格]そうでなければ[合格]と表示しなさい。

  	B	C	D	E
  2		国語	算数	判定
  3	相沢恭子	80	85	合格
  4	今田浩次	60	90	不合格
  5	上田美香	30	40	不合格
  6	江口恭介	70	50	不合格

• 【解答例2】 E3セル：=IF(OR(C3<=60,D3<=60),"不合格","合格")
  「もしC3セルが60以下あるいはD3セルが60以下ならば『不合格』、そうでなければ『合格』としなさい」となります。
  
• 【余談】OR関数を使用しない方法：論理演算子（論理和「+」）を使用する方法
  • セルE3に=IF((C3<=60)+(D3<=60),"不合格","合格")　とします。
    TRUE=1　FALSE=0　に置き換えて計算すると、FALSE+FALSE=0+0=0　以外の組み合わせは1以上になります。
    Excelのシートでは0以外はTRUEと見なすので、FALSE+FALSE以外の条件はTRUEになります。
    

ANDとORを組み合わせて使う　　　　topへ

• 【問題】 A1セルに入力された年がうるう年であるか否かを判定するには?
  うるう年の判定は↓で行います。
  1. 西暦年数が4で割り切れる年は原則として「うるう年」にする。
  2. 上記の例外として、西暦年数が100で割り切れる年は「平年」とする。
  3. さらに例外として、西暦年数が400で割り切れる年は「うるう年」にする。
• 【解答例】
  • =IF(OR(MOD(A1,400)=0,AND(MOD(A1,4)=0,MOD(A1,100)<>0)),"うるう年","平年")
  • 上の数式を解釈すると、『400で割り切れるか、あるいは、4で割り切れて100で割り切れない場合には「うるう年」そうでない場合は「平年」としなさい』となります。
  • 数式は　Microsoft　サポート技術情報　[XL] うるう年を判定する方法　を利用しています。
• 【参考】
  • =DATE(A1,3,1)-1=DATE(A5,3,0)　を使って2/29　になれば「うるう年」　そうでなければ「平年」となりそうです。
    ところが、=IF(DAY(DATE(A5,3,0))=29,"うるう年","平年")　としたら、1900年が「うるう年」と判定されてしまいますので、これをExcelで利用することはできません。
  • 原因は、Microsoft　サポート技術情報を参照願います。
    • [XL] 1900 年から計算する日付システムと 1904 年から計算する日付システム
      http://support.microsoft.com/kb/180162/jp/

IS関数　　　　topへ
　イズエラー
=ISERROR(テストの対象)
　　　テストの対象が任意のエラー値 を参照するとき TRUE を返します。
　　　エラー値：#N/A、#VALUE!、#REF!、#DIV/0!、#NUM!、#NAME? または #NULL! のいずれか

• E5の式は=D5/C5*100ですが、C5が空白であるためにエラー(#DIV/0!)となります。
  エラー表示をなくすためにIF関数とISERROR関数を組み合わせて使います。
  E8セルの例：=IF(ISERROR(D8/C8),"",D8/C8*100)
  式の意味は「もしD8/C8がエラー値であったら、「""」(空白)としなさい、そうでなかったらD8/C8*100の結果を表示しなさい。」となります。
  
• IFERROR関数がExcel2007で追加されています。
  これらの関数では簡易な数式でエラー処理ができるようになっています。
  詳細は　IFERROR関数　　をご覧ください。
  E8セルの数式は　=IFERROR(D8/C8*100,"")　とすることができます。
  

　イズブランク　　　　　topへ
=ISBLANK(テストの対象)
　　　テストの対象が空白セルを参照するとき TRUE を返します。

• E5セルのように、空白セル(未入力セル)で割り算を行うと　#DIV/0!　とエラーになります。
  このエラーを表示しないように参照するセルが空白であるか否かを判定しておく必要があります。
• ISBLANK関数を使って空白の判定をすると、下記のようにOR関数と組み合わせて使います。
  E8セルの例：=IF(OR(ISBLANK(C8),ISBLANK(D8)),"",D8/C8*100)
  式の意味は「もし、C8が空白であるか または D8が空白であったら、「""」(空白)を表示しなさい、そうでなかったらD8/C8*100の結果を表示しなさい」となります。
  

• 【注意】ISBLANK関数で空白の判定ができない例
  • ISBLANK関数はIF関数などで空白("")を返しているセルに対しては「FALSE」となります。
    このような場合には、=IF(OR(C8="",D8=""),"",D8/C8*100)　とします。
    

その他のIS関数　　　　　topへ

• ISERROR	対象が(#N/A、#VALUE!、#REF!、#DIV/0!、#NUM!、#NAME? または #NULL! のいずれか) を参照するとき TRUE を返します。
  ISBLANK	対象が空白セルを参照するとき TRUE を返します。
  ISERR	対象が #N/A を除くエラー値を参照するとき TRUE を返します。
  ISLOGICAL	対象が論理値を参照するとき TRUE を返します。
  ISNA	対象がエラー値 #N/A (使用する値がない) を参照するとき TRUE を返します。
  ISNONTEXT	対象が文字列でない項目を参照するとき TRUE を返します (対象が空白セルを参照するときも TRUE になりますので注意してください)。
  ISNUMBER	対象が数値を参照するとき TRUE を返します。
  ISREF	対象がセル範囲を参照するとき TRUE を返します。
  ISTEXT	対象が文字列を参照するとき TRUE を返します。

N関数　　　　topへ
　ナンバー
=N(値)
　　値を数値に変換します。

• 次の戻り値になります。
  

  値	戻り値
  数値	そのままの数値
  Excelの組み込み書式で表示された日付	その日付のシリアル値
  TRUE	1
  FALSE	0
  #DIV/0!などのエラー値	エラー値
  その他	0

  
  
• (例)計算式の中で文字列になる可能性があるセルを使用する場合。
  • B2セルには　””(文字数0の文字列)が入力されているので、　=B2+C2　は　#VALUE! エラーとなります。
    =N(B2)+C2　として、文字列　B2セルを「0」とみなして計算することができます。
    B2セルに　数値50が入力されると、=N(B2)+C2　は90と計算することができます。
    

NA関数　　　　topへ
　エヌエー
=NA()
　　常にエラー値 #N/A を返します

• 折れ線グラフで値が「0」を無視したい時に使います。
• 【例】6月の売上金額(C5セル)が　0　になっています。この　0　を無視します。
  

1. データの方を変更します。
   C5に　=NA()　と入力して　#N/A　を返すようにします。
2. #N/Aは無視して、折れ線が作成されます。
   
   • Excel2010以降では[グラフのデザイン]タブで[データの選択]を選択します。
     
     ↓
     データ ソースの選択で[非表示および空白セル]をクリックします。
     
     ↓
     「#N/A を空のセルとして表示」のチェックを外します。
     

対象範囲の左上隅にあるセルの書式、位置、内容についての情報を返します　　　topへ
　セル
=CELL(検査の種類,対象範囲)
　　　対象範囲は省略可能ですが、最後に変更されたセルについの情報が表示されます。
　　　セル範囲を入力した場合は左上端のセルについての情報が表示されます。

• 検査の種類には「"」(二重引用符、ダブルクォーテーションマーク)で括った文字列を使用します。
  

  検査の種類	戻り値
  "address"	対象範囲の左上隅にあるセル番地を表す文字列を返します。
  "col"	対象範囲の左上隅にあるセルの列番号を返します。
  "color"	負の数を色で表す書式がセルに設定されている場合は 1、それ以外の場合は 0を返します。
  "contents"	対象範囲の左上隅にあるセルの内容を返します。
  "filename"	対象範囲を含むファイルの名前 (絶対パス名) を表す文字列を返します。 対象範囲を含むファイルがまだ保存されていない場合、結果は空白文字列 (") になります。
  "format"	セルの表示形式に対応する文字列定数を返します。
  "parentheses"	正の数またはすべての値をかっこで囲む書式がセルに設定されている場合は 1、それ以外の場合は 0を返します。
  "prefix"	セルに入力されている文字列の配置に対応する文字列定数を返します。 セルが左詰めの文字列を含むときは一重引用符 (') 右詰めの文字列を含むときは二重引用符 (") 中央配置の文字列を含むときはキャレット (^) 均等配置の文字列を含むときは円記号 (\) そのほかのデータが入力されているときは空白文字列 (") になります。
  "protect"	セルがロックされていない場合は 0、ロックされている場合は 1を返します。
  "row"	対象範囲の左上隅にあるセルの行番号を返します。
  "type"	セルに含まれるデータのタイプに対応する文字列定数を返します。 セルが空白の場合は "b" (Blank の頭文字) セルに文字列定数が入力されている場合は "l" (Label の頭文字) そのほかの値が入力されている場合は "v" (Value の頭文字) になります。
  "width"	小数点以下を切り捨てた整数のセル幅を返します。 セル幅の単位は、標準のフォント サイズの 1 文字の幅と等しくなります。

• 【使用例】以下の返される値の例は使用環境により異なります。あくまでも私の使っているPC及び環境での表示例です。
• =CELL("address",A1)
  • $A$1 と絶対参照の形で返されます。
• =CELL("col",A1)
  • A1が対象ですのでA列つまり1が返されます。
    Excel2002の最終列を指定すると、=CELL("col",IV1)　で「256」となります。
• =CELL("color",A1)
  • A1セルに表示形式で　「0_ ;[赤]-0」のような設定をしていると「1」が返ります。
    「0_ ;-0」　の場合は「0」が返ります。
• =CELL("contents",A1)
  • A1セルに「文字」と入力されていると、「文字」が返ります。
    空白セルだと「0」が返されます。
• =CELL("filename",A1)
  • C:\Users\Yone\Documents\Excel_test\[HP_Cell関数.xls]Sheet2　が返りました。
    ファイル名およびシート名までが返されました。
    なお、ファイルが保存されていないときは空白「""」が返ります。
• =Cell("format",A1)
  • セルの表示形式に対応する文字列定数を返します。
    

    Excel の表示形式	戻り値
    G/標準	G
    0	F0
    #,##0	",0"
    0.00	F2
    #,##0.00	",2"
    #,##0;-#,##0 または $#,##0_);($#,##0)	",0"
    #,##0;[赤]-#,##0 または $#,##0_);[赤]($#,##0)	",0-"
    #,##0.00;-#,##0.00 または $#,##0.00_);($#,##0.00)	",2"
    #,##0.00;[赤]-#,##0.00 または $#,##0.00_);[赤]($#,##0.00)	",2-"
    \#,##0_);(\#,##0)	C0
    \#,##0_);[赤](\#,##0)	C0-
    \#,##0.00_);(\#,##0.00)	C2
    \#,##0.00_);[赤](\#,##0.00)	C2-
    0%	P0
    0.00%	P2
    0.00E+00	S2
    # ?/? または # ??/??	G
    ge.m.d	D4
    gggg"年"m"月"d"日"	D4
    yyyy/m/d	D1
    yyyy"年"m"月"d"日"	D1
    m/d/yy	D1
    d-mmm-yy	D1
    d-mmm	D3
    mmm-yy	D2
    yyyy/m/d h:mm	D1
    h:mm AM/PM	D7
    h:mm:ss AM/PM	D6
    h:mm	D9
    h:mm:ss	D8
    h"時"mm"分"	D9
    h"時"mm"分"ss"秒"	D8

• =CELL("parentheses",A1)
  • (0);[赤](0)　のように正の数をかっこで囲む表示形式が設定されていると「1」を返す。
    0_);[赤](0)　の場合は「0」となります。
• =CELL("prefix",A1)
  • 左揃えなどの設定に応じて一重引用符 (')などが返されます。
    
• =CELL("protect",A1)
  • セルがロックされていたら「1」が返ります。ロックされていないときは「0」となります。
    シートの保護は関係ありません。
• =CELL("row",A1)
  • セルの行番号が返ります。この場合は「1」となります。
• =CELL("type",A1)
  • セルに文字列が入力されていたら「ｌ」（LabelのL(エル)の小文字、空白の時は「ｂ」、数値などの場合は「ｖ」となります。
• =CELL("width",A1)
  • セル幅の整数値を返します。標準のフォント サイズの 1 文字の幅が1となります。

IF関数の入れ子の制限　　topへ

• Excel2003以前では最大7個となっていましたが、Excel2007,Excel2010では64個となっています。
• IF関数で多くの条件を使うことが可能にはなったのですが、数式の可読性が悪くなります。
  多くの条件で分けたい場合は、リストを作成するなどしてLOOKUP関数、VLOOKUP関数、HLOOKUP関数を使うことをお勧めします。

IF関数の入れ子の作り方　　topへ

• ネスト(入れ子)の一例としては以下のような数式が挙げられます。
  =IF(論理式1, [真の場合1], IF(論理式2, [真の場合2], IF(論理式3, [真の場合3], [偽の場合3])))
  つまり、[偽の場合]の部分に次の条件を入れて処理していきます。
• 逆に真の場合に入れることもできますが、ちょっと理解しづらいかもしれません。
• こちらも　IF関数のネスト(入れ子)の方法:Excel関数の技　ご覧ください。

練習1

• 得点が0以上30以下は×、60以下は△、60を超え100以下は○と評価することにします。
  

  	B	C	D
  2	名前	得点	評価
  3	井上	80	○
  4	上野	54	△
  5	内田	30	×
  6	榎田	15	×
  7	岡本	77	○
  8	大野	91	○

• 条件の付け方によって数式はいろいろなものができます。

1. ここでは、得点の低い方から順番に処理してみます。
   
   
   1. 30点以下は×とすると、以下のようになります。
      =IF(C3<=30,"×",偽の場合)
   2. 次に60点以下は△とします。「偽の場合」の部分に書きます。
      =IF(C3<=30,"×",IF(C3<=60,"△",偽の場合))
      となり、ここで偽となるのは60を超える得点ですので、「60を超え100以下は○」を入れることになり、
      =IF(C3<=30,"×",IF(C3<=60,"△","○"))
      で、完成です。
   3. 得点が未入力(C列が未入力)の場合があると、×となりますので、その処理を加えます。
      未入力の場合は30以下に含まれてしまいますので、一番最初に書いて処理する必要があります。
      =IF(C3="","",IF(C3<=30,"×",IF(C3<=60,"△","○")))
      となります。
2. では、得点の大きい方から処理するケースは?
   
   
   1. 今回は、空白の処理から始めます。
      =IF(C3="","",偽の場合)
   2. 60を超えたら○としますので、
      =IF(C3="","",IF(C3>60,"○",偽の場合))
   3. 30を超えたら△とします。
      =IF(C3="","",IF(C3>60,"○",IF(C3>30,"△",偽の場合))
      これらの条件に当てはまらないのは×となりますので、
      =IF(C3="","",IF(C3>60,"○",IF(C3>30,"△","×"))
      となります。
   4. なお、空白の処理を最後に持ってくると、以下のように書くこともできます。
      =IF(C3>60,"○",IF(C3>30,"△",IF(C3="","","×")))
3. 各区分ごとに判定すると考えると・・・
   
   1. 各区分の条件は
      0以上30以下：AND(C3>=0,C3<=30)
      30を超えて60以下：AND(C3>30,C3<=60)
      60を超えて100以下：AND(C3>60,C3<=100)
      と書くことができますので、これをIF関数に入れ込みます。
   2. すると、
      =IF(AND(C3>=0,C3<=30),"×",IF(AND(C3>30,C3<=60),"△",IF(AND(C3>60,C3<=100),"○","")))
      のようになります。
      このケースでは順序が変わっても問題はなく、
      =IF(AND(C3>30,C3<=60),"△",IF(AND(C3>=0,C3<=30),"×",IF(AND(C3>60,C3<=100),"○","")))
      としても結果は同じですが、解読がしずらいので順番に書いた方がよろしいかと思います。
4. 上記A〜Cとは異なった考え方
   
   • =IF(C3<>"",IF(C3<=60,IF(C3<=30,"×","△"),"○"),"")
     といった数式にすることもできます。
     しかし、このように[真の場合]に入れ子としていくのは、ちょっと理解しづらいかもしれません。

• 上記のように、どのような条件にするのか、その着目するところによってさまざまな数式が作成できます。
  分かりやすいのは、大きい方または小さい方から順次処理していく方法だと思います。

IF関数を使わずに条件分岐する数式を作る　　topへ

• このページのタイトルからは脱線してしまいますが、条件分岐にはIF関数がよく使われますが、他の関数でも数式を作ることができます。

問題1

• 上記と同じ問題です。
  得点が0以上30以下は×、60以下は△、60を超え100以下は○と評価することにします。
  

  	B	C	D
  2	名前	得点	評価
  3	井上	80	○
  4	上野	54	△
  5	内田	30	×
  6	榎田	15	×
  7	岡本	77	○
  8	大野	91	○

• 条件は3つあって、それぞれで分岐できればよいのですからCHOOSE関数を使う方法も考えられます。
  • CHOOSE関数の構文は=CHOOSE(インデックス,値1,値2,値3・・・)ですので
    =CHOOSE(インデックス,"×","△","○")　となるような「インデックス」を作成します。
  • 0以上で1point、30を超えたら1point、60を超えたら1pointと加算することで可能と考えました。
    (C3>=0)+(C3>30)+(C3>60) と論理和を求めることにします。
    • 例えば、得点が50なら
      (C3>=0)+(C3>30)+(C3>60) は　(True)+(True)+(False) = 1+1+0 = 2
      といった計算結果になります。
  • 数式は　=CHOOSE((C6>=0)+(C6>30)+(C6>60),"×","△","○")　となります。
  • なお、CHOOSE関数のインデックスには、1〜254の数値、または1〜254 の数値を返す数式またはセル参照を指定することができます。
• IF関数でのネストして作成する例とCHOOSE関数で作成した例で違いを見てみます。
  • 問題例：A1セルの値が「1のときはAを表示、2のときはBを表示、3のときはCを表示、4のときはDを表示する。それ以外はXを表示する」
    • =IF(A1=1,"A",IF(A1=2,"B",IF(A1=3,"C",IF(A1=4,"D","X"))))
    • =CHOOSE(A1,"A","B","C","D")　とシンプルな数式になります。
      しかし、CHOOSE関数では「それ以外はXを表示する」といった処理ができませんので、この部分はIF関数を利用します。
      =IF(OR(A1="",A1>4),"X",CHOOSE(A1,"A","B","C","D"))　としました。

問題2

• 得点が80以上は5、70以上は4、60以上は3、40以上は2、それ以外は1　と5段階表示したい。
  

  	B	C	D
  2	名前	得点	評価
  3	井上	80	5
  4	上野	54	2
  5	内田	30	1
  6	榎田	51	2
  7	岡本	77	4
  8	大野	60	3

  • IF関数での解答例
    • =IF(C2>=80,5,IF(C2>=70,4,IF(C2>=60,3,IF(C2>=40,2,1))))
  • 論理和を使って求めることができます。
    • =(C3>=0)+(C3>=40)+(C3>=60)+(C3>=70)+(C3>=80)
  • LOOKUP関数で求めることもできます。
    • =LOOKUP(C3,{0,40,60,70,80},{1,2,3,4,5})
  • VLOOKUP関数で求めることもできます。
    • =VLOOKUP(C3,{0,1;40,2;60,3;70,4;80,5},2)
  • MATCH関数で求めることもできます。
    • =MATCH(C3,{0,40,60,70,80})
• 5段階評価で1〜5と数値を返す例でしたので、上記のようにシンプルな数式になりました。
  では、返す値が文字列であったら?
  A,B,C,D,Eの文字列で評価することにします。
  

  	B	C	D
  2	名前	得点	評価
  3	井上	80	A
  4	上野	54	D
  5	内田	30	E
  6	榎田	51	D
  7	岡本	77	B
  8	大野	60	C

  • IF関数での解答例
    • =IF(C3>=80,"A",IF(C3>=70,"B",IF(C3>=60,"C",IF(C3>=40,"D","E"))))
  • 論理和を使って求めることができます。
    • =CHOOSE((C3>=0)+(C3>=40)+(C3>=60)+(C3>=70)+(C3>=80),"E","D","C","B","A")
    • =MID("EDCBA",(C3>=0)+(C3>=40)+(C3>=60)+(C3>=70)+(C3>=80),1)
  • LOOKUP関数で求めることもできます。
    • =LOOKUP(C3,{0,40,60,70,80},{"E","D","C","B","A"})
  • VLOOKUP関数で求めることもできます。
    • =VLOOKUP(C3,{0,"E";40,"D";60,"C";70,"B";80,"A"},2)
  • INDEX関数とMATCH関数で求めることもできます。
    • =INDEX({"E","D","C","B","A"},0,MATCH(C3,{0,40,60,70,80}))

スポンサードリンク

PageViewCounter

Since2006/2/27